Excel Data Validation Combo box Click - vba

Question

I am very new to coding...
Sheet 1 has my data validation in a scroll list on it and sheet 2 has the list that it is validating the data from. I am trying to make a combo box on sheet 1 that will auto fill while you type instead of having to type the exact name. The code below only works if the data list is on the same sheet as the sheet I am trying to make the combo box on. Any idea how to change the code so it will pull from sheet 2 where all the list of data is located?
Any help would be greatly appreciated
'=========================================
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim str As String
Dim cboTemp As OLEObject
Dim ws As Worksheet
Set ws = ActiveSheet
On Error GoTo errHandler
If Target.Count > 1 Then GoTo exitHandler
Set cboTemp = ws.OLEObjects("TempCombo")
On Error Resume Next
If cboTemp.Visible = True Then
With cboTemp
.Top = 10
.Left = 10
.ListFillRange = ""
.LinkedCell = ""
.Visible = False
.Value = ""
End With
End If
On Error GoTo errHandler
If Target.Validation.Type = 3 Then
'if the cell contains a data validation list
Application.EnableEvents = False
'get the data validation formula
str = Target.Validation.Formula1
str = Right(str, Len(str) - 1)
With cboTemp
'show the combobox with the list
.Visible = True
.Left = Target.Left
.Top = Target.Top
.Width = Target.Width + 15
.Height = Target.Height + 5
.ListFillRange = ws.Range(str).Address
.LinkedCell = Target.Address
End With
cboTemp.Activate
'open the drop down list automatically
Me.TempCombo.DropDown
End If
exitHandler:
Application.ScreenUpdating = True
Application.EnableEvents = True
Exit Sub
errHandler:
Resume exitHandler
End Sub
'====================================
'Optional code to move to next cell if Tab or Enter are pressed
'from code by Ted Lanham
'***NOTE: if KeyDown causes problems, change to KeyUp
Private Sub TempCombo_KeyDown(ByVal _
KeyCode As MSForms.ReturnInteger, _
ByVal Shift As Integer)
Select Case KeyCode
Case 9 'Tab
ActiveCell.Offset(0, 1).Activate
Case 13 'Enter
ActiveCell.Offset(1, 0).Activate
Case Else
'do nothing
End Select
End Sub
'====================================

Answer 1

You have a lot of code just to populate a Combobox in the active sheet.
Since you are using the Worksheet_Change event, you don't have to set the worksheet as the active sheet, it already is.
This sample code will populate ComboBox1 with a range of cells from Sheet2,
The code and Combobox1 are located in Sheet1.
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim ws As Worksheet, Rws As Long, Rng As Range
'ComboBox1 and this code are in Sheet1
Set ws = Sheets("Sheet2") 'sheet2 column 1 is the list to populate Combobox1
With ws 'set the list range
Rws = .Cells(Rows.Count, "A").End(xlUp).Row
Set Rng = .Range(.Cells(1, 1), .Cells(Rws, 1))
End With
With ComboBox1 'populate the combobox
.Clear
.List = Rng.Value
End With
End Sub

Answer 2

If you can forgo the need to have Excel autocomplete based on a user's entry, you can use the cell validation as demonstrated here (backward compatible with older versions):
Dependent Drop-down Lists
Or here (for newer versions):
Insert or delete a drop-down list
The upside to this is that it requires no code, unless you would like to manipulate the list automatically.
Using a combobox object is definitely more complicated, so you might skip on that until your coding catches up to the complexity required by objects.
==EDIT==
OK, then, 2 things: this code (Private Sub Worksheet_SelectionChange(ByVal Target As Range)) applies every time you click a new cell. If your values don't change very much you can make sure the cbo only populates on workbook_open, or something less active. However, if the combobox source data changes frequently while the workbook is open then having a frequent refresh to the source would be worthwhile.
Try naming the range you want the combobox to get its data from and pointing the ListFillRange to that named range, like:
.ListFillRange = "myNamedRange"
Then, if your source grows or shrinks, incorporate code that redefines the named range based on the changes.