SPARQL group concat union - sparql

Question

I'm trying to GROUP_CONCAT a UNION of two sets of triples.
Is this not allowed?
PREFIX bo: <https://webfiles.uci.edu/jenniyk2/businessontology#>
SELECT (GROUP_CONCAT(DISTINCT ?m2;SEPARATOR = ", ") AS ?comp)
WHERE
{
{{SELECT ?m2 ?c ?p
WHERE { ?c rdfs:label ?m. ?c2 rdfs:label ?m2. ?so bo:owner ?p.
?so bo:sharesIn ?c. ?so2 bo:owner ?p. ?so2 bo:sharesIn ?c2. }
}
UNION
{SELECT ?m2 ?c ?p
WHERE { ?c rdfs:label ?m. ?c2 rdfs:label ?m2. ?dir bo:isPartOf ?c.
?dir bo:isDirectedBy ?p. ?dir2 bo:isPartOf ?c2. ?dir2 bo:isDirectedBy ?p.}
}}
GROUP BY ?c
HAVING (COUNT(?m2) >1)}
It says there's an error in the very last line.
Found group. Was expecting one of : BIND, BLANK_NODE_LABEL, DECIMAL,
DOUBLE, FALSE, FILTER, GEO, GRAPH, INTEGER, MINUS, NIL-SYMBOL, OPTIONAL,
Q_IRI_REF, QNAME, QNAME_NS, SERVICE, STRING_LITERAL1, STRING_LITERAL2,
STRING_LITERAL_LONG1, STRING_LITERAL_LONG2, TEXTINDEX, TRUE, UNION, VALUES,
VARNAME or punctuation '(', '+', '-', '.', '[', '[]', '{', '}'.

Answer 1

The GROUP BY and HAVING clauses should be outside the WHERE clause, not inside it as they currently are. To make your query syntactically correct, remove the closing } from the last line and add it on the line above your GROUP BY:
PREFIX bo: <https://webfiles.uci.edu/jenniyk2/businessontology#>
SELECT (GROUP_CONCAT(DISTINCT ?m2;SEPARATOR = ", ") AS ?comp)
WHERE
{
{{SELECT ?m2 ?c ?p
WHERE { ?c rdfs:label ?m. ?c2 rdfs:label ?m2. ?so bo:owner ?p.
?so bo:sharesIn ?c. ?so2 bo:owner ?p. ?so2 bo:sharesIn ?c2. }
}
UNION
{SELECT ?m2 ?c ?p
WHERE { ?c rdfs:label ?m. ?c2 rdfs:label ?m2. ?dir bo:isPartOf ?c.
?dir bo:isDirectedBy ?p. ?dir2 bo:isPartOf ?c2. ?dir2 bo:isDirectedBy ?p.}
}}}
GROUP BY ?c
HAVING (COUNT(?m2) >1)
As Joshua also indicated, the query can be written a lot simpler, but this should solve your immediate problem.

Answer 2

Jeen Broekstra's answer identifies the typographical problem that causes your syntax error, but I think it's worth mentioning that this query can be simplified a bit, because simpler code from the beginning makes it easier to spot typos and syntax errors when they arise. If I read it correctly, it looks like the body of the query simplifies to this:
?c rdfs:label ?m .
?c2 rdfs:label ?m2 .
{ ?so bo:owner ?p ;
bo:sharesIn ?c .
?so2 bo:owner ?p ;
bo:sharesIn ?c2 . }
union
{ ?dir bo:isPartOf ?c ;
bo:isDirectedBy ?p .
?dir2 bo:isPartOf ?c2 ;
bo:isDirectedBy ?p }
You're looking for a ?c that's connected by one of two certain types of path to a ?c2, and you want to group by ?c and concatenate the distinct labels of ?c2. I see two ways that this could be simplified further. The first is with the use of property paths, since you don't actually use the values of many of these variables. With property paths, the body could become:
?c rdfs:label ?m .
?c2 rdfs:label ?m2 .
{ ?c ^bo:sharesIn/bo:owner/^bo:owner/bo:sharesIn ?c2 }
union
{ ?c ^bo:isPartOf/bo:isDirectedBy/^bo:isDirectedBy/bo:isPartOf ?c2 }
As another alternative, since the structure of the pattern in each union alternative is similar, you could abstract a bit with values:
?c rdfs:label ?m .
?c2 rdfs:label ?m2 .
values (?sharesIn_isPartOf ?owner_isDirectedBy) {
(bo:sharesIn bo:owner)
(bo:isPartOf bo:isDirectedBy)
}
?x ?owner_isDirectedBy ?y ;
?sharesIn_isPartOf ?c .
?x2 ?owner_isDirectedBy ?y ;
?sharesIn_isPartOf ?c2 .