Import CSV file to another sheet - vba

Question

I'm trying to import a CSV file into another sheet when I press a button on one sheet.
Here is my code:
Sub historiskAktieData(ticker)
Set ws = ActiveWorkbook.Sheets("HistoriskAktieData")
Dim enddate As Date
Dim StartDate As Date
StartDate = ThisWorkbook.Sheets("Opg. 1").Range("c1").Value
enddate = ThisWorkbook.Sheets("Opg. 1").Range("c2").Value
Symbol = ticker
qurl = "http://ichart.finance.yahoo.com/table.csv?s=" & Symbol & "&a=" & Month(StartDate) - 1 & "&b=" & Day(StartDate) & "&c=" & Year(StartDate) & "&d=" & Month(enddate) - 1 & "&e=" & Day(enddate) & "&f=" & Year(enddate) & "&g=" & "" & "&q=q&y=0&z=" & Symbol & "&x=.csv"
With ActiveSheet.QueryTables.Add(Connection:= _
"TEXT;" & qurl _
, Destination:=ws.Range("A1"))
.Name = "table.csv?s=SAP&a=01&b=01&c=14&d=01&e=08&f=16&g=Dateq=q&y=0&z=&x="
.FieldNames = True
.RowNumbers = False
.FillAdjacentFormulas = False
.PreserveFormatting = True
.RefreshOnFileOpen = False
.RefreshStyle = xlInsertDeleteCells
.SavePassword = False
.SaveData = True
.AdjustColumnWidth = True
.RefreshPeriod = 0
.TextFilePromptOnRefresh = False
.TextFilePlatform = 850
.TextFileStartRow = 1
.TextFileParseType = xlDelimited
.TextFileTextQualifier = xlTextQualifierDoubleQuote
.TextFileConsecutiveDelimiter = False
.TextFileTabDelimiter = False
.TextFileSemicolonDelimiter = False
.TextFileCommaDelimiter = True
.TextFileSpaceDelimiter = False
.TextFileColumnDataTypes = Array(1, 1, 1, 1, 1, 1, 1)
.TextFileTrailingMinusNumbers = True
.Refresh BackgroundQuery:=False
End With
End Sub
The problem seems to be this bit:
With ActiveSheet.QueryTables.Add(Connection:= _
"TEXT;" & qurl _
, Destination:=ws.Range("A1"))
Hope someone can help. I'm using excel 2010.

Answer 1

From
https://msdn.microsoft.com/en-us/library/office/ff837764.aspx
Destination, Required, Range
The cell in the upper-left corner of the query table destination range
(the range where the resulting query table will be placed). The
destination range must be on the worksheet that contains the
QueryTables object specified by expression.
The QueryTable you are trying to create is in your active sheet (ActiveSheet.QueryTables.Add(...)), yet Destination:=ws.Range("A1") is in general not in the same sheet. Simply write ws.QueryTables.Add(...) instead of ActiveSheet.QueryTables.Add(...).