VBA Array determine where to put values next - sql

Question

I have a recordset from en SQL server. I don't know the exact amount of data I need to retrieve, hence I have created a dynamic array.
What I need to do, is to seperate and sort data when I put it in the array. But I don't know what best practice on this will be.
E.g. I have set of data with a customer ID in one column and revenue in the second. Lets say I only have 2 customers and have a list like the one below:
Customer ID Revenue
1 604
2 669
2 732
2 629
1 897
2 530
I would then like my array to have two dimensions (customer 1 and 2) and have a maximum lenght that matches with the maximum amount of purchases one customer has made. In this case, customer 2 have made four purchases and customer 1 have made two. Therefore my ideal array would be something like this: myArray(1 to 2, 4).
How will I do this best?
Then after I have defined my array, I would like to populate it with my data, but the data is not sorted, so how can I determine in what place I should put the data next? If that makes sence?
For example my initial thought was to run through the dataset and do something like this:
i = 1
do until dataset.eof
if dataset.field("customerid") = 1 then
myArray(1, i) = dataset.field("customerid").value
else if dataset.field("customerid") = 2 then
myArray(1, i) = dataset.field("customerid").value
end if
i = i + 1
dataset.movenext
loop
This is all fine and dandy, until the customer ID changes. If the first to rows are customer 1 then the data would be placed in myArray(1, 1) and myArray(1, 2). But then if the customer ID on the next row i customer 2, the first entry for customer 2 will be in myArray(2, 3) and not in myArray(2, 1) as I will desire.
Also with this, I will exceed the limits of the array if I have the array defined as per my first question :-)
Does this all make sense?
Thanks in advance :-)

Answer 1

You can use a scripting dictionary with the customer id as the key and an array of revenues as the value.
Untested:
dim dict as object, id, rev, tmp, k
set dict = createobject("scripting.dictionary")
do until dataset.eof
id = dataset.fields("customerid").Value
rev = dataset.fields("revenue").Value
if dict.exists(id) then
tmp = dict(id)
ub = ubound(tmp)+1
redim preserve tmp(0 to ub)
tmp(ub) = rev
dict(id) = tmp
else
dict(id) = Array(rev)
end if
dataset.movenext
loop
for each k in dict
debug.print k, join(dict(k),", ")
next k

Answer 2

I believe that arrays are not the best data structure for this goal. I would use a collection of classes. That gives great flexibility in both storing and sorting data. As an example, I created the following:
-in the worksheet (as data source, to replace your recordset):
-Code module Module1:
Option Explicit
Sub jzz()
Dim Customers As Collection
Dim cust As cls_customer
Dim i As Long
Dim arr() As Long
Set Customers = New Collection
i = 1
Do Until Cells(i, 1) = vbNullString
'check if the customer is already in the collection:'
For Each cust In Customers
If cust.id = Cells(i, 1) Then Exit For
Next cust
'check if the customer was found; if not, create new and add to collection'
If cust Is Nothing Then
Set cust = New cls_customer
cust.id = Cells(i, 1)
Customers.Add cust
End If
cust.Revenue = Cells(i, 2)
i = i + 1
Loop
For Each cust In Customers
Debug.Print cust.id, cust.Revenue_count
Next cust
Set Customers = Nothing
End Sub
-Class module cls_customer:
Option Explicit
Public id As Long
Private p_revenue_collection As Collection
Public Property Let Revenue(value As Long)
'accepts a long (value) and adds it to the collection'
p_revenue_collection.Add value
End Property
Public Property Get Revenue_count() As Long
Revenue_count = p_revenue_collection.Count
End Property
Private Sub Class_Initialize()
Set p_revenue_collection = New Collection
End Sub
The class holds only the revenue_count property, which returns the amount of entries in the collection, but you can add your own properties at will to return sorted data etc.