PL/SQL Function and Exception - sql

Question

I am new to PL/SQL and I am writing a somewhat complex script. In order to make the script a little cleaner, I would like to create many functions. However I am not very familiar with functions.
Can a function has VOID return type? If I have to have a return, how will it work with exception handling?
See below:
EX:
DECLARE
some_variable NUMBER;
FUNCTION myFunc1(pInput IN NUMBER) RETURN NUMBER
IS
BEGIN
-- DO SOMETHING
EXCEPTION
WHEN someException THEN
DBMS_OUTPUT.PUT_LINE('ERROR someException ');
WHEN Others THEN
DBMS_OUTPUT.PUT_LINE('ERROR');
-----------------------------
-- WHERE DO I PUT THE RETURN?
-----------------------------
END;
FUNCTION myFunc2(pInput IN NUMBER) -- CAN IT RETURN NOTH
IS
fun1Return NUMBER;
BEGIN
-- DO SOMETHING
fun1Return := myFunc1(1);
EXCEPTION
WHEN someException THEN
DBMS_OUTPUT.PUT_LINE('ERROR someException ');
WHEN Others THEN
DBMS_OUTPUT.PUT_LINE('ERROR');
END;
BEGIN
--- DO SOMETHING
some_variable := myFunc2(2);
EXCEPTION
WHEN someException THEN
DBMS_OUTPUT.PUT_LINE('ERROR someException ');
WHEN Others THEN
DBMS_OUTPUT.PUT_LINE('ERROR');
END;

Answer 1

This is covered pretty well in the documentation.
A function has to return before the exception handler, if you have one. But in your example you should not be catching the exceptions really as you are just squashing the errors, and you're assuming whoever calls this will be able to see the dbms_output which is not a safe assumption. If you don't re-raise the (or any) exception then you still need to return from the exception handlers as well as from the main body of the block:
FUNCTION myFunc1(pInput IN NUMBER) RETURN NUMBER
IS
BEGIN
-- DO SOMETHING
RETURN 0;
EXCEPTION
WHEN someException THEN
DBMS_OUTPUT.PUT_LINE('ERROR ' || SQLERRM);
-- how do you know where the exception was raised?
RETURN -1;
WHEN Others THEN
DBMS_OUTPUT.PUT_LINE('ERROR');
-- how does the caller know what went wrong?
RETURN -2;
END;
You're also hiding all details of the error and removing any hope of being able to find out what actually went wrong. Catching when others is particularly evil, especially if you don't re-raise the exception. If you really want to display your own message you should still re-raise the original exception, in which case you won't need to return again:
FUNCTION myFunc1(pInput IN NUMBER) RETURN NUMBER
IS
BEGIN
-- DO SOMETHING
RETURN 0;
EXCEPTION
WHEN someException THEN
DBMS_OUTPUT.PUT_LINE('ERROR ' || SQLERRM);
RAISE;
WHEN Others THEN
DBMS_OUTPUT.PUT_LINE('ERROR');
RAISE;
END;
Which is very slightly better but you still lose some information about the error stack. You probably don't really want to catch these at all:
FUNCTION myFunc1(pInput IN NUMBER) RETURN NUMBER
IS
BEGIN
-- DO SOMETHING
RETURN 0;
END;
The only reason to catch an exception really is if it's something you sort of expect and can handle elegantly. Anything else - especially other - is almost always better off left to propagate up the call stack.
You can also have multiple returns if you have branches in your function.
FUNCTION myFunc1(pInput IN NUMBER) RETURN NUMBER
IS
BEGIN
IF SOMETHING THEN
RETURN 1;
END IF;
RETURN 0;
END;
As #couling says, a function with no return is a procedure. Stripping the exception again:
PROCEDURE myProc2(pInput IN NUMBER)
IS
fun1Return NUMBER;
BEGIN
-- DO SOMETHING
fun1Return := myFunc1(1);
END;