How I can optimize this code more? [Assembly 8086 letters pyramid] - optimization

Question

I wonder how I could optimize this code a little bit more. Now he has 467k and 59 lines.
Data segment:
code_char db 'A'
counter_space db 39
counter_char dw 1
counter_rows dw 25
Program segment:
rows:
mov cl, counter_space ;here I write space
mov ah,02h
mov dl,''
space:
int 21h
loop space
mov cx, counter_char ;here I write letters
mov ah,02h
mov dl,code_char
letters:
int 21h
loop letters
mov ah,02h ;here I go to another line(enter)
mov dl,0ah
int 21h
INC code_char ;here I change the value of variable's
DEC counter_space
ADD counter_char,2
DEC counter_rows
mov cx,counter_rows ;here I count the rows to 25
loop rows
mov ah,01h ;here I w8 to any key
int 21h
mov ah,4ch
mov al,0
int 21h
If you have any suggestions please comment.
I just started to learn Assembly.

Answer 1

You can make use of the fact that all other variables can be calculated from the counter_rows variable, so you really only need one variable:
code_char = 'A' + 25 - counter_rows
counter_space = counter_rows + 14
counter_char = 51 - counter_rows * 2
As counter_rows is your outer loop counter, you can just keep it in a register all the time instead of allocating memory for it. That makes it possible to run the program without any memory references at all.
There are some other small optimisations that can be done. You don't need to set the ah register to 02h other than for the first call. When setting ah to 01h for the keypress call, you can just decrement the register as you know that it was 02h before. You can set ax instead of setting ah and al separately.
If I counted correctly, this should take the actual code and data bytes down from 59 to 41:
mov bx, 25 ;counter_rows
rows:
;here I write space
mov cx, bx ; counter_space = counter_rows + 14
add cl, 14
mov ah, 02h
mov dl, 32 ;space
space:
int 21h
loop space
;here I write letters
mov cl, 51 ;counter_char = 51 - counter_rows * 2
sub cl, bl
sub cl, bl
;mov ah, 02h - already set
mov dl, 65 + 25 ;code_char = 'A' + 25 - counter_rows
sub dl, bl
letters:
int 21h
loop letters
;here I go to another line(enter)
;mov ah, 02h - already set
mov dl, 0ah
int 21h
dec bx
jnz rows
;here I wait for any key
dec ah ;02h - 1 = 01h
int 21h
mov ax,4c00h ;set ah and al in one go
int 21h