Excel VB subscript out of range repairing macro - vba

Question

Here is the declaration of navrec
Public navrec(1 To 100000, 100) As Variant
navrec(r,c) = Cells(r,c)
I encounter a subscript out of range error on the above for loop line within the below procedure
I am attempting to repair this macro with limited working knowledge of VB-Excel. I am assuming the preceding for loop ranges' navreclr & navreclc are referencing too large of a data area?
Sub import_navr()
EntityList = mywkb.Sheets("Source Files").Range("nrlist")
navreclr = 0
days = 0
fname = navrecloc
If Dir(fname) = "" Then
MsgBox ("Please save current PVAL. Macro will end")
End
End If
Workbooks.Open fname, ReadOnly:=True
Set tempbk = ActiveWorkbook
navreclr = Cells(1048576, 1).End(xlUp).Row
navreclc = Sheets(1).Cells(1, 1).End(xlToRight).Column
For r = 1 To navreclr
For c = 1 To navreclc
navrec(r, c) = Cells(r, c)
Next c
Next r
For c = 1 To navreclc
If navrec(1, c) = "ENTITY_ID" Then einr = c
If navrec(1, c) = "SHARE_CLASS" Then scnr = c
If navrec(1, c) = "LEDGER_ITEMS" Then linr = c
If navrec(1, c) = "BALANCE_CHANGE" Then bcnr = c
Next c
Set ofs = CreateObject("Scripting.FileSystemObject")
mywkb.Sheets("Source Files").Range("nrlist").Cells(1, 2) = ofs.GetFile(fname).Datelastmodified
tempbk.Close savechanges:=False
End Sub

Answer 1

The problem is that your array, navrec, is not the correct size to hold all of the cells. You can fix this by adding the following code directly above your loop (I've included the loop below):
ReDim navrec(navreclr, navreclc) As Variant
For r = 1 To navreclr
For c = 1 To navreclc
navrec(r, c) = Cells(r, c)
Next c
Next r
When you are determining the dimensions of your array dynamically, as in this example, it is generally best to declare the array dynamically as well, and not use a constant size. Try not to overutilize memory unless there is a good reason to do so.
You will also need to declare the variable dimensionless in the global module, or you will get an error stating "Array already dimensioned."
Replace:
Public navrec(1 To 100000, 100) As Variant
with
Public navrec() As Variant
to eliminate this error.

Answer 2

You can pick up the value of a rectangular array directly in one operation:
Set tempbk = Workbooks.Open(fname, ReadOnly:=True)
With tempbk.Sheets(1)
'get row/col counts
navreclr = .Cells(.Rows.Count, 1).End(xlUp).Row
navreclc = .Cells(1, .Columns.Count).End(xlToLeft).Column
'assign range value to array
nacrec = .cells(1).Resize(navreclr, navreclc).Value
End With