Importing Tables from Word to Excel by section - vba

Question

I currently have excel VBA code that opens a form where I can select a Word document. The code then can get one of 3 tables. The last, second to last and third to last. This worked because I can get the total table count and the 3 tables I needed were always the last ones in the documents. Now, the users are allowed to add tables after the 3 I need so I need to add some code to ensure I am getting the ones I want. This is where I have an issue.
My three tables are the only ones in document sections 10.1, 10.2 and 10.3. I don't know how to tell which table by index number is in these document sections. Is there a way I can find the table in Word document section 10.1?
My current code looks like:
Public Sub Get_TP_101(allbool As Boolean)
Dim wdDoc As Object
Dim wdFileName As Variant
Dim tableNo As Integer 'the table number the user selects
Dim iRow As Long 'row index in Excel
Dim iCol As Integer 'column index in Excel
Dim resultRow As Long
Dim tableStart As Integer
Dim tableTot As Integer ' the total number of tables in Document
Dim Ret As Variant
Dim sFullFileName As String
Dim pagenum As Integer
On Error Resume Next
wdFileName = Application.GetOpenFilename("Word files (*.doc*),*.doc*", , _
"Browse for the Test Procedure containing table to be imported")
If wdFileName = False Then Exit Sub '(user cancelled import file browser)
Set wdDoc = GetObject(wdFileName) 'open Word file
With wdDoc
tableTot = wdDoc.tables.Count
If tableTot = 0 Then
MsgBox "This document contains no tables", _
vbExclamation, "Import Word Table"
ElseIf tableTot > 1 Then
'tableNo = InputBox("This Word document contains " & tableNo & " tables." & vbCrLf & _
"Enter the table to start from", "Import Word Table", "1")
tableNo = tableTot - 2 '' get the third from last table by table index number
End If
resultRow = 1
'For tableStart = 1 To tableTot
With .tables(tableNo)
'copy cell contents from Word table cells to Excel cells
For iRow = 1 To .Rows.Count
For iCol = 1 To .Columns.Count
Worksheets("TP_10_1").Cells(resultRow, iCol) = WorksheetFunction.Clean(.Cell(iRow, iCol).Range.Text)
Next iCol
resultRow = resultRow + 1
Next iRow
End With
resultRow = resultRow + 1
'Next tableStart
End With
wdDoc.Close SaveChanges:=False
''Format
Worksheets("TP_10_1").Range("A2:I5000").WrapText = True
Worksheets("TP_10_1").Range("A2:I5000").VerticalAlignment = xlCenter
Worksheets("TP_10_1").Range("A2:I5000").Borders.LineStyle = xlContinuous
If allbool = False Then
MsgBox ("Done import Table 10.1")
End If

Answer 1

You can try something like this - the function will return the first table it finds in the section number you provide.
NOTE: there must be at least one table in the section, otherwise it may pick up the next table it finds, which may be in a following section...
Only lightly tested, so you need to do some of your own testing!
Sub TestGettingTable()
Dim tbl As Table
Set tbl = GetATable(ThisDocument, "2.1")
If Not tbl Is Nothing Then
Debug.Print tbl.Cell(1, 1).Range.Text
End If
End Sub
Function GetATable(d As Word.Document, listNum As String)
Dim p As Paragraph, rng As Object, tbl As Object
For Each p In d.Paragraphs
If p.Style = "Heading 2" And p.Range.ListFormat.ListType = _
wdListOutlineNumbering Then
If p.Range.ListFormat.ListString = listNum Then
Set rng = p.Range.GoTo(What:=wdGoToTable, Which:=wdGoToNext)
If rng.Tables.Count > 0 Then
Set tbl = rng.Tables(1)
Exit For
End If
End If 'matches number
End If 'is Heading 2
Next p
Set GetATable = tbl
End Function