MouseLeave and Enter on Form - vb.net

Question

I am trying to make a form fade away from the taskbar if the user is not currently hovering over the form with the mouse. (The form contains hyperlinks). On the adverse, i want the form to reset to its original position if the mouse comes back to the form. However, for whatever reason, it seems as thought the enter and leave evens fire in sync when either even occurs. If i leave the form with my mouse, both events fire. If i enter the form, both events fire. What is wrong?
Sub FormLeave()
MouseForm = False
Do Until y = Screen.PrimaryScreen.WorkingArea.height + 50
Sleep(10)
y = y + 1
Me.Location = New Point(x, y)
If MouseForm = True Then
Exit Sub
End If
Loop
End Sub
Sub FormEnter()
MouseForm = True
Me.Visible = True
x = Screen.PrimaryScreen.WorkingArea.Width - Me.Width
y = Screen.PrimaryScreen.WorkingArea.Height - Me.Height
Me.Location = New Point(x, y)
End Sub

Answer 1

Animation is best done with a timer (i.e. event driven) rather than sleeping.
You have to make sure the cursor has left the boundary of the form, as a leave event is fired on the form when the mouse enters a control within the form.
I added a longer delay when the mouse initially leaves the form as otherwise it is really annoying.
To demonstrate, use this code with a new Windows Forms project. Add controls to the form if you want to confirm it does not misbehave when you put the mouse over a control on the form.
Public Class Form1
Dim x As Integer
Dim y As Integer
Dim tim As Timer
Sub MoveFormAway(sender As Object, e As EventArgs)
' called on timer tick event
Dim destY = Screen.PrimaryScreen.WorkingArea.Height - 100
If y >= destY Then
tim.Enabled = False
Exit Sub
End If
' interval for form position changes
tim.Interval = 10
y += 2
Me.Location = New Point(x, y)
End Sub
Sub FormBodyLeave(sender As Object, e As EventArgs)
' If the mouse has not left the outside of the form,
' i.e. it has entered a control on the form, then exit:
If Me.ClientRectangle.Contains(PointToClient(Cursor.Position)) Then
Exit Sub
End If
If tim Is Nothing OrElse Not tim.Enabled Then
x = Me.Location.X
y = Me.Location.Y
tim = New Timer
' initial interval until form starts running away
tim.Interval = 1000
AddHandler tim.Tick, AddressOf MoveFormAway
tim.Enabled = True
End If
End Sub
Sub FormBodyEnter(sender As Object, e As EventArgs)
If tim IsNot Nothing Then
tim.Enabled = False
End If
MoveToDefaultPosition()
End Sub
Sub AddFormDisappearingHandlers()
AddHandler Me.MouseEnter, AddressOf FormBodyEnter
AddHandler Me.MouseLeave, AddressOf FormBodyLeave
End Sub
Sub MoveToDefaultPosition()
x = Screen.PrimaryScreen.WorkingArea.Width - Me.Width
y = Screen.PrimaryScreen.WorkingArea.Height - Me.Height
Me.Location = New Point(x, y)
End Sub
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
MoveToDefaultPosition()
AddFormDisappearingHandlers()
End Sub
Private Sub Form1_FormClosing(sender As Object, e As FormClosingEventArgs) Handles MyBase.FormClosing
' Tidy up.
If tim IsNot Nothing Then
tim.Dispose()
End If
End Sub
End Class