Internet Explorer 11 automation error - vba

Question

I am having a problem when using vba from excel to navigate on multiple pages. I have used the code on ie8 and ie9 without any problems, but in ie11, when i navigate to another url the ie.locationurl and ie.document still refer to the previous url. I noticed this only happens with php websites. I am interested in finding a way to solve this. Any help appreciated.
Here is some example code with a php website:
Sub test()
Dim ie As SHDocVw.InternetExplorer
Set ie = New SHDocVw.InternetExplorer
With ie
.navigate "https://www.facebook.com/" 'php website
.Visible = True
Do While ie.Busy
Loop
Do While ie.readyState <> 4
Loop
.navigate "https://en.wikipedia.org/wiki/Main_Page"
.Visible = True
Debug.Print ie.locationurl
Do While ie.Busy
Loop
Do While ie.readyState <> 4
Loop
End With
End Sub
And here is one that works but doesn't have a php website:
Sub test2()
Dim ie As SHDocVw.InternetExplorer
Set ie = New SHDocVw.InternetExplorer
With ie
.navigate "http://www.break.com/" 'non php website
.Visible = True
Do While ie.Busy
Loop
Do While ie.readyState <> 4
Loop
.navigate "https://en.wikipedia.org/wiki/Main_Page"
.Visible = True
Debug.Print ie.locationurl
Do While ie.Busy
Loop
Do While ie.readyState <> 4
Loop
End With
End Sub

Answer 1

You are requesting the LocationURL property before you've allowed the page to load.
Sub test()
Dim ie As SHDocVw.InternetExplorer
Set ie = New SHDocVw.InternetExplorer
With ie
.Visible = True
.navigate "https://www.facebook.com/" 'php website
Debug.Print "1." & .locationurl
Do While .Busy Or .readyState <> 4: DoEvents: Loop
Debug.Print "2." & ie.locationurl
.navigate "https://en.wikipedia.org/wiki/Main_Page"
Debug.Print "3." & .locationurl
Do While .Busy Or .readyState <> 4: DoEvents: Loop
Debug.Print "4." & .locationurl
End With
End Sub
Results from the VBE's Immediate window:
test
1.
2.https://www.facebook.com/
3.https://www.facebook.com/
4.https://en.wikipedia.org/wiki/Main_Page
I've paired up the ie.Busy and ie.readyState checks and threw DoEvents into the loop to allow some processing to happen while the page loads. You were not taking full advantage of the parent ie object references in the With ... End With statement so I chopped off a few unnecessary ie references within the block.
As the Internet Explorer version is pertinent to this question, this is the version that the code was run on.