Whats the best download method for vb? - vb.net

Question

I am trying to make a download client with ftp and im still trying to find out whats the best i have but im in stuck because i followed a guide but it only show how much its have downloaded in bytes, how can i change it to gb? and how can i add a download speed?
Imports System.Net
Public Class MainForm
Private Sub MainForm_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Control.CheckForIllegalCrossThreadCalls = False
End Sub
Private Sub btnBrowseSave_Click(sender As Object, e As EventArgs) Handles btnBrowseSave.Click
Dim newFolder As New FolderBrowserDialog
If newFolder.ShowDialog = Windows.Forms.DialogResult.OK Then
txtSavePath.Text = newFolder.SelectedPath
End If
End Sub
Private Sub btnDownload_Click(sender As Object, e As EventArgs) Handles btnDownload.Click
bWorker.RunWorkerAsync()
End Sub
Private Sub bWorker_DoWork(sender As Object, e As System.ComponentModel.DoWorkEventArgs) Handles bWorker.DoWork
Dim buffer(1023) As Byte
Dim bytesIn As Integer
Dim totalBytesIn As Integer
Dim output As IO.Stream
Dim flLength As Integer
Try
Dim FTPRequest As FtpWebRequest = DirectCast(WebRequest.Create(txtFilePath.Text), FtpWebRequest)
FTPRequest.Credentials = New NetworkCredential(txtFTPUsername.Text, txtFTPPassword.Text)
FTPRequest.Method = Net.WebRequestMethods.Ftp.GetFileSize
flLength = CInt(FTPRequest.GetResponse.ContentLength)
lblFileSize.Text = flLength & " bytes"
Catch ex As Exception
End Try
Try
Dim FTPRequest As FtpWebRequest = DirectCast(WebRequest.Create(txtFilePath.Text), FtpWebRequest)
FTPRequest.Credentials = New NetworkCredential(txtFTPUsername.Text, txtFTPPassword.Text)
FTPRequest.Method = WebRequestMethods.Ftp.DownloadFile
Dim stream As System.IO.Stream = FTPRequest.GetResponse.GetResponseStream
Dim OutputFilePath As String = txtSavePath.Text & "\" & IO.Path.GetFileName(txtFilePath.Text)
output = System.IO.File.Create(OutputFilePath)
bytesIn = 1
Do Until bytesIn < 1
bytesIn = stream.Read(buffer, 0, 1024)
If bytesIn > 0 Then
output.Write(buffer, 0, bytesIn)
totalBytesIn += bytesIn
lblDownloadedBytes.Text = totalBytesIn.ToString & " bytes"
If flLength > 0 Then
Dim perc As Integer = (totalBytesIn / flLength) * 100
bWorker.ReportProgress(perc)
End If
End If
Loop
output.Close()
stream.Close()
Catch ex As Exception
MessageBox.Show(ex.Message)
End Try
End Sub
Private Sub bWorker_ProgressChanged(sender As Object, e As System.ComponentModel.ProgressChangedEventArgs) Handles bWorker.ProgressChanged
pBar.Value = e.ProgressPercentage
lblPercent.Text = e.ProgressPercentage.ToString & "%"
End Sub
Private Sub bWorker_RunWorkerCompleted(sender As Object, e As System.ComponentModel.RunWorkerCompletedEventArgs) Handles bWorker.RunWorkerCompleted
MsgBox("Download Complete!")
End Sub
End Class

Answer 1

