Sql Statement Custom Class - sql

Question

I am new to programming, I tried to create a sub that contains a SQL statement in it using parameterized query. My code is not working, there might something lacking to it or am I doing it wrong.
My connection string is in the app.config:
<?xml version="1.0" encoding="utf-8" ?>
<configuration>
<connectionStrings>
<add name = "DBCS"
connectionString ="Data Source=Mic-PC\Developer; Initial Catalog=Customer; User Id = sa; Password=1224334;"
providerName ="System.Data.SqlClient" />
</connectionStrings>
</configuration>
I create a class called SELECTCLASS and here is the content
Imports System.Configuration
Imports System
Imports System.Threading.Tasks
Imports System.ComponentModel
Imports System.Data
Imports System.Drawing
Imports System.Linq
Imports System.Text
Imports System.Windows.Forms
Imports System.Data.SqlClient
Public Class SelectClass
Public Sub searchData(search As String, LastName As String, FirstName As String, MiddleInitial As String, Age As String, Address As String)
Dim CS As String = ConfigurationManager.ConnectionStrings("DBCS").ConnectionString
Using con As New SqlConnection(CS)
Dim cmd As SqlCommand = New SqlCommand("spGetCustomerByName", con)
cmd.CommandType = CommandType.Storedprocedure
cmd.Parameters.AddWithValue("#FirstName", "%" + search + "%")
con.Open()
Using rdr = cmd.ExecuteReader()
If rdr.HasRows Then
While rdr.Read()
LastName = rdr.GetString(1).ToString
FirstName = rdr.GetString(2).ToString
MiddleInitial = rdr.GetString(3).ToString
Age = rdr.GetString(4).ToString
Address = rdr.GetString(5).ToString
End While
End If
End Using
End Using
End Sub
End Class
And here is the code for my Windows Form:
Imports System.Configuration
Imports System
Imports System.Threading.Tasks
Imports System.ComponentModel
Imports System.Data
Imports System.Drawing
Imports System.Linq
Imports System.Text
Imports System.Windows.Forms
Imports System.Data.SqlClient
Public Class SELECTVB
Dim SelectData As New SelectClass
Private Sub cmdSearch_Click(sender As Object, e As EventArgs) Handles cmdSearch.Click
SelectData.searchData(txtsearch.Text, TextBox1.Text.ToString, TextBox2.Text.ToString, TextBox3.Text.ToString, TextBox4.Text.ToString, TextBox5.Text.ToString)
End Sub
Any help is greatly appreciated, thank you in advance!

Answer 1

I think I see two problem with your code, neither of which have anything to do with ADO or SQL. The problems are related to the way that the data that is read from the database is being passed back to the calling method. I suspect that the searchData method is successfully reading the data from the query results (though you would need to confirm this using the debugger by setting a break-point, stepping through the method, and inspecting the variables' values).
The first problem I see is that you are passing the result of the TextBox.Text.ToString method rather than the TextBox.Text property itself. In other words, you should be calling the searchData method like this:
Private Sub cmdSearch_Click(sender As Object, e As EventArgs) Handles cmdSearch.Click
SelectData.searchData(txtsearch.Text, TextBox1.Text, TextBox2.Text, TextBox3.Text, TextBox4.Text, TextBox5.Text)
End Sub
Secondly, you are attempting to reassign the reference of those Text arguments from inside the searchData method, but the parameters are not declared ByRef. If you want to do it that way, you would need to change the parameters of the method to ByRef, like this:
Public Sub searchData(search As String, ByRef LastName As String, ByRef FirstName As String, ByRef MiddleInitial As String, ByRef Age As String, ByRef Address As String)
However, none of that would be a problem if you returned the results via the function's return value rather than changing the values of the parameters. Most developers, including myself, discourage using ByRef parameters in this manner because it's unexpected behavior. Typically parameters should be reserved for inputs rather than outputs. For instance, if you created a class like this:
Public Class Customer
Public Property LastName As String
Public Property FirstName As String
Public Property MiddleInitial As String
Public Property Age As String
Public Property Address As String
End Class
Then you could change your search method to return a Customer object, like this:
Public Function SearchData(search As String) As Customer
Dim result As Customer = Nothing
Dim CS As String = ConfigurationManager.ConnectionStrings("DBCS").ConnectionString
Using con As New SqlConnection(CS)
Using cmd As SqlCommand = New SqlCommand("spGetCustomerByName", con)
cmd.CommandType = CommandType.Storedprocedure
cmd.Parameters.AddWithValue("#FirstName", "%" & search & "%")
con.Open()
Using rdr = cmd.ExecuteReader()
If rdr.HasRows Then
If rdr.Read() Then
result = New Customer()
result.LastName = rdr.GetString(1)
result.FirstName = rdr.GetString(2)
result.MiddleInitial = rdr.GetString(3)
result.Age = rdr.GetString(4)
result.Address = rdr.GetString(5)
End If
End If
End Using
End Using
End Using
Return result
End Sub
And then you could call it like this:
Private Sub cmdSearch_Click(sender As Object, e As EventArgs) Handles cmdSearch.Click
Dim c As Customer = SelectData.searchData(txtsearch.Text)
If c IsNot Nothing Then
TextBox1.Text = c.LastName
TextBox2.Text = c.FirstName
TextBox3.Text = c.MiddleInitial
TextBox4.Text = c.Age
TextBox5.Text = c.Address
End If
End Sub
However, given the context of what you are doing, it seems likely that your method ought to be returning a list of customers rather than just a single one.
If making these changes still does not fix the problem, stepping through the search method with the debugger will be your best chance of solving the problem. It could be that the stored procedure is returning no matches, or it's returning a different number of columns than you are expecting, or it could be returning a column with a data-type other than a string (like the age column might be an integer, for instance). It's impossible to say, given only the information that you've provided, what the precise problem with the data access code would be.