Batch file. Variable input from a file not working - variables

Question

So heres what I'm trying to do. I'm taking the variable from a text file they look like this
000001 server1 server2
000002 server2 server1
the 1st set of code i wrote would execute but only the last line of the text file
Set _InputFile=c:\usermovelist.txt
For /F "tokens=1-3* delims= " %%A IN (%_InputFile%) DO (
Set _var1=%%A
Set _var2=%%B
Set _var3=%%C
)
xcopy \\%_var2%\e$\profiles\%_var1%.V2 \\%_var3%\e$\profiles\%_var1%.V2 /m /e /y /O /h
xcopy \\%_var2%\e$\users\%_var1% \\%_var3%\e$\users\%_var1% /m /e /y /O /h
pause
ren \\%_var2%\e$\profiles\%_var1%.V2 %_var1%.old.V2.%int%.%date:~-10,2%.%date:~-7,2%.%date:~-4,4%
ren \\%_var2%\e$\users\%_var1% %_var1%.old.%int%.%date:~-10,2%.%date:~-7,2%.%date:~-4,4%
So then I tried this
Set _InputFile=c:\usermovelist.txt
For /f "tokens=* delims= " %%f in (%_InputFile%) do (
set line=%%f
call :processToken
)
:processToken
For /F "tokens=1-3* delims= " %%A IN (%line%) DO (
Set _var1=%%A
Set _var2=%%B
Set _var3=%%C
)
xcopy \\%_var2%\e$\profiles\%_var1%.V2 \\%_var3%\e$\profiles\%_var1%.V2 /m /e /y /O /h
xcopy \\%_var2%\e$\users\%_var1% \\%_var3%\e$\users\%_var1% /m /e /y /O /h
pause
ren \\%_var2%\e$\profiles\%_var1%.V2 %_var1%.old.V2.%int%.%date:~-10,2%.%date:~-7,2%.%date:~-4,4%
ren \\%_var2%\e$\users\%_var1% %_var1%.old.%int%.%date:~-10,2%.%date:~-7,2%.%date:~-4,4%
But this doesnt read the variables into the xcopy part of it but it reads line by line which i also need it to do. I can hit any key and it moves down each line
C:\Users\xxxxx\Desktop>For /F "tokens=1-3* delims= " %A IN (000002 server2 server1) DO (
Set _var1=%A
Set _var2=%B
Set _var3=%C
I'm new to this so thanks in advance for any help!Sorry for the long post I bolded the good stuff

Answer 1

Remove unneeded variables
Set "_InputFile=c:\usermovelist.txt"
For /F "usebackq tokens=1-3* delims= " %%A IN ("%_InputFile%") DO (
xcopy \\%%B\e$\profiles\%%A.V2 \\%%C\e$\profiles\%%A.V2 /m /e /y /O /h
xcopy \\%%B\e$\users\%%A \\%%C\e$\users\%%A /m /e /y /O /h
pause
ren \\%%B\e$\profiles\%%A.V2 %%A.old.V2.%int%.%date:~-10,2%.%date:~-7,2%.%date:~-4,4%
ren \\%%B\e$\users\%%A %%A.old.%int%.%date:~-10,2%.%date:~-7,2%.%date:~-4,4%
)