VBA inputbox input validation issue for excel - vba

Question

Excel requirement: User to enter a number via an input dialog. Rows containing that number in the designated (hard-coded) column of the current selection are to be deleted.
Regarding input validation, I have not come up with or found a solution that covers all these issues:
Empty input is not to be accepted. (Some variations I've tried treat it as zero.) Preferrably an error would be shown, but ok to treat like the cancel button if there's no better way.
Cancel button is to cancel dialog without further messages. (In the code below, it results in "invalid input."
A zero value entry must be permitted. (Not treated as cancel like in some of my attempts)
A zero value when there is no zero to match must show "Nothing to delete."
A row is not to be deleted if the cell is empty. ie. Do not match zero with an empty cell.
I've tried variations of code, but at least one issue remains in each. The code below is modified from my original post. It's my best solution so far. The only issue is that cancel results in "No value entered."
Thanks.
Sub DeleteRows()
On Error GoTo InvalidInput
Dim InputRng As Range
Dim DeleteRng As Range
Dim DeleteNum As Double
Dim DeleteV As Variant
Dim CountDelete As Long
Dim CountAreas As Long
Dim Str As String
Set InputRng = Application.Selection.Rows
DeleteV = Application.InputBox("Match Value", "Delete Rows")
'TODO Ultimate solution: Check for cancel so as not to result in "No value entered".
'NOTE: If DeleteV = Empty is true upon cancel
'NOTE this unwantingly matches zero: If DeleteV = False Then Exit Sub
'Check something was entered
If DeleteV = Empty Then
MsgBox ("No value entered.")
Exit Sub
End If
DeleteNum = CDbl(DeleteV)
'Accumulate what is to be deleted
For Each r In InputRng.Rows
'Only if cell is a number
If Not IsEmpty(r.Cells(3)) Then
If IsNumeric(r.Cells(3).Value) Then
If r.Cells(3).Value = DeleteNum Then
If DeleteRng Is Nothing Then
Set DeleteRng = r
Else
Set DeleteRng = Application.Union(DeleteRng, r)
End If
End If
End If
End If
Next
If DeleteRng Is Nothing Then
MsgBox ("Nothing to delete.")
Exit Sub
End If
CountDelete = 0
'The range may contain separated areas,
'so loop through each area to accumulate the total count
For Each a In DeleteRng.Areas
CountDelete = CountDelete + a.Rows.Count
Next a
If CountDelete > 1 Then
Str = " rows."
Else
Str = " row."
End If
'Confirm delete
If MsgBox("Confirm delete " & CountDelete & Str, vbYesNo) = vbYes Then
DeleteRng.EntireRow.Delete
End If
Exit Sub
InvalidInput:
MsgBox ("Invalid input.")
End Sub

Answer 1

Try it with Type 1
Syntax:
expression.InputBox(Prompt, Title, Default, Left, Top, HelpFile, HelpContextID, Type)
Type:
The following table lists the values that can be passed in the Type argument. Can be one or a sum of the values. For example, for an input box that can accept both text and numbers, set Type to 1 + 2.
Value Meaning
0 A formula
1 A number
2 Text (a string)
4 A logical value (True or False)
8 A cell reference, as a Range object
16 An error value, such as #N/A
64 An array of values
DeleteV = Application.InputBox("Match Value", "Delete Rows", Type:=1)
Sub Sample()
'~~> Only valid numbers are allowed including 0
'~~> Empty input will not to be accepted.
DeleteV = Application.InputBox("Match Value", "Delete Rows", Type:=1)
'~~> If user presses Cancel
If DeleteV = "False" Then Exit Sub
'~~> If user enters a number else it won't execute this
If DeleteV >= 0 Then
'
'~~> Rest of your code
'
End If
End Sub
Your Points which are taken care of
Empty input is not to be accepted.
Cancel button is to cancel dialog without further messages.
A zero value entry must be permitted. (Not treated as cancel like in some of my attempts)
A zero value when there is no zero to match must show "Nothing to delete." Can be handled inside the If-EndIf
A row is not to be deleted if the cell is empty. ie. Do not match zero with an empty cell. Can be handled inside the If-EndIf