How can I add a table in each iteration of my loop? - vba

Question

I am generating a word document from excel using VBA. I have a for loop that I would like to add a [1 row, 1 column, bordered] table to. This is an area where the user can put their comments inside a word document. When I try to add .table.add I have been getting different errors ranging from object errors. This is what I have so far:
Sub GenDocumentables()
Worksheets("checklist").Activate
Dim wdApp As Word.Application
Set wdApp = New Word.Application
Dim saveName As String
Dim NumberOfCells As Integer
With wdApp
.Visible = True
.Activate
'Debug.Print .Version
.Documents.Add
With .Selection
.InsertBreak Type:=wdPageBreak
.ParagraphFormat.Alignment = wdAlignParagraphCenter
.BoldRun
.Font.Size = 13
.TypeText "Documentable Items for "
.TypeText Range("d4").Value
.BoldRun
.TypeParagraph
End With
NumberOfCells = Range("a4", Range("a3").End(xlDown)).Count
For loopcounter = 1 To 2 ' NumberOfCells
With .Selection
.Font.Bold = False
.Style = wdStyleHeading3
.TypeText Range("a3").Offset(loopcounter, 0).Value & " - "
.TypeText Range("a3").Offset(loopcounter, 4).Value
.TypeParagraph
.Font.Size = 10
.TypeText Range("a3").Offset(loopcounter, 5).Value
.TypeParagraph
.Font.Italic = True
.TypeText "<<Please enter your commentary here. Ensure all aspects of the check content are met>>"
.TypeParagraph
'-------------------ADD TABLE HERE-------------------
End With
Next
Set myRange = ActiveDocument.Range(0, 0)
ActiveDocument.TablesOfContents.Add Range:=myRange, UseFields:=False, UseHeadingStyles:=True, LowerHeadingLevel:=3, UpperHeadingLevel:=1
With .Selection
.GoTo What:=wdGoToSection, Which:=wdGoToFirst
.InsertBreak Type:=wdPageBreak
End With
saveName = Environ("UserProfile") & "\Desktop\My Word Doc_" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ".docx"
.ActiveDocument.SaveAs2 saveName
'.ActiveDocument.Close
'.Quit
End With
MsgBox "done!"
End Sub

Answer 1

You are getting object errors due to the fact that Selection does not have a method .Table
To get around this, you'll want to use the line:
Set newTable = wdApp.ActiveDocument.Tables.Add(SomeRange,1,1)
Tables is a member of Document, which you can retrieve using the section wdApp.ActiveDocument.
Here, SomeRange needs to be defined for this to work properly.
To try and get this code running, lets try and add a few variables to make this easier.
Back where you declare your other variables add these:
Dim myRange As Word.Range
Dim wdDoc As Word.Document
Dim newTable As Word.Table
and before you enter your loop, AFTER you create the document add:
Set wdDoc = wdApp.ActiveDocument
Next, inside of your loop, but after your End With (.Selection) you could add:
Set myRange = wdDoc.Range(wdDoc.Content.End - 1, wdDoc.Content.End)
Set newTable = wdDoc.Tables.Add(myRange, 1, 1)
newTable.Cell(1, 1).Range.Text = "Hello"
Set myRange = wdDoc.Range(wdDoc.Content.End - 1, wdDoc.Content.End)
myRange.Select
Let's go through what this does.
First, it sets out custom variable myRange to be the last character in the document. This allows us to place the Table underneath everything that's already been created,
Next, it creates a table at this location, with the size 1x1.
The value of the first cell in this table is set to "Hello"
The next line then AGAIN sets the range to the bottom of the file, then selects it. This is neccessary because creating a table changes the selection to be inside of the new table. Skipping this line would have you then run the next iteration of the loop INSIDE of the table.
Hope this helps.