Optimizing VBA command to delete rows with blanks - vba

Question

I have a macro where I use the following command to delete all rows where A = blank:
Range("A:A").SpecialCells(xlCellTypeBlanks).EntireRow.Delete
The files that I am running through this macro range from 1kb to 300mb.
Doing some pressure testing, it appears that when the file is below 15mb, the command will execute almost instantaneously, resulting in a 20 second to 6 minute run time for the macro.
The second I plug in a file that is larger than 15mb, the macro will get caught on this command for 30-40 minutes.
Does anyone have a nifty trick to optimize this command for large files? If it takes a fraction of a second for a 13mb file, there must be a way to make it take a fraction of a second for a 15mb file and hopefully make it take a fraction of a second for a 300mb file...

Answer 1

Use an AutoFilter Method and temporarily turn off all possible environment parameters.
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Application.EnableEvents = False
Application.Calculation = xlCalculationManual
With Worksheets("Sheet1")
If .AutoFilterMode Then .AutoFilterMode = False
With .Cells(1, 1).CurrentRegion
.Cells.Sort Key1:=.Columns(1), Order1:=xlAscending, _
Orientation:=xlTopToBottom, Header:=xlYes
.AutoFilter Field:=1, Criteria1:="="
.Resize(.Rows.Count - 1, 1).Offset(1, 0).EntireRow.Delete
.AutoFilter
End With
End With
Application.Calculation = xlCalculationAutomatic
Application.EnableEvents = True
Application.DisplayAlerts = True
Application.ScreenUpdating = True
It has been my experience that even looping through the rows from bottom to top can sometimes beat a call to delete Range.SpecialCells with the xlCellTypeBlanks.

Answer 2

Alright, so, basically riding on Jeeped's suggestions that sorting is the best method to do it, I just decided to index the data and sort:
'Insert column for index
Columns("A:A").Select
Selection.Insert Shift:=xlToRight, CopyOrigin:=xlFormatFromLeftOrAbove
'Apply index
Range("A1").Select
ActiveCell.FormulaR1C1 = "1"
Range("A2").Select
ActiveCell.FormulaR1C1 = _
"=IF(RC[1]="""","""",R[-1]C+1)"
Range("A3:A" & Range("B" & Rows.Count).End(xlUp).Row).Formula = "=IF(RC[1]="""","""",IF(R[-1]C="""",R[-2]C+1,R[-1]C+1))"
'Sort blanks to bottom
Columns("A:Z").Select
ActiveWorkbook.Worksheets("MasterList").Sort.SortFields.Clear
ActiveWorkbook.Worksheets("MasterList").Sort.SortFields.Add Key:=Columns( _
"A:A"), SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:= _
xlSortNormal
With ActiveWorkbook.Worksheets("Masterlist").Sort
.SetRange Columns("A:Z")
.Header = xlGuess
.MatchCase = False
.Orientation = xlTopToBottom
.SortMethod = xlPinYin
.Apply
End With
Columns("A").Select
Selection.Delete Shift:=xlToLeft
Which runs like butter. Leaves the non-true-blank rows at the bottom, which is going to drive up the file size a bit, which is not ideal, but id rather run the macro run fast and take a half Meg penalty in file size than sit here waiting 40 minutes when I want to run a large file.