How to open the csv file with proper length in xl - vb.net

Question

Using VB.Net
Below code is working fine for creating a csv file.
When i open the csv file in xls or xlsx, some of the columns are collapsed, i need to expand manually to see the full details of the each column. I want to create a csv file with wraptext or length of the data
Code
Sub SetDataTable_To_CSV(ByVal dtable As DataTable, ByVal path_filename As String, ByVal sep_char As String)
Dim streamWriter As System.IO.StreamWriter
Try
streamWriter = New System.IO.StreamWriter(path_filename)
Dim _sep As String = ""
Dim builder As New System.Text.StringBuilder
For Each col As DataColumn In dtable.Columns
builder.Append(_sep).Append(col.ColumnName)
_sep = sep_char
Next
streamWriter.WriteLine(builder.ToString())
For Each row As DataRow In dtable.Rows
_sep = ""
builder = New System.Text.StringBuilder
For Each col As DataColumn In dtable.Columns
builder.Append(_sep).Append(row(col.ColumnName))
_sep = sep_char
Next
streamWriter.WriteLine(builder.ToString())
Next
Catch ex As Exception
Finally
If Not streamWriter Is Nothing Then streamWriter.Close()
End Try
End Sub
For Example
In csv file
12345,987665544433
Same File when i open in xl
12345,1.02141E+15
Expected Output
in xl file also
12345,987665544433
How to achieve this. Need code help

Answer 1

