trying to create a sequential ID variable for breeds in netlogo - variables

Question

There is probably a very simple solution to this, but I am having trouble coming up with it since I'm still pretty new to netlogo. I'd be very grateful for any suggestions. My model has multiple breeds of turtles with different numbers of turtles in each breed set by sliders. To make it easier to set some breeds-own variables later in the model, I want to create separate sequential ID variables for each breed. These would basically be like who numbers, but would run from 0 to n for each breed. So, let's say I create male and female breeds like this:
breed [males male]
breed [females female]
to setup
clear-all
create-breeds
set-id
ask turtles [setxy random-xcor random-ycor ]
reset-ticks
end
to create-breeds
create-males number-males [set color yellow]
ask males [set shape "circle"]
create-females number-females [set color yellow]
ask females [set shape "circle 2"]
end
to set-id
...
end
I then want to run a "set-id" procedure that will create a male id var that will number the male turtles from 0 to male n, and another female id var that will number the female turtles from 0 to female n. I am assuming the solution should include some combination of foreach or n-values, but I'm having a lot of trouble nailing it down exactly. Thanks!

Answer 1

Don't do it!
I'm pretty sure it won't "make it easier to set some breeds-own variables later in the model". Using who numbers is error prone enough as it is without adding another separate index on top of it. (You shouldn't use who numbers either: there is almost always a better way to do things.) I'd suggest you ask another, separate, question and tell us why you think you need that and what you plan to do with it. I'm confident that someone will be able to suggest an alternative approach.
That being said...
You are right that a combination of foreach and n-values would do the trick.
Assuming you have:
males-own [ id ]
females-own [ id ]
You can use the following procedure:
to set-id-for [ breed-agents ]
(foreach (sort breed-agents) (n-values count breed-agents [?]) [
ask ?1 [ set id ?2 ]
])
end
By using parenthesis around foreach, you can pass it as many lists as you like: it will "zip" them together and give you variables like ?1, ?2, etc., to address elements of each list. In our case, the first list is the agents and the second list is indices generated with n-values.
Call the procedure once for each breed:
set-id-for males
set-id-for females
Supposing you have created 10 males and called set-id-for males, you can verify that it worked using the command center:
observer> show sort [id] of males
observer: [0 1 2 3 4 5 6 7 8 9]
But please...
...don't do it.

Answer 2

You can do it if you create a global variable and you use it inside of create male/female procedures:
globals [id]
breed [males male]
breed [females female]
males-own [id-male]
females-own [id-female]
to setup
clear-all
create-breeds
ask turtles [setxy random-xcor random-ycor ]
reset-ticks
end
to create-breeds
set id 0
create-males number-males
[
set id-male id
set color yellow
set shape "circle"
set id id + 1
]
set id 0
create-females number-females
[
set id-female id
set color yellow
set shape "circle 2"
set id id + 1
]
end
And you can include the "set shape" inside of create procedure.