Copying from outlook - vba

Question

I wrote a VBA program that is supposed to download and copy emails from my outlook account and paste them onto my excel spreadsheet. I would like to run this program daily so obviously, I don't want this to go through my entire mailbox every time. So rather, I want it to start searching for emails after the date of the last copied email. But when I try to run this, it doesn't work. It keeps going through the entire mailbox and loops backward. So for instance, it will look for 6/29/2015 email and then move on to 6/28/2015, 6/27/2015 and so on, which is the opposite of what I am trying to to accomplish. I am not sure what I am doing wrong. Any help would be extremely appreciated. Thanks in advance!
Sub Download_Outlook_Mail_To_Excel()
Dim Folder As Outlook.MAPIFolder
Dim iRow As Integer, oRow As Integer, fRow As Integer
Dim MailBoxName As String, Pst_Folder_Name As String
MailBoxName = "officework#gmail.com"
Pst_Folder_Name = "Inbox" 'Sample "Inbox" or "Sent Items"
Set Folder =
Outlook.Session.Folders(MailBoxName).Folders(Pst_Folder_Name)
If Folder = "" Then
MsgBox "Invalid Data in Input"
GoTo end_lbl1:
End If
ThisWorkbook.Sheets(1).Activate
Folder.Items.Sort "Received"
' Insert Column Headers
' ThisWorkbook.Sheets(1).Cells(1, "A") = "Sender"
' ThisWorkbook.Sheets(1).Cells(1, "D") = "Subject"
' ThisWorkbook.Sheets(1).Cells(1, "F") = "Date"
' ThisWorkbook.Sheets(1).Cells(1, "J") = "EmailID"
' ThisWorkbook.Sheets(1).Cells(1, "M") = "Body"
LastRow = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
vDate = Cells(LastRow, "F").Value
For fRow = 1 To Folder.Items.Count
If Folder.Items.Item(fRow).ReceivedTime >= vDate Then
For iRow = LastRow To Folder.Items.Count
oRow = iRow + 1
ThisWorkbook.Sheets(1).Cells(oRow, 1).Select
ThisWorkbook.Sheets(1).Cells(oRow, "A") = Folder.Items.Item(iRow).SenderName
ThisWorkbook.Sheets(1).Cells(oRow, "D") = Folder.Items.Item(iRow).Subject
ThisWorkbook.Sheets(1).Cells(oRow, "F") = Folder.Items.Item(iRow).ReceivedTime
ThisWorkbook.Sheets(1).Cells(oRow, "J") = Folder.Items.Item(iRow).SenderEmailAddress
ThisWorkbook.Sheets(1).Cells(oRow, "M") = Folder.Items.Item(iRow).Body
Next iRow
End If
Next fRow
MsgBox "Outlook Mails Extracted to Excel"
end_lbl1:
End Sub

Answer 1

