Updating an excel worksheet from another sheet, depending on a value - vba

Question

I am trying to create an If Statement that lets me send an number and a value to another workbook deepening on a value in a 3rd cell (weather the cell is is True or False"). The code that I want to run if the statement is True is below. I have tested this code, and it works, I just want it to happen if the third cell in the row is True. It then needs to carry the information from the number and value rows where the value is true into the function below.
Dim itemName As String
Dim itemPrice As String
Dim myData As Workbook
Worksheets("Sheet1").Select
InvoiceNumber = Range("A2")
qty = Range("B2")
updated = Range("C2")
Set myData = Workbooks.Open("HD:Users:user:Desktop:Inventory.xlsm")
Worksheets("Orders").Select
Worksheets("Orders").Range("a15").Select
RowCount = Worksheets("Orders").Range("a15").CurrentRegion.Rows.Count
With Worksheets("Orders").Range("a15")
.Offset(RowCount, 0) = InvoiceNumber
.Offset(RowCount, 1) = qty
.Offset(RowCount, 2) = updated
End With

Answer 1

Your code looks like it could use another loop to go through a series of rows but I suppose that it may be a case where only a single operation is required.
Dim itemName As String
Dim itemPrice As String
Dim myData As Workbook
Dim sInvoiceNumber As String, dQty As Double, bUpdated As Boolean, iRowCount As Long
With Worksheets("Sheet1")
sInvoiceNumber = .Range("A2").Value
dQty = .Range("B2").Value
bUpdated = CBool(.Range("C2").Value)
If bUpdated Then
Set myData = Workbooks.Open("HD:Users:user:Desktop:Inventory.xlsm")
With myData.Worksheets("Orders").Range("a15")
iRowCount = .CurrentRegion.Rows.Count
.Offset(iRowCount, 0) = sInvoiceNumber
.Offset(iRowCount, 1) = dQty
.Offset(iRowCount, 2) = bUpdated
End With
myData.Close True '<-save and close the workbook
.Range("C2") = Not bUpdated '<- reset the updated field
End If
End With
Rather than loop through the rows, a bulk transfer operation can be used by filtering the data.
Dim itemName As String
Dim itemPrice As String
Dim myData As Workbook
Dim iRowCount As Long
With Worksheets("Sheet1")
If .AutoFilterMode Then AutoFilterMode = False
With .Cells(1, 1).CurrentRegion
.AutoFilter Field:=3, Criteria1:="TRUE"
With .Offset(1, 0).Resize(.Rows.Count - 1, 3)
If CBool(Application.Subtotal(103, .Columns(1))) Then
Set myData = Workbooks.Open("HD:Users:user:Desktop:Inventory.xlsm")
.Cells.Copy Destination:=myData.Sheets("Orders").Cells(Rows.Count, 1).End(xlUp).Offset(1, 0)
myData.Close True '<-save and close the workbook
.Columns(3).Cells = False
End If
End With
.AutoFilter Field:=3
End With
If .AutoFilterMode Then AutoFilterMode = False
End With
That filters on a worksheet cell value of TRUE in column C.

Answer 2

You should read up on if statements. I'm guessing you'd be able to figure it out from here:
http://www.techonthenet.com/excel/formulas/if_then.php
Basically, just use updated as the test condition in your if statement.
Dim itemName As String
Dim itemPrice As String
Dim myData As Workbook
Worksheets("Sheet1").Select
InvoiceNumber = Range("A2")
qty = Range("B2")
updated = Range("C2")
If updated Then
Set myData = Workbooks.Open("HD:Users:user:Desktop:Inventory.xlsm")
Worksheets("Orders").Select
Worksheets("Orders").Range("a15").Select
RowCount = Worksheets("Orders").Range("a15").CurrentRegion.Rows.Count
With Worksheets("Orders").Range("a15")
.Offset(RowCount, 0) = InvoiceNumber
.Offset(RowCount, 1) = qty
.Offset(RowCount, 2) = updated
End With
End If