Different Number of Spaces Depending on the Variable - variables

Question

I am trying to create a sort of list that looks something like this:
echo thing1 thing2
echo.
Then a for loop to list text files in a directory and a bit of information like this:
echo %var% %var1%
echo %var% %var1%
rem and so on
But no matter what length the variable is, there will always be 11 spaces which puts it off a bit with the header.
I know I could make some code to detect the length and save a number of spaces in a variable and then add it on.
But I was just wondering if there is another more simple way.

Answer 1

There's no mention how exactly the strings are taken so I'll leave this to you.
Here's how you can set spaces between two variables and the result will have fixed length.
#echo off
rem http://ss64.org/viewtopic.php?id=424
set max_len=25
set "var11=thing1"
set "var12=thing2"
set "var21=thing1xxxxxx"
set "var22=thing2"
set "var31=thing1xxxxxx"
set "var32=thing2"
call :setSpaces var11 var12
call :setSpaces var21 var22
call :setSpaces var31 var32
goto :eof
:setSpaces var1 var2 [RtnVar]
setlocal EnableDelayedExpansion
set "var1=!%~1!"
set "var2=!%~2!"
call :strlen0 var1 len1
call :strlen0 var2 len2
set /a needed_spaces=%max_len%-%len1%-%len2%
rem echo %needed_spaces%
set "spaces="
for /l %%a in (1;1;%needed_spaces%) do (
set "spaces=!spaces! "
)
set line=%var1%%spaces%%var2%
endlocal&if "%~3" neq "" (set %~3=%line%) else echo %line%
exit /b 0
:strlen0 StrVar [RtnVar]
setlocal EnableDelayedExpansion
set "s=#!%~1!"
set "len=0"
for %%N in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
if "!s:~%%N,1!" neq "" (
set /a "len+=%%N"
set "s=!s:~%%N!"
)
)
endlocal&if "%~2" neq "" (set %~2=%len%) else echo %len%
exit /b