I have noticed the following lines of code:
For fRow = 1 To Folder.Items.Count
If Folder.Items.Item(fRow).ReceivedTime >= vDate Then
It looks like you are iterating through each item in the folder and check the RecievedTime property. Iterating through all items in the folder is not a really good idea. So, I'd suggest using the Find/FindNext or Restrict methods of the Items class instead. The latter applies a filter to the Items collection, returning a new collection containing all of the items from the original that match the filter. So, you just need to iterate through a small number of items and do whatever you need without checking properties each time. You can read more about these methods in the following articles:
How To: Use Find and FindNext methods to retrieve Outlook mail items from a folder (C#, VB.NET)
How To: Use Restrict method to retrieve Outlook mail items from a folder
Dates and times are typically stored with a Date format, but the Find and Restrict methods require that the date and time be converted to a string representation. To make sure that the date is formatted as Microsoft Outlook expects, use the Format function (available in VBA):
sFilter = "[RecevedTime] > '" & Format("6/29/2015 9:30pm", "ddddd h:nn AMPM") & "'"
Also you may find the AdvancedSearch method of the Application class helpful. he key benefits of using the AdvancedSearch method in Outlook are:
The search is performed in another thread. You don’t need to run another thread manually since the AdvancedSearch method runs it automatically in the background.
Possibility to search for any item types: mail, appointment, calendar, notes etc. in any location, i.e. beyond the scope of a certain folder. The Restrict and Find/FindNext methods can be applied to a particular Items collection (see the Items property of the Folder class in Outlook).
Full support for DASL queries (custom properties can be used for searching too). You can read more about this in the Filtering article in MSDN. To improve the search performance, Instant Search keywords can be used if Instant Search is enabled for the store (see the IsInstantSearchEnabled property of the Store class).
You can stop the search process at any moment using the Stop method of the Search class.
See Advanced search in Outlook programmatically: C#, VB.NET for more information.
Finally, take a look at the Getting Started with VBA in Outlook 2010 article in MSDN which explains basics of Outlook programming.

Answer 2

I started my answer before Eugene posted his but finished later because I was trying to do other things in parallel. His answer provides good advice and your code will be better for following that advice. My code is much closer to yours so you might find it easier to understand at this stage in your development as a VBA programmer.
I think I know what is wrong with your code but first some general advice.
Placing Option Explicit at the top of a module means that all variables have to be properly declared. Some of your variables are defined but others are not. If you use a variable that has not been declared with a Dim statement, VBA will declare it for you as a Variant. A variable of type Variant can take any type of value which is slow and error prone. Consider:
X = 5
X = “A”
In the above code, I have not declared X so it is a Variant. Setting X to 5 then “A” is valid code with Variants. Placing these two statements together makes my mistake easy to spot. But if I use X throughout my macro, a statement that sets X to the wrong type of value may be difficult to spot and can lead to strange failures.
Dim X as Long
X = 5
X = “A”
Adding the Dim statement means the interpreter will reject X = “A” at runtime.
If you indent code within For-Next loops and If-Else-EndIf blocks, it becomes much easier to follow the code. I suspect this is one of your problems.
Your other problem is the use of meaningless names. You have iRow, oRow, fRow and LastRow. Perhaps there is a system behind these names but it does not appear so. If there is a system, will you remember that system when you need to update this macro in six or twelve months? I have a system of naming variables which means I can look at macros I wrote ten years ago and immediately know what all the variables are.
My variable names are all a sequence of words or abbreviations. The first word is always what I am using the variable for so “Row” means it’s a Row number. The next word defines what it is a row of. You have rows of an Excel sheet and an Outlook folder so perhaps “RowSht” and “RowFld” or “RowEx” and “RowOut”. Sometimes I need a fourth word but usually three is enough. For a row number, the third word will typically be “Crnt” (for current), First, Last or Next.
There are other general points I could make about your code but I think that is enough for now.
I believe the major problem is that you have both an outer and an inner loop through the rows of the folder. Your choice of variable names makes this difficult to identify,
Issue 1
Dim RcvdPrevLatest as Date
Dim RowShtCrnt as Long
RowShtCrnt = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
RcvdPrevLatest = Cells(LastRow, "F").Value
RowShtCrnt = RowShtCrnt + 1
You only need one variable for the rows of you worksheet so I have named it RowShtCrnt. I have declared it as Long because Integer declares a 16-bit variable which requires special processing on 32 and 64-bit computers and because Integer only allows for 64K rows which is less than the maximum number of rows unless you are using Excel 2003.
I have declared a variable for your date. My system forces me to think about the purpose of my variables. It holds a Received Date/Time so the first word is “Rcvd”. The particular Received Date/Time being held is the latest Received Date/Time from the previous run of the macro.
Issue 2
You have:
For fRow = 1 To Folder.Items.Count
If Folder.Items.Item(fRow).ReceivedTime >= vDate Then
For iRow = LastRow To Folder.Items.Count
The outer For-Loop searches down the folder for a mail item with a received date/time later than the previous latest. The inner For-Loop then outputs every mail item below it in the folder so you are outputting mail items repeatedly. The inner For-Loop starts iRow at the last row of the worksheet and continues to the last row of the folder. You choice of names makes it difficult to spot that the start and end values do not relate to one another. Since fRow is not used within the inner loop, its value has no effect on the mail items selected for output.
I have not tested this code but it will be closer to what you want:
Dim RowFldCrnt as Long
For RowFldCrnt = 1 To Folder.Items.Count
If Folder.Items.Item(RowFldCrnt).ReceivedTime > RcvdPrevLatest Then
ThisWorkbook.Sheets(1).Cells(RowShtCrnt, "A") = _
Folder.Items.Item(RowFldCrnt).SenderName
ThisWorkbook.Sheets(1).Cells(RowShtCrnt, "D") = _
Folder.Items.Item(RowFldCrnt).Subject
: : :
RowShtCrnt = RowShtCrnt + 1
Next