Excel VBA: Checking to make sure all controls aren't empty - vba

Question

In my program, I have a snippet of code in a userfrom that looks at its own controls and loops through to see if all of them are empty. This is for the purpose of using all of the non-null controls' values as search parameters. They are three list boxes and three combo boxes. If it finds a control that is not empty, it sects the function to false and exits. This is because my search found a criteria it can use. I have it setup thus:
Function IsAllEmpty() As Boolean
'presumes true until we find evidence of a control being not empty
IsAllEmpty = True
'function elsewhere that sets my control background to normal
ClearControlFormatting
Dim ctrl As Control
'checks every control in the form
For Each ctrl In Me.Controls
'that is tagged with "searchme" (there are 6, three listbox, three combobox)
If ctrl.Tag = "SEARCHME" Then
'if the value of the control isn't null or len = 0
If Not IsNull(ctrl) Or Len(ctrl) <> 0 Then
ctrl.BackColor = vbGreen
IsAllEmpty = False 'in my other code, I can continue the search if this is triggered
MsgBox "Everything is good (no sarcasm) on this control!"
Exit Function
Else: MsgBox "EVERYTHING IS EMPTY, CARL. THAT KILLS PEOPLE."
End If
End If
Next
'If something is empty, tell the user to correct it
If IsAllEmpty = True Then
MsgBox "YOU NEED TO FILL OUT YOUR SEARCH, PAUL."
End If
End Function
I have tried various things to get this to work:
nesting the Not IsNull(ctrl) statement the only one in the if, the If Len(ctrl) <> 0 part (IDK WHY)
Removing the Len(ctrl) <> 0 part
Editing both parts of the Or statement to evaluate for ctrl.Value = "" instead
Removed the "SEARCHME" tags from the comboboxes, in case their dynamic values were interfering.
However, every time, I have watched this function highlight all of my controls green, and then proceed to continue attempting a search. (The function call down in the search says if all the cells come back null, exit the sub).
I'm at a loss, and would greatly appreciate the help! Thanks!
P.S.: If it helps, the above code is a modified version of the following, meant to check to see if any empty controls exist at all. When I used this on my controls, it found them all to be empty and worked like designed.
Function CheckForEmpty() As Boolean
CheckForEmpty = True
ClearControlFormatting
Dim ctrl As Control
'Checks each control that needs to be filled for null or 0 length value
'For every one it finds, it marks red
CheckForEmpty = True
For Each ctrl In Me.Controls
If ctrl.Tag = "FILL" Then
If IsNull(ctrl) Or Len(ctrl) = 0 Then
ctrl.BackColor = vbRed
CheckForEmpty = False
End If
End If
Next
'If something is empty, tell the user to correct it
If CheckForEmpty = False Then
MsgBox "Please fill out red boxes!"
End If
End Function

Answer 1

In this line, change to be explicit that you're looking for the value:
If Not IsNull(ctrl) Or Len(ctrl) <> 0 Then
change to:
If (Not IsNull(ctrl.Value)) OR (Len(ctl.Value & "") <> 0) Then
First, I added the .Value qualifier to the control. This is the default property, but sometimes (when assigning to a variant or checking null, for example), it might be checking that the Control itself is null because VBA isn't always smart enough to read your thoughts and you're technically telling it to check the control, and not it's value: be explicit.
Second, I explicitly split the two checks into two separate checks using parentheses. Not sure it's strictly required, but best to be clear and far easier to read and now we don't have to worry about the fact that it maybe was reading the boolean logic incorrectly.
Third, I added a ZLS concatenation to .Value to force it to ZLS if null before checking the length (you get an 'Invalid Use of Null' error if trying to check the Len() of a null value).
As Tom mentions, in this case ctrl will never be null (as it's part of the form's collection, which won't have null references in it), so the whole thing can be simplified to:
If Len(ctrl.Value & "") <> 0 Then 'ctrl has no value entered
Lastly, wrap it up in a Trim() function just in case there's a single (or double, or more) space in there, and you have:
If Len(Trim(ctrl.Value & "")) <> 0 Then 'ctrl has no meaningful value entered