Turning coloured cells into no-fill cells throughout the whole excel spreadsheet - vba

Question

This is my code which does not seem to work. I basically get an "object required" error in the 3rd line "for each cell in UsedRange.Cells"
Sub AgreeAll()
Dim myRange As Range
For Each cell In UsedRange.Cells
If cell.Interior.Color = RGB(255, 192, 0) Then
If myRange Is Nothing Then
Set myRange = cell
Else
Set myRange = Union(myRange, cell)
End If
End If
Next
If Not myRange Is Nothing Then
myRange.Interior.Color = RGB(255, 255, 255)
Range("P7").ClearContents
Columns("E:F").EntireColumn.Delete
End If
End Sub

Answer 1

The anatomy of a basic If block:
If [condition] = [true | false] Then
'// Do something
[Else]
['// Do something Else]
End If
So in your case, you would want something like:
(Revised after comment feedback)
Dim myRange As Range
For Each cell In UsedRange.Cells
If cell.Interior.ColorIndex = 44 Then
If myRange Is Nothing Then
Set myRange = cell
Else
Set myRange = Union(myRange, cell)
End If
End If
Next
If Not myRange Is Nothing Then
myRange.Interior.ColorIndex = xlNone
Range("P7").ClearContents
Columns("E:F").EntireColumn.Delete
End If

Answer 2

It has never been determined whether the cells are orange filled by manually setting a background fill or whether they are filled by a conditional formatting rule. If the latter, then you can set the Interior.Pattern property to white or xlNone all you like; the CF rule will override anything you set. You can clear the content (which I assume drives the CF rule) or delete the CF rule from that cell.
The AutoFilter method can filter for the Range.DisplayFormat property. The .DisplayFormat includes both regular formatting and conditional formatting; i.e. if you see orange, then so does .DisplayFormat.
Sub AgreeAll()
Dim rng As Range
Dim c As Long
'Application.ScreenUpdating = False
With Worksheets("Sheet2") '<~~set this worksheet reference properly!
'why wait until the end to do this? It only means you have to process rtwo columns you plan to delete
.Columns("E:F").EntireColumn.Delete
If .AutoFilterMode Then .AutoFilterMode = False
With .Cells(1, 1).CurrentRegion
For c = 1 To .Columns.Count
With .Columns(c)
.AutoFilter Field:=1, Criteria1:=RGB(255, 192, 0), _
Operator:=xlFilterCellColor
If .Cells.SpecialCells(xlCellTypeVisible).Count > 1 Then
.Offset(1, 0).Interior.Pattern = xlNone
For Each rng In .SpecialCells(xlCellTypeVisible)
If rng.DisplayFormat.Interior.Color = RGB(255, 192, 0) Then _
rng.FormatConditions.Delete
Next rng
'your code cleared P7; did you want to clear all of the orange cells?
'.Offset(1, 0).ClearContents
End If
.AutoFilter
End With
Next c
End With
If .AutoFilterMode Then .AutoFilterMode = False
End With
Application.ScreenUpdating = True
End Sub
Neither your code nor narrative adequately explains what Range("P7").ClearContents was supposed to do. If you wanted to clear the orange cells then I've left some commented code in the appropriate place to do that.
If you run into problems, feel free to leave a comment but remember to provide sufficient information that I can help you with it.

Answer 3

Try this :
Sub AgreeAll()
Dim wS As Worksheet, _
myRange As Range, _
aCell As Range
Set wS = ActiveSheet
'set ws =sheets("Your_Sheet's_Name")
With wS
For Each aCell In .UsedRange.Cells
If aCell.Interior.Color = RGB(255, 192, 0) Then
If myRange Is Nothing Then
Set myRange = aCell
Else
Set myRange = Union(myRange, aCell)
End If
End If
Next
If Not myRange Is Nothing Then
myRange.Interior.Pattern = xlNone
.Range("P7").ClearContents
.Columns("E:F").EntireColumn.Delete
End If
End With
End Sub