Export Excel data to INI file - vba

Question

Summary: Export values from a column to an INI file.
I have a spreadsheet that has data in column M and I want to copy the data from column M to a an .ini file. Each cell in the column contains a file name of a person's progress report. This data would be like:
Smith, John Progress Report 2015-07-30.doc
The .ini file would be something like:
[Settings]
smith=Smith, John Progress Report 2015-07-30
I would prefer to have the key in lowercase and remove the ".doc" from the filename.
I want to export those filenames to the .ini and use the last name as the key. I don't really know where to start on this. Excel doesn't have its own access to writing to .ini files, but it can use Word or Windows API from what I read on the internet. Also, I guess Excel can just simply append the data to the .ini as a text file.
So I have some ideas, but I didn't see anything else on StackOverflow that specifically worked on this task to get me started. If you find something that does this specifically then that would be great. Otherwise, if someone can get me started on the code to complete this task, I would really appreciate it.

Answer 1

This should get you started. It uses the value from M1 and writes it to an .ini file. Just add a loop to iterate all your rows and you should be all set.
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long
Public Sub ExportToIni()
Dim re As Object
Set re = CreateObject("VBScript.RegExp")
re.IgnoreCase = True
re.Pattern = "^(([^,]+),.+)\.doc$"
Dim strText As String
strText = Trim$(Cells(1, 13)) ' [M1]
Dim m As Object, c As Object, strLastName As String, strFileName As String
If re.Test(strText) Then
Set c = re.Execute(strText)
strFileName = c(0).SubMatches(0)
strLastName = LCase$(c(0).SubMatches(1))
WritePrivateProfileString "Settings", strLastName, strFileName, "c:\path\to\your.ini"
End If
End Sub
The .ini file:
[Settings]
smith=Smith, John Progress Report 2015-07-30

Answer 2

This will do what you want:
Sub SaveIni()
Dim c as range
Open "C:\Temp\Output.ini" For Output As #1
For Each c In Range("M1:M" & Range("M" & Rows.Count).End(xlUp).Row)
Print #1, LCase(Split(c, ",")(0)) & "=" & Split(c, ".doc")(0)
Next
Close #1
End Sub
Uses split on the comma to get the name and lower cases it then adds an = then splits the initial string on .doc to drop that off, we could have used replace here if you so wish.
Here is my test input:
Smith, John Progress Report 2015-07-30.doc
davis, andrew Progress Report 2015-07-30.doc
MALCOLMSON, Aaron File 20jio32ejo23oji32eojie23oj23eoje23joe3e23oji-07-30.doc
Green, Frank Report 20-07-30.doc
Here is my ini file:
smith=Smith, John Progress Report 2015-07-30
davis=davis, andrew Progress Report 2015-07-30
malcolmson=MALCOLMSON, Aaron File 20jio32ejo23oji32eojie23oj23eoje23joe3e23oji-07-30
green=Green, Frank Report 20-07-30
Note, this will OVERWRITE your ini file if it already exists If you wish to append then change this:
Open "C:\Temp\Output.ini" For Output As #1
to this:
Open "C:\Temp\Output.ini" For Append As #1