VBA - Get the Second-Last modified file (FSO) without built-in functions - vba

Question

I'm trying to get the one Before the Last modified File in a Folder Using Excel VBA, I have managed to Get the Last Modified File, But I couldn't get the second one.
Herein Below the code I used to get the Last Modified File, without using system Functions or built-in function.
Sub LastFileModified()
Dim fso As New Scripting.FileSystemObject
Dim fill As Scripting.File
Dim i As Integer
Dim ForStep As Integer
Dim Arr() As Variant
ReDim Arr(fso.GetFolder("C:\Users\Shahim\Desktop\xxxx").Files.Count - 1, 1) As Variant
i = 0
For Each fill In fso.GetFolder("C:\Users\Shahim\Desktop\xxxx").Files
Arr(i, 0) = fill.Name
Arr(i, 1) = CDbl(fill.DateLastModified)
i = i + 1
Next fill
Dim filename As String
Dim Initializer As Double
Initializer = Arr(0, 1)
For ForStep = LBound(Arr) To UBound(Arr)
If Arr(ForStep, 1) > Initializer Then
Initializer = Arr(ForStep, 1)
filename = Arr(ForStep, 0)
End If
Next ForStep
Debug.Print filename
Erase Arr
End Sub

Answer 1

Sub SecodLastModified()
Const FLDR_PATH As String = "C:\Test"
Dim i As Long, j As Long, fileArr() As String, maxFiles As Long
Dim fso As Variant, fldr As Variant, f As Variant, l1 As String, l2 As String
Set fso = CreateObject("Scripting.FileSystemObject")
Set fldr = fso.GetFolder(FLDR_PATH)
maxFiles = fldr.Files.Count
ReDim fileArr(1 To maxFiles, 1 To 2)
i = 1
For Each f In fldr.Files
fileArr(i, 1) = f.Name
fileArr(i, 2) = f.DateLastModified
i = i + 1
Next
For i = 1 To maxFiles
For j = i + 1 To maxFiles
If fileArr(j, 2) > fileArr(i, 2) Then
l1 = fileArr(i, 2)
l2 = fileArr(i, 1)
fileArr(i, 2) = fileArr(j, 2)
fileArr(i, 1) = fileArr(j, 1)
fileArr(j, 2) = l1
fileArr(j, 1) = l2
End If
Next
Next
MsgBox fileArr(2, 1)
End Sub

Answer 2

The original answer did not work for me for two reasons.
fileArr(i,2) was not declared a date, and occassionally Excel could not decipher what was the greater date. When I tried to dim this as a date, it said I could not dim an Array.
If temporary files were included, it did not skip over those files.
Here is what worked for me.
Function SecodLastModified(Directory)
Dim FileSys As FileSystemObject
Dim objFile As File, objFile1 As File
Dim myFolder
Dim strFilename As String, strFolder As String, myDir As String
Dim strFilenameFirst As String, strFilenameSecond As String, strFilenameSecond1 As String
Dim dteFile As Date, dteFileSecond1 As Date, dteFileFirst As Date, dteFileSecond As Date
Dim openLastFile
'set up filesys objects
Set FileSys = New FileSystemObject
Set myFolder = FileSys.GetFolder(Directory)
dteFileSecond1 = DateSerial(1900, 1, 1)
dteFile = DateSerial(1900, 1, 1)
'loop through each file and get date last modified. If largest date then store Filename
For Each objFile In myFolder.Files
For Each objFile1 In myFolder.Files
' To prevent opening temporary files
If objFile1.Name Like "*.xlsx" And Left(objFile1.Name, 2) <> "~$" Then
If objFile1.DateLastModified > objFile.DateLastModified Then
dteFileSecond = objFile.DateLastModified
strFilenameSecond = objFile.Name
dteFileFirst = objFile1.DateLastModified
strFilenameFirst = objFile1.Name
' If second file date is greater than current second file, store away as the second file
If dteFileSecond > dteFileSecond1 Then
dteFileSecond1 = objFile.DateLastModified
strFilenameSecond1 = objFile.Name
End If
End If
End If
Next
Next objFile
Set SecodLastModified = Workbooks.Open(Directory & "\" & strFilenameSecond1)
Set FileSys = Nothing
Set myFolder = Nothing
End Function