Splitting UK Postcodes by matching to their outcode - ms-access-2007

Question

I have been given a list of UK postcodes, with the following format L15TG or TS14TGU.
I need to be able to match these postcodes to a list of postcodes I have stored in the database, however, my list are only UK outcodes, so L15TG is just L1 and TS14TGU is just TS14.
So I need to match the records and return the part of the string that matches i.e take L1 from L15TG.

Answer 1

Okay, so we have a table named [BadCodes]
BadCode
-------
L15TG
TS14TGU
and a table named [OutCodes]
OutCode
-------
L1
TS14
I would add two Text fields to the [BadCodes] table: [OuterCode] and [InnerCode]
Then I would use the following VBA code to populate [BadCodes].[OuterCode]
Option Compare Database
Option Explicit
Public Sub PopulateOuterCodes()
Dim cdb As DAO.Database, qdf As DAO.QueryDef, rstOutCodes As DAO.Recordset
Set cdb = CurrentDb
Set qdf = cdb.CreateQueryDef("", _
"PARAMETERS prmOuterCode TEXT(255), prmLike TEXT(255);" & _
"UPDATE BadCodes SET OuterCode=[prmOuterCode] " & _
"WHERE BadCode LIKE [prmLike] AND OuterCode IS NULL")
Set rstOutCodes = cdb.OpenRecordset( _
"SELECT OutCode FROM OutCodes " & _
"ORDER BY Len(OutCode) DESC, OutCode", _
dbOpenSnapshot)
Do Until rstOutCodes.EOF
qdf!prmOuterCode = rstOutCodes!OutCode
qdf!prmLike = rstOutCodes!OutCode & "*"
qdf.Execute
rstOutCodes.MoveNext
Loop
rstOutCodes.Close
Set rstOutCodes = Nothing
Set qdf = Nothing
Set cdb = Nothing
End Sub
After running that VBA code my [BadCodes] table would look like
BadCode OuterCode InnerCode
------- --------- ---------
L15TG L1
TS14TGU TS14
Then I could populate [BadCodes].[InnerCode] with the query
UPDATE BadCodes
SET InnerCode = Replace(BadCode,OuterCode,"",1,1)
and my [BadCodes] table would now look like
BadCode OuterCode InnerCode
------- --------- ---------
L15TG L1 5TG
TS14TGU TS14 TGU