Excel 'Forgot to Attach Attachment' alert VBA no longer working - vba

Question

I inserted the below VBA I found somewhere on the web into my outlook to catch e-mails which I have forgotten to attach the attachment to before they get sent.
It worked fine on initial application of the VBA however today I managed to forget to attach the attachment to an e-mail and sure enough it has stopped working for whatever reason. Can anybody help me rectify this please?
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
Dim m As Variant
Dim strBody As String
Dim intIn As Long
Dim intAttachCount As Integer, intStandardAttachCount As Integer
On Error GoTo handleError
'Edit the following line if you have a signature on your email that includes images or other files. Make intStandardAttachCount equal the number of files in your signature.
intStandardAttachCount = 1
strBody = LCase(Item.Body)
intIn = InStr(1, strBody, "original message")
If intIn = 0 Then intIn = Len(strBody)
intIn = InStr(1, Left(strBody, intIn), "attach")
intAttachCount = Item.Attachments.Count
If intIn > 0 And intAttachCount <= intStandardAttachCount Then
m = MsgBox("You forgot to attach your file didn't you?" & vbCrLf & " ...idiot" & vbCrLf & vbCrLf & " Send it without?", vbQuestion + vbYesNo + vbMsgBoxSetForeground)
If m = vbNo Then Cancel = True
End If
handleError:
If Err.Number <> 0 Then
MsgBox "Outlook Attachment Reminder Error: " & Err.Description, vbExclamation, "Outlook Attachment Reminder Error"
End If
End Sub

Answer 1

I inserted the below VBA I found somewhere on the web into my excel to catch e-mails which I have forgotten to attach the attachment to before they get sent.
Your code isn't going to work in Excel as is.
The event Application_ItemSend is an Outlook specific event handler. It is not present in Excel. It is tied to the Outlook action "Send." See here for a description.
Setup event handler for Excel to handle Outlook events
If you want to have this work for emails generated in Excel you are going to have to do something different.
In your situation, create a separate class module and name it OutlookEventHandler and paste the following:
Private WithEvents ol As Outlook.Application
Private Sub ol_ItemSend(ByVal Item As Object, Cancel As Boolean)
'your code here
End Sub
Public Sub init()
Set ol = GetObject(, "Outlook.Application")
End Sub
Then, in your ThisWorkbook module add the following:
Private olEH As OutlookEventHandler
Private Sub Workbook_Activate()
Set olEH = New OutlookEventHandler
olEH.init
End Sub
This will result in your event handler being called for emails sent by both Excel and Outlook.