Comparing variables in awk - awk

Question

My file has timestamps in its 6th field which looks like this: Mon Jul 7 14:53:16 PDT 2014
I want to get all those lines from this file whose 6th field values are within the last 24 hours.
Sample Input:
abc -> /aa/bbb, hello, /home/user/blah.pl, 516, usc, Mon Jul 4 10:06:33 PDT 2014
abc -> /aa/bbb, hello, /home/user/blah.pl, 516, usc, Mon Jul 5 10:06:33 PDT 2014
abc -> /aa/bbb, hello, /home/user/blah.pl, 516, usc, Mon Jul 7 07:06:33 PDT 2014
abc -> /aa/bbb, hello, /home/user/blah.pl, 516, usc, Mon Jul 7 08:06:33 PDT 2014
abc -> /aa/bbb, hello, /home/user/blah.pl, 516, usc, Mon Jul 7 09:06:33 PDT 2014
abc -> /aa/bbb, hello, /home/user/blah.pl, 516, usc, Mon Jul 7 10:06:33 PDT 2014
The field delimiter is comma.
Sample Code
But it's not working as expected:
awk 'BEGIN {FS = ","};
{ a=$6;
aint=a +"%y%m%d%H%M%S";
yestint=$(date --date='1 day ago' +"%y%m%d%H%M%S");
if (aint>yestint)
print aint;
}' /location/canzee/textfile.txt
Sample Output
I get an output like this:
awk: cmd. line:4: yestint=$(date --date=1
awk: cmd. line:4: ^ syntax error
awk: cmd. line:5: (END OF FILE)
awk: cmd. line:5: syntax error
Desired Output
Mon Jul 7 07:06:33 PDT 2014
Mon Jul 7 08:06:33 PDT 2014
Mon Jul 7 09:06:33 PDT 2014
Mon Jul 7 10:06:33 PDT 2014
I would like to know how to go about this if I can't call shell commands like date within awk command. I hope its clear enough.

Answer 1

Here's a sketch of an idea. Beware that it is gawk-specific.
# An array to convert abbreviated month names to numbers.
BEGIN {m["Jan"]=1; m["Feb"]=2; m["Mar"]=3; m["Apr"]=4; m["May"]=5; m["Jun"]=6
m["Jul"]=7; m["Aug"]=8; m["Sep"]=9; m["Oct"]=10; m["Nov"]=11; m["Dec"]=12;}
# later in your script
{
# systime() gives the number of seconds since the "epoch".
# Subtract 24-hours-worth of seconds from it to get "yesterday".
# (Note that this is yesterday at a specific time, which may not
# really be what you want.)
yest = systime() - 24 * 60 * 60;
a = "Mon Jul 7 14:27:56 PDT 2014" # or however a gets its value
# Split the fields of a into the array f (splitting on spaces).
split(a, f, " ");
# Split the fields of f[4] (the time) into the array t (splitting on colons).
split(f[4], t, ":")
# mktime() converts a date specification into seconds since the epoch.
# The datespec format is: 2014 7 7 14 27 56 [optional dst flag]
# If the daylight savings time flag is left out the system tries to determine
# whether or not dst is in effect.
tm = mktime(f[6] " " m[f[2]] " " f[3] " " t[1] " " t[2] " " t[3])
#Compare the seconds since epochs.
if (tm > yest)
...
}
In the context of your program, it might be done like this:
awk '
BEGIN {
m["Jan"]=1; m["Feb"]=2; m["Mar"]=3; m["Apr"]=4; m["May"]=5; m["Jun"]=6
m["Jul"]=7; m["Aug"]=8; m["Sep"]=9; m["Oct"]=10; m["Nov"]=11; m["Dec"]=12;
FS = "[[:space:]]*,[[:space:]]*"
yest = systime() - 24 * 60 * 60;
}
{
split($6, f, " ")
split(f[4], t, ":")
tm = mktime(f[6] " " m[f[2]] " " f[3] " " t[1] " " t[2] " " t[3])
if (tm > yest)
print $6;
}
' /location/canzee/textfile.txt