This behavior happens because of scientific notation which is a "feature" built into Excel. Unfortunately there is no known way to disable this, there are workarounds however:
1) If you want the numbers to show up properly without having to do anything then adding commas into your numbers is the way to go. Excel will still treat this as a number field, and will stop doing scientific notation on the number.
Note: You will most likely have to wrap all text in double-quotes to prevent Excel from thinking the commas indicate a new column. Wrapping your text with double quotes alone will not stop scientific notation from changing your numbers!:
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Dim dt As New DataTable
dt.Columns.Add("StringField", GetType(String))
dt.Columns.Add("NumberField", GetType(String)) ' Notice that our number field is saved as type string so that we can add commas into the number
Dim dr As DataRow
For i As Int32 = 1 To 10
dr = dt.NewRow
dr("StringField") = "test"" " & i
dr("NumberField") = FormatNumber(987654320 + i, 0, TriState.UseDefault, TriState.UseDefault, TriState.True) ' Format the number with commas
dt.Rows.Add(dr)
Next
SetDataTable_To_CSV(dt, System.IO.Path.Combine(Application.StartupPath, "test.csv"), ",")
End Sub
Sub SetDataTable_To_CSV(ByVal dtable As DataTable, ByVal path_filename As String, ByVal sep_char As String)
Dim streamWriter As System.IO.StreamWriter
Try
streamWriter = New System.IO.StreamWriter(path_filename)
Dim _sep As String = ""
Dim builder As New System.Text.StringBuilder
For Each col As DataColumn In dtable.Columns
builder.Append(_sep).Append(FixCSVField(col.ColumnName)) ' Add quotes around this field
_sep = sep_char
Next
streamWriter.WriteLine(builder.ToString())
For Each row As DataRow In dtable.Rows
_sep = ""
builder = New System.Text.StringBuilder
For Each col As DataColumn In dtable.Columns
builder.Append(_sep).Append(FixCSVField(row(col.ColumnName))) ' Add quotes around this field
_sep = sep_char
Next
streamWriter.WriteLine(builder.ToString())
Next
Catch ex As Exception
Finally
If Not streamWriter Is Nothing Then streamWriter.Close()
End Try
End Sub
Function FixCSVField(sInString As String) As String
Return """" & sInString.Replace("""", """""""") & """" ' Wrap string in quotes to prevent problems with commas in the field and escape double quotes with another double quote
End Function
End Class
2) If you don't like the comma approach then you can always just open up the csv and highlight all the cells that you want to change. Once highlighted you can right-click on the columns and choose the "Format Cells" option. In the "Category" box, click "Number" and click "OK" to change all your cells back into numbers so that they no longer show up funny. Unfortunately this has to be done for every new csv file that you generate and I'm kind of assuming you knew about this option and were looking for the automatic method above.
3) The only last thing I can recommend is to use a different csv viewer such as Open Office or Google Spreadsheets to view your CSV files as these products do not truncate your numbers.
Good luck!
Edit:
I just thought of some more ideas on how to create your excel files automatically without any user intervention:
4) Use Excel Automation. You can use this to create an xls/xlsx file directly instead of a csv file. The benefit here is that you have a little more control of the data and layout then you do with a simple csv file. Unforunately there are many drawbacks and it depends upon your situation whether or not this is a valid option:
Potential Negatives:
You will require a license for Microsoft Excel on every machine your application will run on
All machines that the application runs on must have the same version of Microsoft Excel installed (For some reason I am thinking that newer versions installed on the client machine may still work, but older for sure will not, can anyone confirm?)
When you use Excel Automation, Microsoft Excel is loaded in the background which takes up memory to load a large number of files/DLLs
Excel Automation is much slower to generate large files as opposed to CSV
Microsoft explicitly recommends against using Excel Automation in a server environment: http://support.microsoft.com/kb/257757
That all being said, if you are just using the app on your own machine or you know for sure that everyone else who will use it is going to have the same version of Excel installed, this is a great way to write your Excel files without having to worry about the scientific notation problem.
Here is some sample code using the same test data as above:
Note: Before you can use this code you must add a reference to the Microsoft Excel xx.0 Object Library to your project. The version number will depend upon which version of Microsoft Excel you have installed on your machine. In my case I have Excel 2013 and therefore I add the Microsoft Excel 15.0 Object Library. You do this by opening up your project properties window, click the "References" tab, Click "Add", Click the "Com" tab and put a check next to the Microsoft Excel Object Library and click "OK".
Imports Microsoft.Office.Interop
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
' Test datatable creation
Dim dt As New DataTable
dt.Columns.Add("StringField", GetType(String))
dt.Columns.Add("NumberField", GetType(Int32)) ' Notice that our number field is now actually an integer type
Dim dr As DataRow
For i As Int32 = 1 To 10
dr = dt.NewRow
dr("StringField") = "test"" " & i
dr("NumberField") = 987654320 + i
dt.Rows.Add(dr)
Next
' Use Excel automation to create an xls/xlsx file
Dim xlApp As Excel.Application = New Microsoft.Office.Interop.Excel.Application()
If xlApp Is Nothing Then
' Excel automation can only be used if the correct version of excel is installed on the machine
MessageBox.Show("Excel is not installed on this computer.")
Else
Dim bIsXLSX As Boolean = True ' If this is true then an xlsx file is created, if false then the older xls file is used (use xls only if you need to support office 2003 and below)
Dim xlWorkBook As Excel.Workbook
Dim xlWorkSheet As Excel.Worksheet
Dim misValue As Object = System.Reflection.Missing.Value
Dim sFilename As String = System.IO.Path.Combine(Application.StartupPath, "excelfile.xls" & If(bIsXLSX = True, "x", ""))
xlWorkBook = xlApp.Workbooks.Add(misValue)
xlWorkSheet = xlWorkBook.Sheets("sheet1")
' Write headers
For c As Int32 = 0 To dt.Columns.Count - 1
xlWorkSheet.Cells(1, c + 1) = dt.Columns(c).ColumnName
Next
' Loop through rows and columns to create the data fields
For r As Int32 = 0 To dt.Rows.Count - 1
For c As Int32 = 0 To dt.Columns.Count - 1
xlWorkSheet.Cells(r + 2, c + 1) = dt.Rows(r).Item(c) ' Write the data to the correct column
Next
Next
xlWorkSheet.Columns.AutoFit() ' Autofit all cells to ensure they do not show the scientific notation
xlWorkBook.SaveAs(sFilename, If(bIsXLSX = True, Excel.XlFileFormat.xlWorkbookDefault, Excel.XlFileFormat.xlWorkbookNormal), misValue, misValue, misValue, misValue, Excel.XlSaveAsAccessMode.xlExclusive, misValue, misValue, misValue, misValue, misValue)
xlWorkBook.Close(True, misValue, misValue)
xlApp.Quit()
' Cleanup excel object
ReleaseExcelObject(xlWorkSheet)
ReleaseExcelObject(xlWorkBook)
ReleaseExcelObject(xlApp)
MessageBox.Show("Excel file created: " & sFilename)
End If
End Sub
Private Sub ReleaseExcelObject(ByVal oExcelObject As Object)
Try
System.Runtime.InteropServices.Marshal.ReleaseComObject(oExcelObject)
oExcelObject = Nothing
Catch ex As Exception
oExcelObject = Nothing
Finally
GC.Collect()
End Try
End Sub
End Class
5) If you would like to go the xls/xlsx route (as opposed to csv) but can't ensure that every client machine the app will be run on will have the same version of Excel installed you can use a third party dll to generate the file. The benefit of this approach is that the client machine does not even need to have Microsoft Excel installed to work. The biggest drawback to this method is that most dlls are not free.
There are many different options when it comes to these third party dlls so you have a lot of choices. Here are a few examples that should work for you:
Spire.XLS
GemBox.Spreadsheet
SpreadsheetGear
ComponentOne Excel for .Net
TMS Flexcel Studio for .NET
The only one I have used in the past is Spire.XLS and I will provide a working example below to demonstrate how easy it is to create the excel file with this dll. They provide a fully functional dll for free that you can use to test the product. The only limitation of using the free version versus paying is that the free version will automatically insert an extra worksheet into the file with an evaluation warning.
At the time of writing the newest version is 7.6 and you can find a direct link here: http://www.e-iceblue.com/downloads/spire.xls-se_7.6.zip (usually you need to signup to get the download link so this link may change in the future).
Here is a sample of how to get it working:
Imports Spire.Xls
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
' Test datatable creation
Dim dt As New DataTable
dt.Columns.Add("StringField", GetType(String))
dt.Columns.Add("NumberField", GetType(Int32)) ' Our number field is an actual integer this time
Dim dr As DataRow
For i As Int32 = 1 To 10
dr = dt.NewRow
dr("StringField") = "test"" " & i
dr("NumberField") = 987654320 + i
dt.Rows.Add(dr)
Next
' Use Spire.XLS to create an xls file
Dim bIsXLSX As Boolean = True ' If this is true then an xlsx file is created, if false then the older xls file is used (use xls only if you need to support office 2003 and below)
Dim sFilename As String = System.IO.Path.Combine(Application.StartupPath, "excelfile.xls" & If(bIsXLSX = True, "x", ""))
Dim oWorkbook As New Workbook
Dim oSheet As Worksheet = oWorkbook.Worksheets(0)
' New workbook automatically creates 3 blank worksheets by default
' Remove the last two since we only need one
oWorkbook.Worksheets.Remove(oWorkbook.Worksheets(2))
oWorkbook.Worksheets.Remove(oWorkbook.Worksheets(1))
' Write headers
For c As Int32 = 0 To dt.Columns.Count - 1
oSheet.Range(1, c + 1).Text = dt.Columns(c).ColumnName
Next
' Loop through rows and columns to create the data fields
For r As Int32 = 0 To dt.Rows.Count - 1
For c As Int32 = 0 To dt.Columns.Count - 1
oSheet.Range(r + 2, c + 1).Text = dt.Rows(r).Item(c) ' Write the data to the correct column
Next
Next
oSheet.Range().AutoFitColumns() ' Automatically adjust the width of all columns to fit the data
oWorkbook.SaveToFile(sFilename, If(bIsXLSX = True, ExcelVersion.Version2013, ExcelVersion.Version97to2003)) ' You can change version from 2013 to match the version of Excel you are using
oWorkbook.Dispose()
MessageBox.Show("Excel file created: " & sFilename)
End Sub
End Class
6) There is a free, open-source dll called ExcelLibrary that will create an xls file without having Excel installed but it hasn't been updated since 2011 and has a few quirks. First off it does not support the newer xlsx format, which shouldn't be an issue for you since you were using csv to begin with. Second, it supports setting the column width but it doesn't have an autofit option so you will have to hardcode the width which might cause the original problem with scientific notation if you don't specify a large enough width. Next, it does other funny things to large numbers like the ones you specified (ex. 987665544433) so you again have to treat the number as a string when you write it or else you will get negative numbers when they should be large positive numbers. Finally, xls files generated with this dll don't open properly in Microsoft Excel 2010 or higher unless it is of a certain filesize (file needs to be at least 7 KB in size so if you have too few rows the file won't open). However there is a workaround for this which involves adding blank data rows to the end of the file to make the filesize larger and therefore readable by Microsoft Excel. I don't recommend this approach because of all the quirks but I am including it for completion sake. Download the dll from here: https://code.google.com/p/excellibrary/
Imports ExcelLibrary.SpreadSheet
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
' Test datatable creation
Dim dt As New DataTable
dt.Columns.Add("StringField", GetType(String))
dt.Columns.Add("NumberField", GetType(String)) ' Our number field is a string value again, if you try Int32 it makes large numbers negative and if you try Int64 it will give you an "Invalid cell value" error
Dim dr As DataRow
For i As Int32 = 1 To 10
dr = dt.NewRow
dr("StringField") = "test"" " & i
dr("NumberField") = 987654320 + i
dt.Rows.Add(dr)
Next
' Use Excel Library to create an xls file
Dim sFilename As String = System.IO.Path.Combine(Application.StartupPath, "excelfile.xls")
Dim oWorkbook As New Workbook()
Dim oWorksheet As New Worksheet("Sheet1")
' Write headers
For c As Int32 = 0 To dt.Columns.Count - 1
oWorksheet.Cells(0, c) = New Cell(dt.Columns(c).ColumnName)
Next
' Loop through rows and columns to create the data fields
For r As Int32 = 0 To dt.Rows.Count - 1
For c As Int32 = 0 To dt.Columns.Count - 1
oWorksheet.Cells(r + 1, c) = New Cell(dt.Rows(r).Item(c)) ' Write the data to the correct column
Select Case c
Case Is = 0 ' StringField width
oWorksheet.Cells.ColumnWidth(c) = 3000
Case Is = 1 ' NumberField width
oWorksheet.Cells.ColumnWidth(c) = 3500
End Select
Next
Next
' Workaround to fix the "We found a problem with some content in 'excelfilename'" error when opening with Office 2010 or greater by adding extra blank rows to ensure the file size is greater than 7 KB
If dt.Rows.Count < 100 Then
Dim nRowCount = dt.Rows.Count + 1
Do While nRowCount < 100
oWorksheet.Cells(nRowCount, 0) = New Cell(" ")
nRowCount += 1
Loop
End If
oWorkbook.Worksheets.Add(oWorksheet)
oWorkbook.Save(sFilename)
MessageBox.Show("Excel file created: " & sFilename)
End Sub
End Class
As you can see there are many solutions to this problem. Please let us know which one worked for you!
Edit 2:
Well I had some more time and I found some better and FREE dlls to create xls/xlsx files with which are very much worth mentioning:
7) ClosedXML is a free, open source solution that can be used to create xlsx files from .Net code with much less hassle than ExcelLibrary. It only allows creation of the newer xlsx files so Excel 2007 or greater is required to open but it doesn't require Excel to be installed for it to create files. This one was really simple to use and the only real downside I found was that you need to also reference the DocumentFormat.OpenXml.dll (also free and open source) along with the ClosedXML dll. More information here: http://closedxml.codeplex.com/
Imports ClosedXML.Excel
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
' Test datatable creation
Dim dt As New DataTable
dt.Columns.Add("StringField", GetType(String))
dt.Columns.Add("NumberField", GetType(Int32)) ' Our number field is an actual integer this time
Dim dr As DataRow
For i As Int32 = 1 To 10
dr = dt.NewRow
dr("StringField") = "test"" " & i
dr("NumberField") = 987654320 + i
dt.Rows.Add(dr)
Next
' Use Closed XML to create an xlsx file
Dim sFilename As String = System.IO.Path.Combine(Application.StartupPath, "excelfile.xlsx")
Dim oWorkbook As New XLWorkbook
Dim oWorksheet = oWorkbook.Worksheets.Add("Sheet1")
' Write headers
For c As Int32 = 0 To dt.Columns.Count - 1
oWorksheet.Cell(1, c + 1).Value = dt.Columns(c).ColumnName
Next
' Loop through rows and columns to create the data fields
For r As Int32 = 0 To dt.Rows.Count - 1
For c As Int32 = 0 To dt.Columns.Count - 1
oWorksheet.Cell(r + 2, c + 1).Value = dt.Rows(r).Item(c) ' Write the data to the correct column
Next
Next
oWorksheet.Columns.AdjustToContents() ' Automatically adjust the width of all columns to fit the data
oWorkbook.SaveAs(sFilename)
oWorkbook.Dispose()
MessageBox.Show("Excel file created: " & sFilename)
End Sub
End Class
8) NPOI is another free open source dll that is a tad bit more complicated than ClosedXML but it supports read/write of xls, xlsx and word + powerpoint files too (not that you need those last ones). It also requires two dlls to be referenced and doesn't require excel to be installed to generate files. More information here: http://npoi.codeplex.com/
Imports NPOI.SS.UserModel
Imports NPOI.XSSF.UserModel
Imports NPOI.HSSF.UserModel
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
' Test datatable creation
Dim dt As New DataTable
dt.Columns.Add("StringField", GetType(String))
dt.Columns.Add("NumberField", GetType(Int32)) ' Our number field is an actual integer this time
Dim dr As DataRow
For i As Int32 = 1 To 10
dr = dt.NewRow
dr("StringField") = "test"" " & i
dr("NumberField") = 987654320 + i
dt.Rows.Add(dr)
Next
' Use NPOI to create an xls/xlsx file
Dim bIsXLSX As Boolean = True ' If this is true then an xlsx file is created, if false then the older xls file is used (use xls only if you need to support office 2003 and below)
Dim sFilename As String = System.IO.Path.Combine(Application.StartupPath, "excelfile.xls" & If(bIsXLSX = True, "x", ""))
Dim oWorkbook As IWorkbook
' Define workbook differently for xls and xlsx files
If bIsXLSX = True Then
oWorkbook = New XSSFWorkbook()
Else
oWorkbook = New HSSFWorkbook()
End If
Dim oWorksheet As ISheet = oWorkbook.CreateSheet("Sheet1")
Dim oRow As IRow
' Write headers
oRow = oWorksheet.CreateRow(0)
For c As Int32 = 0 To dt.Columns.Count - 1
oRow.CreateCell(c).SetCellValue(dt.Columns(c).ColumnName)
Next
' Loop through rows and columns to create the data fields
For r As Int32 = 0 To dt.Rows.Count - 1
oRow = oWorksheet.CreateRow(r + 1)
For c As Int32 = 0 To dt.Columns.Count - 1
oRow.CreateCell(c).SetCellValue(dt.Rows(r).Item(c).ToString) ' Write the data to the correct column
Next
Next
' Automatically adjust the width of all columns to fit the data
For i As Int32 = 0 To dt.Columns.Count - 1
oWorksheet.AutoSizeColumn(i)
Next
Dim sw As IO.FileStream = IO.File.Create(sFilename)
oWorkbook.Write(sw)
sw.Close()
MessageBox.Show("Excel file created: " & sFilename)
End Sub
End Class
9) Last but not least is EPPlus which again is free and open source. It only uses one dll and only works with xlsx files. Again, very simple to use. More information here: http://epplus.codeplex.com/
Imports OfficeOpenXml
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
' Test datatable creation
Dim dt As New DataTable
dt.Columns.Add("StringField", GetType(String))
dt.Columns.Add("NumberField", GetType(Int32)) ' Our number field is an actual integer this time
Dim dr As DataRow
For i As Int32 = 1 To 10
dr = dt.NewRow
dr("StringField") = "test"" " & i
dr("NumberField") = 987654320 + i
dt.Rows.Add(dr)
Next
' Use EPPlus to create an xlsx file
Dim sFilename As String = System.IO.Path.Combine(Application.StartupPath, "excelfile.xlsx")
Dim oPackage As New ExcelPackage()
Dim oWorksheet As ExcelWorksheet = oPackage.Workbook.Worksheets.Add("Sheet1")
' Write headers
For c As Int32 = 0 To dt.Columns.Count - 1
oWorksheet.Cells(1, c + 1).Value = dt.Columns(c).ColumnName
Next
' Loop through rows and columns to create the data fields
For r As Int32 = 0 To dt.Rows.Count - 1
For c As Int32 = 0 To dt.Columns.Count - 1
oWorksheet.Cells(r + 2, c + 1).Value = dt.Rows(r).Item(c).ToString ' Write the data to the correct column
Next
Next
oWorksheet.Cells(oWorksheet.Dimension.Address).AutoFitColumns() ' Automatically adjust the width of all columns to fit the data
oPackage.SaveAs(New IO.FileInfo(sFilename))
oPackage.Dispose()
MessageBox.Show("Excel file created: " & sFilename)
End Sub
End Class
Well that's it, I'm not adding more. Here are 9+ ways that you can accomplish what you are looking for using a variety of methods and complete with code examples. Believe it or not there are more ways to do this still but for sure one of these methods will get you to where you need to go. Happy coding!