With Sheets("").Range("B:B"); Variable range when searching - vba

Question

Here´s the thing, I have a code that uses a fixed range in a fixed sheet to search for a value. I need now to make the sheet variable. I´ve tried couple of things with no luck so far.
The name of the sheet where I need to search is determined by a cell in another sheet. Replacing the 3rd line with something like: "With Sheets("Sheets("asd").range("A1")").Range("B:B") does not work.
My code:
FindString = W
If Trim(FindString) <> "" Then
With Sheets(**"CARS"**).Range("B:B")
Set Rng = Cells.Find(What:=FindString, _
After:=.Cells(.Cells.Count), _
LookIn:=xlValues, _
LookAt:=xlWhole, _
SearchOrder:=xlByRows, _
SearchDirection:=xlNext, _
MatchCase:=False)
If Not Rng Is Nothing Then
Application.Goto Rng, True
Else
MsgBox "Nothing found"
End If
End With
End If
Let me know if more info is required.
Thanks!

Answer 1

Try omitting some of the doublequotes: With Sheets(Sheets("asd").range("A1")).Range("B:B")
Explanation
When you do this, you'll get a compile error: Expected list separator or ):
With Sheets("Sheets("asd").range("A1")").Range("B:B")
This is because the double-quotes encapsulate a string literal, so in this case the string literal is "Sheets(", which raises an error at asd (and subsequent errors, too).
The solution is to simply refer to the Sheets("asd") object, there is no need to qualify that object within quotes :)
NOTE Brad identifies another potential error in your code, see his answer below.

Answer 2

replace "With Sheets("Sheets("asd").range("A1")").Range("B:B")
by:
dim VAR_Sheet as string
Var_Sheet=Sheets("asd").range("A1").value
With Sheets(Var_Sheet).Range("B:B")
...code...
end with
works also like this (same result):
With Sheets(Sheets("asd").range("A1").value).Range("B:B") 'removed quotes that made error

Answer 3

It looks like, while you types With you are actually not using it.
With Sheets("CARS").Range("B:B")
Set Rng = Cells.Find(What:=FindString, _ <~~ Cells references the active sheet
After:=.Cells(.Cells.Count), _
LookIn:=xlValues, _
LookAt:=xlWhole, _
SearchOrder:=xlByRows, _
SearchDirection:=xlNext, _
MatchCase:=False)
If Not Rng Is Nothing Then
Application.Goto Rng, True
Else
MsgBox "Nothing found"
End If
End With
You need to start the statement with a dot to signify you are continuing the reference established int eh With
With Sheets("CARS").Range("B:B")
Set Rng = .Find(What:=FindString, _ <~~ .Cells
After:=.Cells(.Cells.Count), _
LookIn:=xlValues, _
LookAt:=xlWhole, _
SearchOrder:=xlByRows, _
SearchDirection:=xlNext, _
MatchCase:=False)
If Not Rng Is Nothing Then
Application.Goto Rng, True
Else
MsgBox "Nothing found"
End If
End With
I assume the double * was for emphasis (Sheets(**"CARS"**) --> Sheets("CARS"))