1 KB = 210 bytes = 1,024 bytes
1 MB = 210 KB = 220 bytes = 1,048,576 bytes
1 GB = 210 MB = 230 bytes = 1,073,741,824 bytes
1 TB = 210 GB = 240 bytes = 1,099,511,627,776 bytes
The next units are Petabytes PB and Exabytes EB (maybe in future computer generations?).
Here is a function that formats the byte numbers. It determines the appropriate unit automatically:
Public Function FormatBytes(ByVal bytes As Long) As String
Dim sizes As String() = {"B", "KB", "MB", "GB", "TB", "PB", "EB"}
Dim order As Integer = 0
Dim len As Double = bytes
While len >= 1024 AndAlso order + 1 < sizes.Length
order += 1
len = len / 1024
End While
Return String.Format("{0:0.0} {1}", len, sizes(order))
End Function
Initialize the worker with:
bWorker.WorkerReportsProgress = True
You can also pass the number of bytes instead of a percentage to the ReportProgress method. The BackgroundWorker doesn't care. Because big files might exceed Integer.MaxValue declare totalBytesIn As Long instead as of Integer and pass the progress in KB to the ReportProgress method:
bWorker.ReportProgress(CInt(totalBytesIn / 1024))
In the ProgressChanged event handler:
Private Sub bWorker_ProgressChanged(ByVal sender As Object, _
ByVal e As ProgressChangedEventArgs) _
Handles bWorker.ProgressChanged
Me.txtProgress.Text = FormatBytes(1024 * e.ProgressPercentage)
' More code to come here ... (see below)
End Sub
As for the speed you could use a System.Diagnostics.Stopwatch. It shows you the elapsed time.
Dim stopwatch As New System.Diagnostics.Stopwatch()
stopwatch.Start()
And then in bWorker_ProgressChanged:
Dim elapsedSeconds As Double = stopwatch.ElapsedMilliseconds / 1000
If elapsedSeconds > 0 Then
Dim speed As Double = bytes / elapsedSeconds
lblSpeed.Text = FormatBytes(CInt(speed)) & " / s"
End If
The final version of the progress changed event handler:
Private Sub bWorker_ProgressChanged(ByVal sender As Object, _
ByVal e As System.ComponentModel.ProgressChangedEventArgs) _
Handles bWorker.ProgressChanged
Dim bytes As Long = 1024 * e.ProgressPercentage
'Can exceed 100% beacause of rounding effects
Dim percent As Integer = Math.Min(100, CInt(100 * bytes \ flLength))
pBar.Value = percent
lblPercent.Text = percent & "%"
lblDownloadedBytes.Text = FormatBytes(bytes)
Dim elapsedSeconds As Double = stopwatch.ElapsedMilliseconds / 1000
If elapsedSeconds > 0 Then
Dim speed As Double = bytes / elapsedSeconds
lblSpeed.Text = FormatBytes(CInt(speed)) & " / s"
End If
End Sub
And if you declare flLength in the Form instead as local variable, you can calculate and display the percentages in bWorker_ProgressChanged as well.
As you have troubles understanding my answer, here is the complete code. Where possible I kept your code as is and marked my changes with comments ('===). (I had only my code snippets from above until now, so I had to create a form with all the required controls. It's tested and it works):
Imports System.Net
Public Class MainForm
Dim flLength As Long '=== As Form variable instead as local variable and As Long.
Dim stopwatch As New System.Diagnostics.Stopwatch() '=== New variable.
Private Sub MainForm_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
Control.CheckForIllegalCrossThreadCalls = False
End Sub
Private Sub btnBrowseSave_Click(ByVal sender As Object, ByVal e As EventArgs) Handles btnBrowseSave.Click
Dim newFolder As New FolderBrowserDialog
If newFolder.ShowDialog = Windows.Forms.DialogResult.OK Then
txtSavePath.Text = newFolder.SelectedPath
End If
End Sub
Private Sub btnDownload_Click(ByVal sender As Object, ByVal e As EventArgs) Handles btnDownload.Click
bWorker.RunWorkerAsync()
End Sub
Private Sub bWorker_DoWork(ByVal sender As Object, ByVal e As System.ComponentModel.DoWorkEventArgs) Handles bWorker.DoWork
Dim buffer(1023) As Byte
Dim bytesIn As Integer
Dim totalBytesIn As Long '=== As Long instead of Integer
Dim output As IO.Stream
'Dim flLength As Integer '=== Now as form variable
Try
Dim FTPRequest As FtpWebRequest = DirectCast(WebRequest.Create(txtFilePath.Text), FtpWebRequest)
FTPRequest.Credentials = New NetworkCredential(txtFTPUsername.Text, txtFTPPassword.Text)
FTPRequest.Method = Net.WebRequestMethods.Ftp.GetFileSize
flLength = CInt(FTPRequest.GetResponse.ContentLength)
lblFileSize.Text = flLength & " bytes"
Catch ex As Exception
End Try
Try
stopwatch.Start() '=== Start Stopwatch
Dim FTPRequest As FtpWebRequest = DirectCast(WebRequest.Create(txtFilePath.Text), FtpWebRequest)
FTPRequest.Credentials = New NetworkCredential(txtFTPUsername.Text, txtFTPPassword.Text)
FTPRequest.Method = WebRequestMethods.Ftp.DownloadFile
Dim stream As System.IO.Stream = FTPRequest.GetResponse.GetResponseStream
Dim OutputFilePath As String = txtSavePath.Text & "\" & IO.Path.GetFileName(txtFilePath.Text)
output = System.IO.File.Create(OutputFilePath)
bytesIn = 1
Do Until bytesIn < 1
bytesIn = stream.Read(buffer, 0, 1024)
If bytesIn > 0 Then
output.Write(buffer, 0, bytesIn)
totalBytesIn += bytesIn
lblDownloadedBytes.Text = totalBytesIn.ToString & " bytes"
If flLength > 0 Then
'=== Moved to bWorker_ProgressChanged.
'Dim perc As Integer = (totalBytesIn / flLength) * 100
'=== Now reports downloaded bytes in KB instead of percent.
bWorker.ReportProgress(CInt(totalBytesIn / 1024))
End If
End If
Loop
output.Close()
stream.Close()
Catch ex As Exception
MessageBox.Show(ex.Message)
End Try
End Sub
'=== Completely reworked
Private Sub bWorker_ProgressChanged(ByVal sender As Object, _
ByVal e As System.ComponentModel.ProgressChangedEventArgs) _
Handles bWorker.ProgressChanged
Dim bytes As Long = 1024 * e.ProgressPercentage
'Can exceed 100% beacause of rounding effects
Dim percent As Integer = Math.Min(100, CInt(100 * bytes \ flLength))
pBar.Value = percent
lblPercent.Text = percent & "%"
lblDownloadedBytes.Text = FormatBytes(bytes)
Dim elapsedSeconds As Double = stopwatch.ElapsedMilliseconds / 1000
If elapsedSeconds > 0 Then
Dim speed As Double = bytes / elapsedSeconds
lblSpeed.Text = FormatBytes(CInt(speed)) & " / s"
End If
End Sub
Private Sub bWorker_RunWorkerCompleted(ByVal sender As Object, ByVal e As System.ComponentModel.RunWorkerCompletedEventArgs) Handles bWorker.RunWorkerCompleted
MsgBox("Download Complete!")
End Sub
'=== New Function
Private Function FormatBytes(ByVal bytes As Long) As String
Dim sizes As String() = {"B", "KB", "MB", "GB", "TB", "PB", "EB"}
Dim order As Integer = 0
Dim len As Double = bytes
While len >= 1024 AndAlso order + 1 < sizes.Length
order += 1
len = len / 1024
End While
Return String.Format("{0:0.0} {1}", len, sizes(order))
End Function
End Class
See: How to: Use a Background Worker