Find missing value in a numbers sequence - DGV column - vb.net

Question

I tried searching and didn't have any success in fixing my problem so I tried finding my own solution.
First I found max (Max) value (min value is always 1), then I set loop to search value by value, but something is wrong with my loop.
For i As Integer = 1 To Max
For y As Integer = 0 To DataGridView1.Rows.Count - 1
If DataGridView1.Rows(y).Cells(0).Value = i Then
Else
builder2.Append(i & ",")
End If
Next
Next
To me loop looks OK but it's not working. If value i is found do nothing if it's not found add i to stringbuilder, and so on until it reaches Max value. But whatever combination I've tried I get some weird results.
Numbers are sorted from lowest to highest.
I've also extracted all values from DGV column to comma delimited string if it's easier that way...
EDIT :
Just for experimenting with that loop I've put i = 40 to 50 (to reduce the range). I know that missing values in DGV column are 40-46 and 59.
This is what I've got with loop above :

Answer 1

You can use LINQ to find missing numbers quite easily. You just need to get the existing numbers into a List, and then you can use Max() to find the largest number, and Except() to find the missing ones.
I put a DGV named DataGridView1 with one column, a button named bnPopulateDGV, and a button named bnFindMissingNumbers on a new Windows Form, and used the following code (with Option Infer On):
Private Sub bnPopulateDGV_Click(sender As Object, e As EventArgs) Handles bnPopulateDGV.Click
DataGridView1.Rows.Clear()
Dim seq1 = Enumerable.Range(1, 100).ToList()
Dim rand As New Random
' knock some out
For i = 1 To 5
seq1.RemoveAt(rand.Next(0, 50))
Next
For Each s In seq1
DataGridView1.Rows.Add(New String() {s.ToString()})
Next
End Sub
Private Sub bnFindMissingNumbers_Click(sender As Object, e As EventArgs) Handles bnFindMissingNumbers.Click
Dim existingNumbers As New List(Of Integer)
For Each r As DataGridViewRow In DataGridView1.Rows
existingNumbers.Add(CInt(r.Cells(0).Value))
Next
Dim min = 1
Dim max = existingNumbers.Max()
Dim missingNumbers = Enumerable.Range(min, max - min + 1).Except(existingNumbers)
MsgBox("Missing: " & String.Join(", ", missingNumbers))
End Sub