Remove the "same as the whole table" property from Outlook table - vba

Question

I've got the following code to "Codeize" a block of code in an outlook message:
On Error GoTo Catch
Dim oSelection As Word.Selection
Set oSelection = Application.ActiveInspector.CurrentItem.GetInspector.WordEditor.Application.Selection
With oSelection
With .Font
.Name = "Courier New"
'.Color = 10027008 '13369344
.Size = 10
End With
End With
Dim oTable As Word.Table
Set oTable = oSelection.ConvertToTable(, 1, 1)
With oTable
.Borders.OutsideLineStyle = wdLineStyleDot
.Shading.BackgroundPatternColor = wdColorGray05
.TopPadding = InchesToPoints(0.1)
.BottomPadding = InchesToPoints(0.1)
.LeftPadding = InchesToPoints(0.2)
.RightPadding = InchesToPoints(0.05)
End With
Works great, BUT I think I cannot get the margins to work because I'm missing whatever removes the "Same as the whole table" property.
After the code runs, the Table Properties looks like this:
Perhaps I'm just setting the margins wrong, and this will automatically go away? What am I missing?

Answer 1

Word provides a macro recorder which allows to generate the VBA code in the background. Try to record a VBA macro in Word and see what properties should be used for that. See Record or run a macro for more information.

Answer 2

My bad,
Turns out that setting the padding is the way to turn off this property. The problem was actually in the InchesToPoints call that I copied and pasted from when I macro recording in MS Word.
However InchesToPoints is/was not an available method and that issue was hidden by the first line of my code:
On Error Goto Catch
(Shoot me now!)
So, InchesToPoints failed, which means the padding was NOT actually getting set. I made my own InchesToPoints method:
Public Function InchesToPoints(ByVal dInches As Double) As Double
Const INCHES_TO_POINTS = 72#
InchesToPoints = dInches * INCHES_TO_POINTS
End Function
And now it all works just fine.
The actual correct answer to this question is setting the table padding (E.g., .TopPadding = 7.2 will turn off the "Same as the whole table" property.
Have a nice day.