How to set multiple bit values within an integer - vb.net

Question

I am coding a program in vb.net using Visual Studio 2015. I am trying to figure out how to modify individual bits in a 16 bit integer. The numeric data-type byte-order is little-Indian and is as follows:
origin (2 bits)
tagged (1 bit)
addressable (1 bit)
protocol (12 bits)
Field: [ origin ] [tagged] [addressable] [protocol]
Bits: 16 15 14 13 12 11 10 9 8 7 6 5 4 3 2 1
In the example code below, I am trying to figure out how to set origin, tagged, addressable and protocol in the variable "i" which is a 16 bit integer.
Dim i As UInt16 = 0
Dim origin As Byte = 0 ' Message origin indicator
Dim tagged As Byte = 0 ' Determines usage of the Frame Address target field (0 or 1)
Dim addressable As Byte = 0 ' Message includes a target address (0 or 1)
Dim protocol As UInt16 = 1024 ' Protocol number: must be 1024 (decimal)
Can anyone provide a vb.net example of how I can update the variable "i" so that it contains the bit values for origin, tagged, addressable and protocol?

Answer 1

You can use a combination of or to set individual bits and >> and << to shift bits.
For example, to set two bytes from tagged, addressable and protocol, you can do:
Dim tagged As Byte = 1 ' Determines usage of the Frame Address target field (0 or 1)
Dim addressable As Byte = 1 ' Message includes a target address (0 or 1)
Dim protocol As UInt16 = 1026 ' Protocol number: must be 1024 (decimal)
sendbuf(0) = sendbuf(0) or tagged ' bit 0
sendbuf(0) = sendbuf(0) or (addressable << 1) ' bit 1
sendbuf(0) = sendbuf(0) or ((protocol << 2) and 255) ' first 6 bits of protocol
sendbuf(1) = sendbuf(1) or (protocol >> 6) ' next 6 bits of protocol
You may need to adjust it - I didn't follow the link, so I'm not completely sure which bits should go where (there's 14 bits to fit into 2 bytes).

Answer 2

Map the bit values using binary values in an enumeration. 1 = 1, 2 = 10, 4 = 100, etc. Then you can assign your variable using the enumeration. You can also combine the values into a new enumeration (see ProtocolX).
To give initial values, just add the enumeration you want to use.
' switch bits on 1, 5, 13, 14, 16
i = FrameSectionEnum.ProtocolBit1 + FrameSectionEnum.ProtocolBit5 +
FrameSectionEnum.AddressableBit13 +
FrameSectionEnum.TaggedBit14 + FrameSectionEnum.OriginBit16
PrintBits(i)
To switch on some bits and preserve the other bits, use OR.
' switch bits on 2 and 3 using a combined value. preserve other bits
i = SetOn(i, FrameSectionEnum.ProtocolX)
PrintBits(i)
To switch off some bits and preserve the other bits, use AND and NOT.
' switch bits off 1 and 5
i = SetOff(i, FrameSectionEnum.ProtocolBit1 + FrameSectionEnum.ProtocolBit5)
PrintBits(i)
List of utilities functions:
Check if certain bits is on:
Function CheckBit(i As Integer, bit As FrameSectionEnum) As Integer
Return If((i And bit) = bit, 1, 0)
End Function
Set bits on, preserve other bits:
Function SetOn(i As Integer, bit As FrameSectionEnum) As Integer
Return i Or bit
End Function
Set bits off, preserve other bits:
Function SetOff(i As Integer, bit As FrameSectionEnum) As Integer
Return i And (Not bit)
End Function
Full code:
Module Module1
Enum FrameSectionEnum
ProtocolBit1 = 1
ProtocolBit2 = 2
ProtocolBit3 = 4
ProtocolBit4 = 8
ProtocolBit5 = 16
ProtocolBit6 = 32
ProtocolBit7 = 64
ProtocolBit8 = 128
ProtocolBit9 = 256
ProtocolBit10 = 512
ProtocolBit11 = 1024
ProtocolBit12 = 2048
AddressableBit13 = 4096
TaggedBit14 = 8192
OriginBit15 = 16384
OriginBit16 = 32768
ProtocolX = ProtocolBit2 + ProtocolBit3
End Enum
Sub Main()
Dim i As UInt16 = 0
' switch bits on 1, 5, 13, 14, 16
i = FrameSectionEnum.ProtocolBit1 + FrameSectionEnum.ProtocolBit5 +
FrameSectionEnum.AddressableBit13 +
FrameSectionEnum.TaggedBit14 + FrameSectionEnum.OriginBit16
PrintBits(i)
' switch bits on 2 and 3 using a combined value. preserve other bits
i = SetOn(i, FrameSectionEnum.ProtocolX)
PrintBits(i)
' switch bits off 1 and 5
i = SetOff(i, FrameSectionEnum.ProtocolBit1 + FrameSectionEnum.ProtocolBit5)
PrintBits(i)
Console.ReadKey(True)
End Sub
Function SetOn(i As Integer, bit As FrameSectionEnum) As Integer
Return i Or bit
End Function
Function SetOff(i As Integer, bit As FrameSectionEnum) As Integer
Return i And (Not bit)
End Function
Function CheckBit(i As Integer, bit As FrameSectionEnum) As Integer
Return If((i And bit) = bit, 1, 0)
End Function
Sub PrintBits(i As Integer)
Console.Write(CheckBit(i, FrameSectionEnum.OriginBit16))
Console.Write(CheckBit(i, FrameSectionEnum.OriginBit15))
Console.Write(CheckBit(i, FrameSectionEnum.TaggedBit14))
Console.Write(CheckBit(i, FrameSectionEnum.AddressableBit13))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit12))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit11))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit10))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit9))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit8))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit7))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit6))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit5))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit4))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit3))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit2))
Console.Write(CheckBit(i, FrameSectionEnum.ProtocolBit1))
Console.WriteLine()
End Sub
End Module

