Autopopulate a column utilizing the MATCH function - vba

Question

I have 2 workbooks: "MainWorkbook.xlsm" and "ReferenceWorkbook.xlsx". The reference workbook is a report that the main workbook pulls data from.
There is a column in my main workbook called "Vendor Name", which is column J. The column in the reference workbook that "Vendor Name" would be referencing is column X, named "Vendor_Data". Both of the vendor columns in the 2 worksheets are non-numeric data types. Furthermore, both of these worksheets are subject to variations in row counts; I may have 200 rows in "Mainworkbook.xlsm" one day and 230 the next. The same applies for "ReferenceWorkbook". The vendor column in "MainWorkbook.xlsm" will remain static as far as it's index value goes, but the position of the vendor column in ReferenceWorkbook.xlsx could potentially change in the future (ex. going from column x to column y). The header row in "MainWorkbook") is row 2, while the header row in "ReferenceWorkbook" is row 1.
What I would like to do is build a macro that will automatically populate my vendor column in "MainWorkbook" by first matching to the vendor column in "ReferenceWorkbook" based on their headers and then matching rows by their primary keys (Column C in "MainWorkbook" and column K in "ReferenceWorkbook"). The primary key column in "ReferenceWorkbook" is also subject to having it's column index changed, like it's vendor column, so I would like to do all of my header matching based on header names, not their index values.
Since I'm just starting out with VBA, the best I have so far is an incomplete and very logically flawed block of code:
Sub New_Macro()
Dim ran As Range, source_header As Range, target_header As Range
Dim source As Workbook, source_sheet As Worksheet, target As Workbook, target_sheet As Worksheet
Dim i As Integer, j As Integer, Match_header As Integer
Set source = Application.Workbooks("ReferenceWorkbook.xlsx")
Set Reference_sheet = source.Worksheets("ReferenceSheet")
Set target = Application.Workbooks("MainWorkbook.xlsm")
Set target_sheet = target.Worksheets("MainSheet")
Set source_worksheet_header = source_sheet.Range("X1")
Set target_worksheet_header = target_sheet.Range("J2")
LR = target_sheet.Cells(Rows.Count, 1).End(xlUp).Row
j = 10
Set ran = target_sheet.Range("J3" & LR)
ran.ClearContents
Do While j < 11
For Each cell In target_worksheet_header
For i = 3 To LR
Match_header = source_worksheet_header.Find(cell.Value)
target_sheet.Cells(i, j).Value = Application.WorksheetFunction.Index(source_sheet.Range("X"), WorksheetFunction.Match(target_sheet.Cells(i, 10).Value, source_sheet.Range("X"), LR), Match_header)
On Error Resume Next
Next i
j = j + 1
Next cell
Loop
End Sub
Does anyone have a way to turn this into an actual solution? Any help would be wonderous

Answer 1

Compiled but not tested:
Sub New_Macro()
Dim ran As Range, c As Range
Dim source_sheet As Worksheet
Dim target_sheet As Worksheet
Dim srcVendorCol As Range, srcIdCol As Range, f As Range
Dim vndr, r, id
Dim LR As Long
Set source_sheet = Workbooks("ReferenceWorkbook.xlsx") _
.Worksheets("ReferenceSheet")
Set target_sheet = Workbooks("MainWorkbook.xlsm") _
.Worksheets("MainSheet")
Set f = source_sheet.Rows(1).Find(what:="Vendor_Data", _
lookat:=xlWhole, LookIn:=xlValues)
If Not f Is Nothing Then
Set srcVendorCol = f.EntireColumn
End If
Set f = Nothing
Set f = source_sheet.Rows(1).Find(what:="PrimaryKey", _
lookat:=xlWhole, LookIn:=xlValues)
If Not f Is Nothing Then
Set srcIdCol = f.EntireColumn
End If
If srcVendorCol Is Nothing Or srcIdCol Is Nothing Then
MsgBox "Required column headers not found in source sheet!"
Exit Sub
End If
'find last populated cell in Col J
LR = target_sheet.Cells(Rows.Count, "J").End(xlUp).Row 'EDIT
Set ran = target_sheet.Range("J3:J" & LR)
For Each c In ran.Cells
id = c.EntireRow.Cells(3).Value
If Len(id) > 0 Then 'EDIT - added check for Id length
r = Application.Match(id, srcIdCol, 0)
If Not IsError(r) Then
c.Value = Application.Index(srcVendorCol, r, 1)
Else
c.Value = "Id not found"
End If
End If
Next c
End Sub