Searching a column and evaluating adjacent cell in excel - vba

Question

I'm trying to make a spreadsheet that can tell me when somebody is in doing two things at the same time. say column A contains names, column B has the sign in time, and C has Sign out time. I am trying to find a way to assess whether any other instances of the same name had overlap in the time in and time out. I considered Vlookup, but that only gets me to the first instance.
Essentially I'm looking for if(A from this row exists anywhere else in column A and the adjacent B cell >= this row's B cell and the adjacent C cell >= this row's C cell, then true, otherwise do something else)
I work in a machine shop, and it's very common for people to work two machines at the same time. I understand my example a moment ago was only one of several possible ways the times could overlap, but if I could get help getting that far I would be ecstatic. even pointing me in the broadest of directions like "not possible without learning to code" would be helpful.
My excel skills are limited essentially to what I can learn in the help file, and as of now I'm ok with ifs. Any help would be appreciated. Do I need to learn VBA for this?

Answer 1

I am not an Excel power user. I learnt VBA because of employers who provided me with Excel but would not allow me use of other programmable tools. I have never made serious use of the more advanced capabilities of Excel. There are a surprising number of questions that get the comment, "you could do this with a Pivot table" but never an explanation of how. To be fair questions about Pivot Table belong on the SuperUser site but I find it a really unhelpful comment.
I do not know and do not care if your requirement can be met with a Pivot Table. I wish to show how simple tasks can be solved with VBA even if they cannot be solved with advanced Excel functionality. The macro below did not take long to write and I believe it meets your requirement.
Yes you should learn VBA. It does not take long to learn the basics and it can be used to solve many simple problems. I cannot imagine not being able to create macros or programs to solve day-to-day problems.
Search the web for "Excel VBA tutorial". There are many to choose from. Try a few and complete one that matches your learning style. I prefer books to online tutorials. I visited a large library and checked out their Excel VBA Primers. I then bought the one that worked best for me.
I will admit there is a lot of practice behind the macro below but I believe the real skill is in breaking your requirement into steps that can be solved easily with Excel VBA.
I created a worksheet Log which I filled with data that matches my understanding of your data. Perhaps your people do not run so many machines at the same time but I wanted to test my macro thoroughly.
The macro creates a copy of this worksheet (in case you do not want it sorted) and names it Temp. It then sorts Temp by Name and Sign-on time to give:
The macro compares adjacent rows and copies overlaps to worksheet Overlap:
Finally it deletes worksheet Temp.
My objective was to fully explain what the code does but not how the macro does it. Once you know a statement exists, it is usually easy to look it up. Come back with questions if necessary but the more you can decipher for yourself the faster you will develop your skills.
Option Explicit
Sub FindOverlap()
Dim RowOverCrnt As Long
Dim RowTempCrnt As Long
Dim RowTempLast As Long
Dim WithinOverlap As Boolean
Dim WshtLog As Worksheet
Dim WshtOver As Worksheet
' My principle reason for using worksheet objects is so the names appear in a single place.
Set WshtLog = Worksheets("Log") ' Change Log to your name for the source worksheet
Set WshtOver = Worksheets("Overlap") ' Change Log to your name for the destination worksheet
' Create temporary copy of worksheet "Log" in case sequence must be preserved.
' This is not necessary if you do not care if worksheet Log is sorted.
WshtLog.Copy After:=Sheets(Worksheets.Count)
Sheets(Worksheets.Count).Name = "Temp"
' Clear any existing data from destination worksheet and copy the headings from the
' source worksheet
With WshtOver
.Cells.EntireRow.Delete
WshtLog.Rows(1).Copy Destination:=.Range("A1")
End With
RowOverCrnt = 2 ' First to which rows from worksheet Log will be copied
' Sort worksheet Temp by Name and Sign-in time
With Worksheets("Temp")
With .Cells
.Sort Key1:=.Range("A2"), Order1:=xlAscending, _
Key2:=.Range("B2"), Order2:=xlAscending, _
Header:=xlYes, OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
DataOption1:=xlSortNormal, DataOption2:=xlSortNormal
End With
' This is the VBA equivalent of selecting the cell at the bottom of column A
' and clicking Ctrl+Up. With the keyboard, this move the cursor up to the first
' cell with a value and selects that cell. That is, it selects the last cell from
' the top with a value. This statement sets RowTempLadst to the row number of that
' cell.
RowTempLast = .Cells(Rows.Count, "A").End(xlUp).Row
WithinOverlap = False ' Not currently within a set of rows that overlap.
' I assume row 2 is the first data row. This loop checks a row for an overlap with
' the previous row. This is why the start row is 3.
For RowTempCrnt = 3 To RowTempLast
If .Cells(RowTempCrnt, "A").Value = .Cells(RowTempCrnt - 1, "A").Value And _
.Cells(RowTempCrnt, "B").Value < .Cells(RowTempCrnt - 1, "C").Value Then
' The current row and the previous row are for the same person and
' the start time of the current row is before the end time of the previous row
If WithinOverlap Then
' Previous rows have overlapped and have been copied to worksheet Overlap.
' Add current row to end of current set of overlaps
.Rows(RowTempCrnt).Copy Destination:=WshtOver.Cells(RowOverCrnt, "A")
RowOverCrnt = RowOverCrnt + 1 ' Advance to next free row
Else
' The current and previous rows overlap. Copy both to worksheet Overlap.
.Rows(RowTempCrnt - 1 & ":" & RowTempCrnt).Copy _
Destination:=WshtOver.Cells(RowOverCrnt, "A")
RowOverCrnt = RowOverCrnt + 2 ' Advance to next free row
WithinOverlap = True ' Record within overlap set
End If
Else
' Current row does not overlap with previous
If WithinOverlap Then
' An overlap set has ended
RowOverCrnt = RowOverCrnt + 1 ' Leave gap between overlap sets
WithinOverlap = False ' Record no longer within overlap set
End If
End If
Next RowTempCrnt
End With
' Delete worksheet Temp
' "Application.DisplayAlerts = False" suppresses the "Are you sure you want to delete
' this worksheet?" question.
Application.DisplayAlerts = False
Worksheets("Temp").Delete
Application.DisplayAlerts = True
End Sub