Delete Files If value does Not exist - vba

Question

I'm searching for a clean way in VBA to solve this:
I have an Excel sheet containing value's in 1 row.
If the value's are found in a specified directory then they should be kept and all the others deleted.
A short example:
table:
A
1 1000
2 1500
3 2000
4 1800
5 0009
Directory content on C:\Temp\1000.pdf ; 1200.pdf ; 1800.pdf ; 0001.pdf
So the action should keep 1000.pdf and 1800.pdf and delete all other *.pdf 's
This is what I attempted yet, but this is just with one cell.
Dim cName As String
cName = Sheets("Blad2").Range("A2").Text
If Len(Dir("C:\Temp\" & cName, vbDirectory)) = 0 Then
Kill "C:\Temp\" & cName & ".pdf"
End If

Answer 1

see if this helps you:
Sub RemoveFiles()
Dim sht As Worksheet
Dim range As range
Dim found As range
Dim myFolder As String
Dim currFile As String
Dim currFileNoSuffix As String
Set sht = ActiveSheet
' Set the range to the A column-
' - only visible cells (xlCellTypeVisible)
' - and only constants, meaning skip over empty cells
' and cells containing formulas or errors (7).
Set range = sht.range("A:A").SpecialCells(xlCellTypeVisible, 7)
' the files folder
myFolder = "C:\temp\111\"
' give me the first file in the folder
currFile = Dir(myFolder)
' while the code has not gone throug all of the files in the folder
While Not currFile = vbNullString
' put in the variable the name of the file without its suffix,
' for example 11111.pdf --> will put 11111 into the variable.
' ! This does not change the the actual file in the directory!
currFileNoSuffix$ = Mid(currFile, 1, InStrRev(currFile, ".") - 1)
' look for the name of the file in the "A" column.
' xlWhole means to search for an exact match, for example
' if you have a file named 111.pdf, it will only watch with a "111" sheet entry,
' but not with a "1111111" entry.
Set found = range.Find(currFileNoSuffix$, , , xlWhole, , , False)
' if the filename does not appear in the sheet
If found Is Nothing Then
' then delete the file
Kill myFolder & currFile
End If
' give me the next file in the folder
currFile = Dir()
Wend
End Sub

Answer 2

To provide more context, this code loops through each cell in column A (save the top cell which it presumes is the header) and the feeds the Value of that cell to the function to be examined.
The function loops through every file in the provided folder (make sure you update the folder to match your own) and checks to see if file name is Like the criteria provided. (For more information about the Like Operator visit: https://msdn.microsoft.com/en-us/library/swf8kaxw.aspx)
Option Explicit
Private Sub Example()
Dim ws As Excel.Worksheet
Dim rng As Excel.Range
Dim cll As Excel.Range
Dim deletedCount As Long
Set ws = Excel.ActiveSheet
Set rng = Excel.Intersect(ws.UsedRange.Offset(1&, 0&), ws.Columns(1), ws.UsedRange)
For Each cll In rng.Cells
deletedCount = deletedCount + DeleteFilesByCriteria("C:\_Test", cll.value & ".pdf", False)
Next
MsgBox "Deleted " & deletedCount, vbInformation
End Sub
Private Function DeleteFilesByCriteria(ByVal folderPath As String, ByVal criteria As String, Optional ByVal deleteReadOnly As Boolean = False) As Long
'Create a reference to Microsoft Scripting Runtime
Dim fso As Scripting.FileSystemObject
Dim fldr As Scripting.Folder
Dim fl As Scripting.File
Dim deletedCount As Long
Set fso = New Scripting.FileSystemObject
Set fldr = fso.GetFolder(folderPath)
For Each fl In fldr.Files
If fl.name Like criteria Then
fl.Delete deleteReadOnly
deletedCount = deletedCount + 1&
End If
Next
DeleteFilesByCriteria = deletedCount
End Function