Save As to specific location using excel VBA - vba

Question

I have working code that copies cells in a file and pastes into a newly created document that is generated with VBA code. I am looking to Save As this newly created document, which is currently is able to do. I created a csPath variable to try and specify a location for the document to Save As in, but it will only either save on my desktop or runs into an error. Any advice?
'Declaring variables for the Save As function
Dim fname As Variant ' Required for declaring the document name
Dim NewWb As Workbook ' Specifies the new workbook for the Save As function
Dim FileFormatValue As Long ' Allows programmer to declare what file formats that can be in the Save As function, currently only .xlsx
Dim csPath As String ' Allows program to set location for Save As function
'Begin the Save As function for easy operator reference of old batches
csPath = "\\346nafp1\shares$\Departments\Starch\Wetend\Transfer\old - dont touch\"
' Check the Excel version
If Val(Application.Version) < 9 Then Exit Sub
If Val(Application.Version) < 12 Then
' Only choice in the "Save as type" dropdown is Excel files(xls)
' if the Excel version is 2000-2003
fname = Application.GetSaveAsFilename(InitialFileName:="", _
Filefilter:="Excel Files (*.xls), *.xls", _
Title:="This example copies the ActiveSheet to a new workbook")
If fname <> False Then
' Copy the ActiveSheet to new workbook
ActiveSheet.Copy
Set NewWb = ActiveWorkbook
' We use the 2000-2003 format xlWorkbookNormal here to save as xls
NewWb.SaveAs fname, FileFormat:=-4143, CreateBackup:=False
NewWb.Close False
Set NewWb = Nothing
End If
Else
' Force to save as .xls for archiving in the History folder
' Files available there for use in the future for reference
' But disable macros to prevent changing or confusion when looking at archives
fname = Application.GetSaveAsFilename(InitialFileName:=Worksheets("Oxy1").Cells(4, 7) & " " & Worksheets("Oxy1").Cells(4, 11), _
Filefilter:= _
" Excel Macro Free Workbook (*.xls), *.xls,", _
FilterIndex:=2, Title:="Save and archive for new batch")
' Add the code to the Filefilter above if additional formats are needed
' Include " before the word Excel to add it in
' Excel Macro Enabled Workbook (*.xlsm), *.xlsm," & _
' Excel 2000-2003 Workbook (*.xls), *.xls," & _
' Excel Binary Workbook (*.xlsb), *.xlsb", _
' Find the correct FileFormat that match the choice in the "Save as type" list
If fname <> False Then
Select Case LCase(Right(fname, Len(fname) - InStrRev(fname, ".", , 1)))
Case "xls": FileFormatValue = 56
Case "xlsx": FileFormatValue = 51
Case "xlsm": FileFormatValue = 52
Case "xlsb": FileFormatValue = 50
Case Else: FileFormatValue = 0
End Select
' Now we can create/Save the file with the xlFileFormat parameter
' value that match the file extension
If FileFormatValue = 0 Then
MsgBox "Sorry, unknown file extension"
Else
' Copies the ActiveSheet to new workbook
ActiveSheet.Copy
Set NewWb = ActiveWorkbook
'Save the file in the format you choose in the "Save as type" dropdown
NewWb.SaveAs fname, FileFormat:= _
FileFormatValue, CreateBackup:=False
NewWb.Close False
Set NewWb = Nothing
End If
End If
End If

Answer 1

Define it in your saveas with the filename:= argument.
NOTE: Not sure if it is going to like saving to a UNC\share.
NewWb.SaveAs filename:="C:\Temp\NewFilename.xls", FileFormat:=56, CreateBackup:=False
or with your variable
NewWb.SaveAs filename:=csPath & "\NewFilename.xls", FileFormat:=56, CreateBackup:=False
Also here in some infor on the fileformat arg. Not sure what your FileFormat:=-4143 is trying to do.
These are the main file formats in Excel 2007-2016, Note: In Excel for the Mac the values are +1
51 = xlOpenXMLWorkbook (without macro's in 2007-2013, xlsx)
52 = xlOpenXMLWorkbookMacroEnabled (with or without macro's in 2007-2013, xlsm)
50 = xlExcel12 (Excel Binary Workbook in 2007-2013 with or
without macro's, xlsb)
56 = xlExcel8 (97-2003 format in Excel
2007-2013, xls)