sending multiple parameters from form to report query - vba

Question

Trying to send three variables (startDate, endDate, division) from a chooser form to a report query. Sent the three variables through an doCommand.OpenReport command, then unpacked them in the Load event of the report. I'm not sure what to assign them to in the report to use them in the query.
In the form:
Private Sub btn_bud_sum_exp_div_Click()
Dim StrWhereCondition
Dim a As String
Dim b As String
Dim c As String
a = Me.txtStartDate.Value
b = Me.txtEndDate.Value
c = Me.lstDivision.Value
StrWhereCondition = a & "|" & b & "|" & c
'StrWhereCondition = "[accounting start date] = " & Me.txtStartDate.Text
DoCmd.OpenReport "FY15 Budget Line Sum - Expenditures - Div", , , StrWhereCondition
End Sub
In the Load event of the report:
Private Sub Report_Load()
Dim dtStartDate As Date
Dim dtEndDate As Date
Dim strDivision As String
If Not IsNull(Me.OpenArgs) Then
dtStartDate = parsetext(OpenArgs, 0)
dtEndDate = parsetext(OpenArgs, 1)
strDivision = parsetext(OpenArgs, 2)
End If
End Sub
In the report query:
SELECT
*
FROM
budget b
WHERE
(b.start_date between dtStartDate AND dtEndDate) AND d.division = strDivision

Answer 1

If you open the report with a filter string, you can delete all the OnLoad stuff of the report:
Private Sub btn_bud_sum_exp_div_Click()
Dim StartDate As String
Dim EndDate As String
Dim Division As String
Dim WhereCondition As String
StartDate = Format(Me!txtStartDate.Value, "yyyy\/mm\/dd")
EndDate = Format(Me!txtEndDate.Value, "yyyy\/mm\/dd")
Division = Me!lstDivision.Value
WhereCondition = "start_date between #" & StartDate & "# and #" & EndDate & "# and division = " & Division & ""
' or:
' WhereCondition = "[accounting start date] between #" & StartDate & "# and #" & EndDate & "# and division = " & Division & ""
' or, if division is text:
' WhereCondition = "start_date between #" & StartDate & "# and #" & EndDate & "# and division = '" & Division & "'"
DoCmd.OpenReport "FY15 Budget Line Sum - Expenditures - Div", , , WhereCondition
End Sub