Oracle SQL - Keeping Comments from previous table in new table - sql

Question

EDIT:Thank you, I got one step further, but can't seem to get it working since the original tables are accessed by a database link.
I access have a lot of tables with descriptions of the columns in the comments section.
Is there any way to copy the comments over when I create a new table, besides adding it manually afterwards?
Select a.tot_sum
,b.id
,b.size
from original_table a
,someother_table b
where a.id=b.id
and b.region in 'North'
I can do it manually with some copypasting in excel:
Comment On Column Mytable.Tot_Sum
Is 'Total sum of sales';
But I want to do something like this:
Comment On Column Mytable.Tot_Sum
IS (select comment from column original_table.tot_sum);
Or is there a syntax to simply keep the comments when creating a new table?

Answer 1

You can query ALL_COL_COMMNENTS.
You can automate this with a small PL/SQL anonymous block :
SQL> set serveroutput on;
SQL> DECLARE
2 v_ViewName VARCHAR2(30) := 'XXX';
3 BEGIN
4 FOR v_Comment IN
5 (SELECT acc.COLUMN_NAME,
6 REPLACE(REPLACE(acc.COMMENTS, chr(13), ''), chr(10), '') comments
7 FROM ALL_COL_COMMENTS ACC
8 WHERE ACC.OWNER = 'SCOTT'
9 AND ACC.TABLE_NAME = 'EMP'
10 )
11 LOOP
12 dbms_output.put_line(v_comment.column_name || ' - '||v_comment.comments);
13 END LOOP;
14 END;
15 /
EMPNO -
ENAME -
JOB -
MGR -
HIREDATE -
SAL -
COMM -
DEPTNO -
PL/SQL procedure successfully completed.
If you have any table with some comments, just replace the USER and TABLE_NAME in my script.

Answer 2

declare
comment_ varchar2(255);
begin
select comments into comment_ from user_col_comments
where table_name=upper('original_table')
and column_name=upper('my_column');
execute immediate 'comment on column new_table.my_column is '''||comment_||'''';
end;
COMMENT function accept only text literals, that's why I used dynamic query instead of IS SELECT

Answer 3

There are DBA-Views for the comments.
DBA_COL_COMMENTS
ALL_COL_COMMENTS
USER_COL_COMMENTS
You could do something like that:
declare
v_comment varchar2(100);
v_stmt varchar2(4000);
begin
select comments
into v_comment
from user_col_comments
where table_name= 'ORIGINAL_TABLE'
and column_name='TOT_SUM';
v_stmt:='comment on column MYTABLE.TOT_SUM IS '''||v_comment||'''';
execute immediate v_stmt;
end;
Edit: When you have a lot of columns, you could automate it by doing this:
declare
v_comment varchar2(100);
v_stmt varchar2(4000);
v_orig_table varchar2(100) :='ORIGINAL_TABLE';
v_new_table varchar2(100) :='MYTABLE';
begin
for c in (select column_name
from user_tab_columns c
where table_name=v_orig_table
and exists(select 1
from user_tab_columns
where table_name=v_new_table
and column_name=c.column_name)) loop
select comments
into v_comment
from user_col_comments
where table_name= v_orig_table
and column_name=c.column_name;
v_stmt:='comment on column '||v_new_table||'.'||c.column_name||' IS '''||v_comment||'''';
execute immediate v_stmt;
end loop;
end;
Edit 2: Version with SCHEMA_Name and DB-Link
declare
v_comment varchar2(100);
v_stmt varchar2(4000);
v_orig_table varchar2(100) :='ORIGINAL_TABLE';
v_orig_schema varchar2(100) := 'ORIG_OWNER';
v_new_table varchar2(100) :='MYTABLE';
begin
for c in (select column_name
from all_tab_columns#db.link c
where table_name=v_orig_table
and owner=v_orig_schema
and exists(select 1
from user_tab_columns
where table_name=v_new_table
and column_name=c.column_name)) loop
select comments
into v_comment
from all_col_comments#db.link
where table_name= v_orig_table
and column_name=c.column_name
and owner=v_orig_schema;
v_stmt:='comment on column '||v_new_table||'.'||c.column_name||' IS '''||v_comment||'''';
execute immediate v_stmt;
end loop;
end;