How do I prevent MS Access VBA from converting objects to strings? - oop

Question

I am trying to pass a collection of Folder objects in a VBA module, but it consistently performs an implicit cast of the objects to String type
Function GetFolderFiles(ByRef dir As Object) As Collection
Dim files As Collection
Set files = New Collection
For Each file In dir.files
Debug.Print TypeName(file)
files.Add (file)
Next frile
For Each subfolder In dir.SubFolders
Dim sf As Object
Set sf = subfolder
Debug.Print TypeName(sf)
Dim tmpfiles As Collection
Set tmpfiles = GetFolderFiles(sf)
For Each File In tmpfiles
files.Add (File)
Next File
Next subfolder
Set GetFolderFiles = files
End Function
Here is my test code:
Function TestGetFiles()
Dim fso As Object
Dim d As Object
Dim files As Collection
Set fso = CreateObject("Scripting.FileSystemObject")
Set d = fso.GetFolder("C:\Users\X\Documents\My Web Sites")
Set files = GetFolderFiles(d)
For Each f In files
Debug.Print TypeName(f)
Next f
End Function
As you can see, I'm printing out the TypeName() call's results. When I step through the functions, I get the expected type "File" within GetFolderFiles, but when I iterate over the returned collection, the type of the objects is "String".
1) How do I get a collection of File objects back from my function?
2)More generally, How do I prevent the implicit conversion of Objects to Strings?

Answer 1

There's a difference between f and (f), as illustrated in the code below:
Function TestGetFiles()
Dim fso As Object
Dim d As Object, f As Object
Set fso = CreateObject("Scripting.FileSystemObject")
Set d = fso.GetFolder("C:\_Stuff\test")
For Each f In d.files
Debug.Print TypeName(f), TypeName((f)) '>> File String
Next f
End Function
f is the file itself, but wrapping f in parentheses causes that expression to be evaluated (resulting in a string: I'm guessing the default property of File is its Name)
and the result of the evaluation is what gets added to your collection.
Fix: don't use
files.Add (File)
but
files.Add File
Hint: any time the VB editor puts a space before your opening ( means you need to be sure you meant to use those parens. Basically be careful when using parens in a method call unless you're using the Call keyword.