Outlook blank 'To' field from Excel VBA on some computers - vba

Question

We have an Excel spreadsheet that we use to create quotations for potential customers. Through the use of VBA, it generates PDFs and emails them to the customer using Outlook. It takes the customer's email address from a cell on the main sheet where the user fills in the customer's details.
A couple of weeks ago, it stopped filling the customer's email address in the 'To' field in Outlook, even though it had been filled in on the main sheet.
When we change anything on this spreadsheet, including code, we save it as a new 'revision' (keeping all previous revisions.) Going back through the previous revisions, I now find that none of them work. This is odd as they definitely did before. I am using Office 2016 (although I upgraded a while ago, but this issue is recent.) A machine running Office 2013 is also not working. However, a machine running Office 2007 DOES work.
Any ideas as to why this is an issue now, and why it is only an issue on certain versions of Office? Here is a snippet of the code:
Private Sub send_as_pdf_Click()
On Error GoTo ErrMsg
Dim strPath As String, strFName As String
Dim OutApp As Object, OutMail As Object
strPath = Environ$("temp") & "\"
strFName = Sheets("Quotation").Name & " " & Range("G18") & ".pdf"
Sheets("Quotation").ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
strPath & strFName, Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
strPath2 = Environ$("temp") & "\"
strFName2 = Sheets("Quotation Offer Letter").Name & " " & Range("G18") & ".pdf"
Sheets("Quotation Offer Letter").ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
strPath2 & strFName2, Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
strPath3 = Environ$("temp") & "\"
strFName3 = Sheets("Additional Works Required").Name & " " & Range("G18") & ".pdf"
Sheets("Additional Works Required").ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
strPath3 & strFName3, Quality:=xlQualityStandard, _
IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
strbody = "<p style='color:#2C3E50;font-family:Calibri;font-size:11pt;'>Hi " & Range("C9") & ",</p>"
strbody2 = "<p style='color:#2C3E50;font-family:Calibri;font-size:11pt;'>The content of the email goes here.</p>"
On Error Resume Next
With OutMail
.Display
.To = Range("C19")
.CC = ""
.BCC = "first#person.com" & ";" & "second#person.com" & ";" & Range("I6") & ";"
.Subject = "Quotation"
.HTMLBody = strbody & strbody2 & .HTMLBody
.Attachments.Add strPath & strFName
.Attachments.Add strPath2 & strFName2
.Attachments.Add strPath3 & strFName3
.Attachments.Add ("C:\Terms and Conditions of Business of Our Business.pdf")
.Attachments.Add ("C:\Warranty Statement of Our Business.pdf")
End With
Kill strPath & strFName
On Error GoTo 0
Set OutMail = Nothing
Set OutApp = Nothing
Exit Sub
ErrMsg:
MsgBox ("MUST enter Issue Number, Date & Customer Info."), , "Customer Email Error Message"
End Sub

Answer 1

Try this:
Comment this line so you can see what the error is and debug.
'On Error Resume Next
After doing that you should be able to see the error within the line:
.To = Range("C19")
In excel this returns the value of the range, however you are sending that value to another application Outlook which is expecting a string.
I changed that line to this:
.To = Range("C19").Value2
and it worked