eliminating all values that occur in all files in folder with awk - awk

Question

I have a folder with several files of which I want to eliminate all of the terms that they have in common using awk.
Here is the script that I have been using:
awk '
FNR==1 {
if (seen[FILENAME]++) {
firstPass = 0
outfile = FILENAME "_new"
}
else {
firstPass = 1
numFiles++
ARGV[ARGC++] = FILENAME
}
}
firstPass { count[$2]++; next }
count[$2] != numFiles { print > outfile }
' *
An example of the information in the files would be:
File1
3 coffee
4 and
8 milk
File2
4 dog
2 and
9 cat
The output should be:
File1_new
3 coffee
8 milk
File2_new
4 dog
9 cat
It works when I use a small number of files (i.e. 10), but when I start to increase that number, I get the following error message:
awk: file20_new makes too many open files input record number 27, file file20_new source line number 14
Where is the error coming from when I use larger amounts of files?
My main goal is to run this script over all of the files in a folder to generate new files that do not contain any words that occur in all of the files in the folder.

Answer 1

When you use >, a file is opened for writing (and truncated). As suggested in the comments, you need to close your files as you go along. Try something like this:
awk '
FNR==1 {
if (seen[FILENAME]++) {
firstPass = 0
if (outfile) close(outfile) # <-- close the previous file
outfile = FILENAME "_new"
}
else {
firstPass = 1
numFiles++
ARGV[ARGC++] = FILENAME
}
}
firstPass { count[$2]++; next }
count[$2] != numFiles { print > outfile }
' *