Object reference not set to an instance of an object while assinging value to byte object - vb.net

Question

I am trying to read byte array and i want to store first value of array in list. I tried one small console application example but i got above issue. I searched a lot on internet but didnt get answer
Sub Main()
Dim lData As New List(Of Byte)
Dim lBuffer() As Byte = {5, 99, 4, 7}
Dim a() As Byte
For ReadValue As Integer = 0 To lBuffer.Length
a(0) = lBuffer(ReadValue)
Exit For
Next
lData.AddRange(a)
End Sub

Answer 1

Your problem here is that you have declared the array but you have not initialized it. By declaring a variable with Dim a() As Byte, you have said "This thing exists and here's what it looks like". However, you haven't actually provided anything that will occupy the definition of a(), or in other words you haven't instantiated it yet.
Think of it this way. I tell you that apples exist and that they look like oddly shaped red orbs, there are seeds inside of them, and they are edible. Now I'm going to tell you to take all of the seeds out of the apple and eat the apple. Picking seeds out of an apple is completely possible, and eating apples is also possible. One problem though, you can't do what I told you. Why? Because I never gave you an apple to do those things with.
To be more specific in regards to you question, You have created an array of bytes with Dim a() As Byte. That's the first step, you told it "Hey, this is going to be a collection of things and all of those things are going to be a Byte". The main problem with arrays in the way you used it is that arrays need to know how big they are when you use them. So you have two options, you can either a) declare the array with a size which will create an empty array where all elements are null or b) you can do it like you did and then assign an array that has already been defined to it.
I'll give you examples of both the methods:
Sub Main()
Dim lData As New List(Of Byte)
Dim lBuffer() As Byte = {5, 99, 4, 7}
' Tell the array how big to be in the first place
Dim a(lBuffer.Length - 1) As Byte
For ReadValue As Integer = 0 To lBuffer.Length - 1
a(ReadValue) = lBuffer(ReadValue)
Next
lData.AddRange(a)
End Sub
Sub Main()
Dim lData As New List(Of Byte)
Dim lBuffer() As Byte = {5, 99, 4, 7}
Dim a() As Byte
' Lets create a temporary list and then use the .ToArray function
' which will return an already instantiated array.
Dim byteList as new List(of Byte)
For ReadValue As Integer = 0 To lBuffer.Length - 1
' Add each item to the list
byteList.Add(lBuffer(ReadValue))
Next
' Now, convert the list to an array and set it to a()
a = byteList.ToArray
lData.AddRange(a)
End Sub
Either of those options should stop the NullReferenceException error you are receiving. However you already have a List(of Byte) defined and instantiated, so the easiest option would probably be just assigning the values to the list directly:
Sub Main()
Dim lData As New List(Of Byte)
Dim lBuffer() As Byte = {5, 99, 4, 7}
For ReadValue As Integer = 0 To lBuffer.Length - 1
lData.Add(lBuffer(ReadValue))
Next
End Sub
Or even shorter code would be to use a Lambda expression:
Sub Main()
Dim lData As New List(Of Byte)
Dim lBuffer() As Byte = {5, 99, 4, 7}
lBuffer.ToList.ForEach(Sub(x) lData.Add(x))
End Sub
However the shortest possible answer to achieve the same thing would be to use the .ToList extension directly:
Sub Main()
Dim lData As List(Of Byte)
Dim lBuffer() As Byte = {5, 99, 4, 7}
lData = lBuffer.ToList()
End Sub
After re-reading this, I thought of an even shorter version. You can cut out the middleman of the byte array completely and just instantiate the List(Of Byte) from your array list.
Sub Main()
Dim lData As New List(Of Byte) From {5, 99, 4, 7}
End Sub
And I believe that's the shortest possible way to do it. If someone can prove me wrong though, I'd love to learn.