Find and Replace and Looping Though a Table - vba

Question

I am trying to make a user friendly excel interface to replace values in a large data set using vba.
I have a small table with the Columns "Replace What" and "Replace With" and the large data set in a worksheet together.
My goal is to hit a button and have a macro use the Find function on the data to look up the number in the Replace What Column and then paste in the data from the corresponding row of the Replace With column.
Here's my code so far:
Sub ReplaceItems()
Dim replaceList As Range
Set replaceList = ListItems("Table4").ListColummns("Replace What").DataBodyRange
Dim item As Range
For Each Cell In replaceList.Cells
Cell.Offset(0, 1).Select.Copy
item = ActiveWorksheet.Find(Cell.Value)
item.Select.Paste
Next Cell
End Sub

Answer 1

You could use a dictionary to quickly map the Replace What key to the Replace With values. Then check if a key appears in the cell's value (you can use a combination of Index-match and InStr/RegEx, but I would probably just loop through the cells). Finally delete the key from the cell and copy in the value, you can do this in one line using Left() and Right() functions
Ex. Using a dictionary
Sub dictionary()
Dim key As String, value As String, var As Variant
Dim d As Object
Set d = CreateObject("Scripting.Dictionary")
key = "my key"
value = "my value"
d.Add key, value
d.Add key & 1, value & 1
For Each var In d.keys
MsgBox var & " : " & d.item(var)
Next var
End Sub
Ex. Replace key with value
Sub ReplaceItems()
Dim s As String, k As String, v As String, index As Integer
s = "this is my key, I think"
k = "key"
v = "value"
index = InStr(s, k)
MsgBox Left(s, index - 1) & v & Right(s, Len(s) - index - Len(k) + 1)
End Sub

Answer 2

I happen to have this kind of routine so I'll share.
Like what Alter posted, I used Dictionary.
Sub test()
Dim RepList As Range, RepItem As Range
Dim rng As Range, ldbase As Variant
Dim i As Long
With Sheet1 '~~> contains your table, change to suit
Set RepList = .Range("Table4[Replace What]")
End With
With Sheet2 '~~> contains your large database, change to suit
'~~> transfer your database in an array
'~~> I this example, my target is the whole column B with data.
Set rng = .Range("B2", .Range("B" & .Rows.Count).End(xlUp))
ldbase = Application.Transpose(rng) 'dumps range values to array
End With
With CreateObject("Scripting.Dictionary")
'~~> first transfer your list in Dictionary
For Each RepItem In RepList
If Not .Exists(RepItem.Value) Then
.Add RepItem.Value, RepItem.Offset(0, 1).Value
End If
Next
'~~> here is the actual find and replace
For i = LBound(ldbase) To UBound(ldbase)
If .Exists(ldbase(i)) Then ldbase(i) = .Item(ldbase(i))
Next
rng = Application.Transpose(ldbase) '~~> dumps array values to range
End With
End Sub
HTH.