VB is not a member of 'String' - vb.net

Question

Private Sub TextBox1_TextChanged(sender As Object, e As EventArgs) Handles TextSearch.TextChanged
'attempting to allow search by last name
Dim con As New OleDb.OleDbConnection
Dim cmd As New OleDb.OleDbCommand
Dim Sql As String
Dim data_reader As String
con.ConnectionString = "PROVIDER = Microsoft.ACE.OLEDB.12.0;Data Source=C:\Me._DeCON_12___2015DataSet.DeCon"
con.Open()
Sql = "SELECT [First Name 2015], [Last Name 2015] FROM DeCon WHERE [Last Name 2015] = TextBoxLName.Text"
data_reader = Sql.ExecuteReader()
'ListBox1.Items.Clear()
If data_reader.HasRows = True Then
Do While data_reader.Read()
lbfirstname.item = data_reader.Item("firstname")
Loop
End If
data_reader.Close()
data_reader = Nothing
con.Close()
End Sub
Okay I'm a total newbie, and I'm trying to make it so a user can search by last name in a textbox, and then have first names (of people with that last name) show up in a listbox. I was given this code (except for data_reader As String) and I know I can make it work, but I don't know how.
Here are the errors I'm getting:
'ExecuteReader' is not a member of 'String'.
'Has Rows' is not a member of 'String'.
'Read' is not a member of 'String'.
'lbfirstname' is not declared. It may be inaccessible due to its protection level.
'Item is not a member of 'String'.
'Close' is not a member of 'String'.
Now...lbfirstname, I might be able to figure out. I assume I need to change the name to whatever makes sense. Is it referring to the textbox or the listbox?
The rest of it...I have no idea. I thought Close was a given, and assumed Read was. When I try to Dim * As String it's of no help, and I knew that wouldn't be right anyway. I'm connecting to an Access database, if that makes any difference.
I don't know enough VB to do so. I was voluntold to make it, and somehow managed most the other bits with little help. This is the last part I should have to do, and I need it done by tomorrow.

Answer 1

The errors you are getting are because you're attempting to call properties and methods that are not part of the String class, as has been mentioned in the comments. Specifically:
ExecuteReader is a method of OleDbCommand.
HasRows is a property of OleDbDataReader (which is returned by calling OleDbCommand.ExecuteReader(). Read() and Close() are methods on the OleDbDataReader.
lbfirstname is not the ID assigned to the ListBox control in your application - you need to use the ID you gave the control.
Item should probably be Items (note the plural), referring to the collection of items in the ListBox.
You're vulnerable to SQL injection (in addition to the fact that your SQL string won't work anyway, because you use TextBoxLName.Text as a literal when you want the value of the TextBox instead. To avoid SQL injection, you should be using parmaterized queries.
lbfirstname.item = data_reader.Item("firstname") - Even if this line of code worked, you'd only wind up with the last firstname in the collection returned from your database. You need to add the first names to the ListBox via the Add method.
Putting this altogether, you would have something like this:
Using con As New OleDb.OleDbConnection("PROVIDER = Microsoft.ACE.OLEDB.12.0;Data Source=C:\Me._DeCON_12___2015DataSet.DeCon")
con.Open()
Dim Sql As String = "SELECT [First Name 2015], [Last Name 2015] FROM DeCon WHERE [Last Name 2015] = #LastName"
Dim cmd As New OleDb.OleDbCommand(Sql, con)
cmd.Parameters.Add("#LastName", OleDb.OleDbType.VarChar).Value = TextBoxLName.Text
Using data_reader As OleDb.OleDbDataReader = cmd.ExecuteReader()
If data_reader.HasRows Then
Do While data_reader.Read()
lbfirstname.Items.Add(data_reader.GetString(0))
Loop
End If
End Using
End Using
Explanation of the above code:
First, the connection is wrapped in a Using block - this will ensure the connection is properly closed and disposed of when the block is exited, even if an exception is thrown.
Next, the Sql string is parameterized by replacing the value in the WHERE clause with #LastName. The OleDbCommand is created and assigned the Sql string plus the OleDbConnection object.
The #LastName parameter is then added to the command's Parameters collection and assigned the value of the TextBoxLName.
ExecuteReader is then called on the OleDbCommand object, in a Using block again (to ensure the reader is properly closed and disposed of).
While the reader is looped through, the first name of each record returned from the query is added to the ListBox. I used the GetString method of the reader to return the value as a string. This method requires an ordinal (the index of the column), which based on your provided SQL string is the first column (0 since it's 0-indexed).
All of the above code assumes the column names in the query are correct and the control names are correct - you may need to adjust them to match what you have in your application.