Progress bar in Status bar, a blank and a filled in char are not equal width - vba

Question

I am playing around creating code for a progress bar that runs in the Excel Status Bar. I want to replace my old dated userform with the 2 rectangles (which worked but I would sooner a less obtrusive method now).
Problem: The width of the chars I am using to signify "Filled In" and "Not Filled in" are slightly different, when using 100 of them you can see the percentage at the end appears to shift right as the progress increases.
Here is some working sample code to show you exactly what I mean:
Sub TestNewProgBar()
Dim X As Long
For X = 1 To 100000
Call NewProgressBar("Testing", X, 100000)
Next
End Sub
Sub NewProgressBar(MyMessage As String, CurrentVal As Long, MaxVal As Long)
Dim FilledIn As Long, NotFilledIn As Long
If CurrentVal >= MaxVal Then
Application.StatusBar = MyMessage & ": Complete"
Else
FilledIn = Round((CurrentVal / MaxVal) * 100, 0)
NotFilledIn = (100 - FilledIn)
Application.StatusBar = MyMessage & ": " & Application.WorksheetFunction.Rept(ChrW(9608), FilledIn) & Application.WorksheetFunction.Rept(ChrW(9620), NotFilledIn) & "| " & FilledIn & "%"
End If
End Sub
Run TestNewProgBar and look at the status bar.
Is this going to be a simple case of choosing a different Unicode symbol or are there forces beyond my control at work here?

Answer 1

There's a Unicode block from U+25A0 to U+25FF called Geometric Shapes. There are some matching pairs of black/ white shapes in there that will successfully work for your progress bar implementation.
In the test code below, some pairs work and some do not!. Personally I like the last example (pairing U+25AE and U+25AD).
Option Explicit
Sub TestNewProgBar()
Dim lngCounter As Long
Dim lngMax As Long
Dim strFilledChar As String
Dim strNotFilledChar As String
'iterations
lngMax = 100000
'small squares - works
strFilledChar = ChrW(&H25AA)
strNotFilledChar = ChrW(&H25AB)
For lngCounter = 1 To lngMax
Call NewProgressBar("Small squares", lngCounter, lngMax, strFilledChar, strNotFilledChar)
Next
'large squares - doesn't work
strFilledChar = ChrW(&H25A0)
strNotFilledChar = ChrW(&H25A1)
For lngCounter = 1 To lngMax
Call NewProgressBar("Large squares", lngCounter, lngMax, strFilledChar, strNotFilledChar)
Next
'large squares 2 - doesn't work (but opposite effect)
strFilledChar = ChrW(&H25A3)
strNotFilledChar = ChrW(&H25A1)
For lngCounter = 1 To lngMax
Call NewProgressBar("Large squares 2", lngCounter, lngMax, strFilledChar, strNotFilledChar)
Next
'mixed vertical/ horizontal rectangles - works!
strFilledChar = ChrW(&H25AE)
strNotFilledChar = ChrW(&H25AD)
For lngCounter = 1 To lngMax
Call NewProgressBar("Mixed rectangles", lngCounter, lngMax, strFilledChar, strNotFilledChar)
Next
End Sub
Sub NewProgressBar(strMyMessage As String, lngCurrentVal As Long, lngMaxVal As Long, strFilledChar As String, strNotFilledChar As String)
Dim lngFilledIn As Long
Dim lngNotFilledIn As Long
Dim strStatus As String
If lngCurrentVal >= lngMaxVal Then
Application.StatusBar = strMyMessage & ": Complete"
Else
lngFilledIn = Round((lngCurrentVal / lngMaxVal) * 100, 0)
lngNotFilledIn = (100 - lngFilledIn)
strStatus = strMyMessage & ": " & _
String(lngFilledIn, strFilledChar) & _
String(lngNotFilledIn, strNotFilledChar) & _
"| " & lngFilledIn & "%"
Application.StatusBar = strStatus
End If
End Sub

Answer 2

Edit:
To follow up on my 'aside' below, I did some experimenting, and Comintern was onto something when s/he provided a link to this issue. The problem described above is to do with ScreenUpdating. If Screenupdating is set to false when the status bar is changed, the character widths of ChrW(9608) and ChrW(9620) are the same.
I've no idea why, but it does the trick. So you'll want to do the following:
Application.Screenupdating = False
'code which changes the status bar
Application.Screenupdating = True
(my previous comment continues below)
I prefer this pairing:
strFilledChar = ChrW(&H2588) 'a black rectangle, "Full Block"
strUnfilledChar = ChrW(&H2584) 'an array of sparse dots, "Light Shade"
Or this one:
strFilledChar = ChrW(&H2588) 'a black rectangle, "Full Block"
strUnfilledChar = ChrW(&H2500) 'a horizontal line, "Block Drawings Light Horizontal"
(as an aside, I encountered the same problem as described in the question whereby ChrW(9608) and ChrW(9620) have different widths - but only in one of my workbooks. In another workbook, they have the same widths and so the progress bar displays properly. I have no idea why.)