Answer 3

The header format in the question contains the key to getting all the bits in the right place. For me personally, it's easier to visualize if you renumber the bits using a zero-based index:
Field: [ origin ] [tagged] [addressable] [protocol]
Bits: 15 14 13 12 11 10 9 8 7 6 5 4 3 2 1 0
Starting with the origin field, it needs to be shifted 14 bits to the left, which can be done like this:
origin << 14
The tagged and addressable fields need to be shifted to the left by 13 and 12 bits, respectively, which can be done the same way. The protocol field is already in the right place, so it doesn't need to be shifted. They can all be combined together with the Or operator as follows:
i = (origin << 14) Or (tagged << 13) Or (addressable << 12) Or protocol
One last detail that needs to be addressed is that in VB.NET, bit shift operations are dependent upon the datatype that is being shifted. In your code above, the origin, tagged, and addressable variables are all of type Byte. Shifts on this type will all be done modulo 8 (the number of bits in a byte), meaning a shift of 9 bits is the same of a shift of 1 bit.
Because all of our shifts are more than 8 bits, we need to convert to a wider datatype or else things won't end up in the right place. The easy way to do this is to just change the declarations of all the variables to UInt16:
Dim i As UInt16
Dim origin As UInt16 = 0
Dim tagged As UInt16 = 0
Dim addressable As UInt16 = 0
Dim protocol As UInt16 = 1024
i = (origin << 14) Or (tagged << 13) Or (addressable << 12) Or protocol
The alternative to this is to keep your variables declared as they are and use CType to convert the fields right before doing the shifts:
Dim i As UInt16 = 0
Dim origin As Byte = 0
Dim tagged As Byte = 0
Dim addressable As Byte = 0
Dim protocol As UInt16 = 1024
i = (CType(origin, UInt16) << 14) Or (CType(tagged, UInt16) << 13) Or (CType(addressable, UInt16) << 12) Or protocol
Personally, I prefer the first way due to brevity, but the choice is yours!