Getting each field following regular pattern with awk - awk

Question

Having an input text file as below:
1234, aaa = 34 </T><AT/>X_CONST = 34 </T><AT/>AAA_Z = 3 </T><AT/>Y_CONST = 34 </T><AT/>FOUND_ME_1 = 5 </T><AT/>BBB_X = 3 </T><AT/>CCC_X = 8 </T><AT/>FOUND_ME_2 = 8 </T><AT/>FOUND_ME_3 = 8 </T><AT/>RRR_Z = 3 </T><AT/>T_CONST = 37 </T><AT/>FOUND_ME_4 = 10 </T><AT/>X_CONST = 34
7844, aaa = 33 </T><AT/>X_CONST = 21 </T><AT/>AAA_Z = 3 </T><AT/>R_CONST = 34 </T><AT/>FOUND_ME_1 = 50 </T><AT/>BBB_X = 3 </T><AT/>CCC_X = 8 </T><AT/>FOUND_ME_2 = 81 </T><AT/>FOUND_ME_3 = 8 </T><AT/>RRR_Z = 3 </T><AT/>T_CONST = 37 </T><AT/>X_CONST = 55
8888, aaa = 31 </T><AT/>X_CONST = 21 </T><AT/>AAA_Z = 3 </T><AT/>R_CONST = 34 </T><AT/>FOUND_ME_1 = 54 </T><AT/>BBB_Z = 3 </T><AT/>CCC_X = 8 </T><AT/>FOUND_ME_2 = 81 </T><AT/>FOUND_ME_3 = 8 </T><AT/>RRR_Z = 3 </T><AT/>T_CONST = 37 </T><AT/>FOUND_ME_4 = 11 </T><AT/>X_CONST = 55 </T><AT/>FOUND_ME_5 = 8 </T><AT/>TTT_X = 8 </T><AT/>FOUND_ME_6 = 20
I need to extract all the values related to the field FOUND_ME_[0-9] , possibly with awk. I know that converting each field to separate lines it would be easier but I'm finding a solution working with the file as it is.
My goal is to have an output like the following (values separated by commas)
5, 8, 8, 10
50, 81, 8
54, 81, 8, 11, 8, 20
I'm trying the following but no luck:
awk '{for(i=1;i<=NF;i++){ if($i==".*FOUND_ME_[0-9]"){print $($i+2)} } }'
I have also problems with this special regular pattern FOUND_ME_[0-9]

Answer 1

This awk script gets you the output you want (although I'm guessing that file might have started out as XML once upon a time...):
$ cat script.awk
BEGIN { FS = "[[:space:]=]+" }
{
s = ""
for (i = 1; i <= NF; ++i)
if($i ~ /FOUND_ME_[0-9]/)
s = s sprintf("%s, ", $(++i))
print substr(s, 1, length(s) - 2)
}
$ awk -f script.awk file
5, 8, 8, 10
50, 81, 8
54, 81, 8, 11, 8, 20
It builds a string s from the field after each one matching the pattern. sprintf("%s, ", $(++i)) returns the value of the next field followed by a comma and a space. $(++i) increments the field number i and then returns the value of the field. In awk, strings are concatenated, so the string returned by sprintf is added to the existing value of s.
I set the field separator FS to one or more space or = characters, so the field you're interested is the one after the one matching the pattern. Note that I'm using ~ to match a regex pattern - you cannot use == as you were doing as this performs a string comparison.
The substr strips the last , from the the string before it is printed.
A much shorter option, inspired by Kent's use of FPAT on GNU awk (note that this requires a version >=4.0) :
$ awk -v FPAT="FOUND_ME_[0-9] *= *[0-9]+" -v OFS=", " '{$1=$1;gsub(/FOUND_ME_[0-9] *= */,"")}1' file
5, 8, 8, 10
50, 81, 8
54, 81, 8, 11, 8, 20
$1=$1 causes awk to "touch" each record, removing the parts which aren't matched by FPAT. gsub performs a global substitution, removing the part we aren't interested in. 1 at the end is always true, so the default action {print} is performed. Setting the OFS variable causes each field in the output to be comma-separated as desired.

Answer 2

gawk has FPAT, which we could use for this problem:
awk -v FPAT="FOUND_ME_[0-9] *= *[0-9]+" '
{for(i=1;i<=NF;i++){sub("FOUND_ME_[0-9] *= *","",$i);
printf "%s%s",$i,(NF==i?"\n":", ")}}' file
output:
5, 8, 8, 10
50, 81, 8
54, 81, 8, 11, 8, 20