How to define large list of strings in Visual Basic - vba

Question

I'm writing a macro in Visual Basic for PowerPoint 2010. I'd like to initialize a really big list of strings like:
big_ol_array = Array( _
"string1", _
"string2", _
"string3", _
"string4" , _
.....
"string9999" _
)
...but I get the "Too many line continuations" error in the editor. When I try to just initialize the big array with no line breaks, the VB editor can't handle such a long line (1000+) characters.
Does anyone know a good way to initialize a huge list of strings in VB?
Thanks in advance!

Answer 1

I don't think there's a way to do what you want. But there exist some workarounds.
For example, you could load your list of strings from a file.
That example can show you a hint :
Dim value As String = File.ReadAllText("C:\file.txt")
Also, this page talks about it : Excel macros - Too many line continuations.

Answer 2

To expand on freelax's answer:
You could store the string values in an external text file and read the items into an array line by line. My example (untested) early binds to the Microsoft Scripting Runtime library.
Dim arr() as string
Dim fso as New FileSystemObject
Dim fl as file
Dim ts as textstrean
Dim i as long ' counter
Set fl = fso.GetFile("c:\path\to\configfile.txt")
Set ts = fl.OpenAsTextStream(ForReading)
i = 0
Do While Not ts.AtEndOfStream
Redim Preserve arr(i) 'resize the array leaving data in place
arr(i) = ts.Readline
i = i + 1
Loop
Further Reading:
FileSystemObject
File
TextStream
Reading a text file with
vba
Redim an array
Of course, you'll probably want to be smarter about resizing the array, doubling it's size when you run out of space.

Answer 3

An option for a workaround might be to use the Join Command, like this:
Const ARRAY_VALUES As String = _
"string1,string2," & _
"string3,string4"
Dim big_ol_array() As String
big_ol_array() = Split(ARRAY_VALUES, ",")
This would allow you to put multiple entries on each line, and then you could use multiple lines continuations.
Or, if you really want one value per line, you could just use multiple constants, like this:
Const ARRAY_VALUES1 As String = _
"string1," & _
"string2," & _
"string3," & _
"string4,"
Const ARRAY_VALUES2 As String = _
"string5," & _
"string6," & _
"string7," & _
"string8"
Const ARRAY_VALUES As String = _
ARRAY_VALUES1 & _
sARRAY_VALUES2
Of course, you could choose a different delimiter if it conflicts with your data. In cases like this I'll use a pretty rare but readable delimiter like the bullet (•), which can be typed by holding the Alt key and typing the "0149" on the number pad. Then your code would look like this:
Const ARRAY_VALUES As String = _
"string1•string2•" & _
"string3•string4"
Dim big_ol_array() As String
big_ol_array() = Split(ARRAY_VALUES, "•")
Here's some other interesting delimiters. These will all show up in the IDE (while others will just look like a box):
§ ¸ · • ¤ « » ¦ ± _­ ¯ ¨ ª ¹ ² ³ ´ ° º ¿ ¡

Answer 4

Get rid of the line continuation character as what GSerg posted in this link if you want to keep it simple. Same link posted by Freelex actually.
Dim bigStr As String, big_ol_array() As String
bigStr = "string1"
bigStr = bigStr & "," & "string2"
bigStr = bigStr & "," & "string3"
.
.
bigStr = bigStr & "," & "string9999"
big_ol_array() = Split(bigStr, ",")

Answer 5

Dim BigOlArray(1 to 99999) as String
BigOlArray(1) = "String1"
BigOlArray(2) = "String2"
or to save some typing
' Keep copy/pasting the second and third lines as needed
' then all you need to change is the string
x = 1
BigOlArray(x) = "String1"
x = x+1
BigOlArray(x) = "String2"
x = x+1
BigOlArray(x) = "String3"
x = x+1