Inserting item into list causes item to be deleted - vb.net

Question

I currently am trying to insert a score into its proper position. The scores add to their proper position.
However when I add or insert to the contained list it does not expand past its deserialized size. (Note this highscore class is serialized to XML after the AddNewScore function is called. Also it is deserialized when the program is loaded)
The issue only occurs after deserialization.
Here is my serialization code (its contained in a serialization class that manages saving and loading all data types I use)
Public Sub LoadHighScores()
_highScores = DirectCast(LoadXml(highScoreFilePath, highScoreBackupFilePath, _highScoreFileCorrupted, GetType(HighScores)), HighScores)
If (_highScores.scores.Count < 5) Then
_highScores.AddNewScore(New Score("Steve", 9000))
_highScores.AddNewScore(New Score("John", 8000))
_highScores.AddNewScore(New Score("Paul", 7000))
_highScores.AddNewScore(New Score("Alex", 6000))
_highScores.AddNewScore(New Score("Joe", 5000))
SaveHighScores()
End If
End Sub
Private Sub SaveHighScores()
If (File.Exists(highScoreFilePath) And Not _highScoreFileCorrupted) Then
File.Copy(highScoreFilePath, highScoreBackupFilePath, True) 'Backup quiz data
End If
Using FileStream As FileStream = New FileStream(highScoreFilePath, FileMode.Create)
'Dim encryptionStream As CryptoStream = New CryptoStream(FileStream, AESCrypto.CreateEncryptor(Key, IV), CryptoStreamMode.Write)
Dim serializer As XmlSerializer = New XmlSerializer(GetType(HighScores))
serializer.Serialize(FileStream, _highScores)
_highScoreFileCorrupted = False
'encryptionStream.Close()
End Using
End Sub
Public Function LoadXml(ByVal filePath As String, ByVal backupFilePath As String, ByRef fileCorrupt As Boolean, ByVal dataType As Type) As Object
Dim returnValue As Object = Activator.CreateInstance(dataType)
If (File.Exists(filePath) Or File.Exists(backupFilePath)) Then
Using fileStream As FileStream = New FileStream(filePath, FileMode.OpenOrCreate)
Using backupFileStream As FileStream = New FileStream(backupFilePath, FileMode.OpenOrCreate)
Dim serializer As XmlSerializer = New XmlSerializer(dataType)
Try
returnValue = serializer.Deserialize(fileStream)
Catch ex As Exception
fileCorrupt = True
Try
returnValue = serializer.Deserialize(backupFileStream)
Catch e As Exception
MessageBox.Show("Backup Corrupted", "Loading error", MessageBoxButtons.OK, MessageBoxIcon.Error)
End Try
End Try
End Using
End Using
End If
Return returnValue
End Function
Here is my high score class
Imports System.Collections.Generic
Imports System.Xml
Public Class HighScores
Public scores As List(Of Score) = New List(Of Score)
Public userplays As List(Of UserGameLog) = New List(Of UserGameLog)
'Public userPlays As Dictionary(Of String, Integer) = New Dictionary(Of String, Integer)
Sub New()
End Sub
Private Sub UpdatePlays(ByVal Username As String)
For Each userlog As UserGameLog In userplays
If (userlog.username = Username) Then
userlog.numberOfPlays += 1
Return
End If
Next
userplays.Add(New UserGameLog(Username))
End Sub
Public Function GetNumberOfPlays(ByVal Username As String) As Integer
For Each userlog As UserGameLog In userplays
If (userlog.username = Username) Then
Return userlog.numberOfPlays
End If
Next
Return 0
End Function
Public Function GetHighScores() As List(Of Score)
Return scores
End Function
Public Sub AddNewScore(ByVal score As Score)
UpdatePlays(score.username)
If (scores.Count > 0) Then
For index = 0 To scores.Count - 1
If (scores(index).score < score.score) Then
scores.Insert(index, score)
Exit Sub
End If
Next
End If
scores.Add(score)
End Sub
End Class

Answer 1

Solved my issue, on loading the highscore list i was pulling out the 5 highest scores. Instead of using range of I was assigning a new list the score list and removing the unused values to trim it down to 5 with
Public Function GetHighScores(ByVal maxScoreCount As Integer) As List(Of Score)
Dim scores As List(Of Score) = New List(Of Score)
scores = _highScores.scores
If (scores.Count > maxScoreCount) Then
scores.RemoveRange(maxScoreCount - 1, scores.Count - maxScoreCount)
End If
Return scores
End Function
This was a reference to the prior list and it was cutting out my values. Swapped it out with GetRange and problem is fixed. smacks head