Poster Plugin with Autohot key - httprequest

Question

am trying to create a GUI with autohotkey for a poster request using autohotkey.
for Ex:
{
"hwId":"2703",
"clientApiVersion":"1.0.0",
"sellId":"123456",
"uid":"123456",
"targetUserId":"123456",
"templateId":"123456",
"overrideValues": [{"name":"USERNAME","value":"test"}],
"customMessages": [{"name":"key1","value":"value1"},{"name":"key2","value":"value2"}],
"language":"en",
"verificationCode":"code",
"badge":"33",
}
this is the poster body that i use. these are inputs that go in and the output is shown. usally when i send a POST request i get a response in json. Can some on help me with this... i tried searching the web but could not find anything that is relevant to the poster plugin with autohotkey.
Kindly help me guys.
Following is the code that i used
#NoEnv
#SingleInstance, Force
;InputBox, pass, Password, Enter password.
URL := "https://examplesite.com/exchange/api/ios/sendPushNotificationTemplateByUid"
;PostData := "username=Pulover&password=" pass
PostData := "
(
hwId=2703,
clientApiVersion=1.0.0,
sellId=865895,
uid=573675618,
targetUserId=573675618,
templateId=78,
language=en,
verificationCode=code,
badge=50,
)"
oHTTP := ComObjCreate("WinHttp.WinHttpRequest.5.1")
;Post request
oHTTP.Open("POST", URL , False)
;Add User-Agent header
oHTTP.SetRequestHeader("User-Agent", "Mozilla/5.0 (compatible; MSIE 9.0; Windows NT 6.1; WOW64; Trident/5.0)")
;Add Referer header
oHTTP.SetRequestHeader("Referer", URL)
;Add Content-Type
oHTTP.SetRequestHeader("Content-Type", "application/JSON")
;Send POST request
oHTTP.Send(PostData)
;Get received data
Gui, Add, Edit, w800 r30, % oHTTP.ResponseText
Gui, Show
return
GuiClose:
ExitApp

Answer 1

The example body is written in JSON. So I'm highly suggesting you to use a JSON lib. This is the one I've been using so far without any problems: http://pastebin.com/6EzQAHbH
Just save it as jsonParser.ahk in your scripts dir. I wrote you a pretty clean example of what I think you are looking for:
#Include jsonParser.ahk
url := "https://examplesite.com/exchange/api/ios/sendPushNotificationTemplateByUid"
username := "USERNAME"
Gui, Add, Edit, w800 r30 vResponseEdit
Gui, Show
body_AhkObj := {"hwId": "2703"
,"clientApiVersion": "1.0.0"
,"sellId": "123456"
,"uid": "123456"
,"targetUserId": "123456"
,"templateId": "123456"
,"overrideValues": [{"name":username,"value":"test"}]
,"customMessages": [{"name":"key1","value":"value1"}, {"name":"key2","value":"value2"}]
,"language": "en"
,"verificationCode": "code"
,"badge": "33"}
;change the sellId after the object was created
body_AhkObj.sellId := "987654321"
;;;;;;;;
body_JsonCode := BuildJson(body_AhkObj)
WinHttpObj := ComObjCreate("WinHttp.WinHttpRequest.5.1")
WinHttpObj.Open("POST", url)
WinHttpObj.SetRequestHeader("User-Agent", "Mozilla/5.0 (compatible; MSIE 9.0; Windows NT 6.1; WOW64; Trident/5.0)")
WinHttpObj.SetRequestHeader("Referer", url)
WinHttpObj.SetRequestHeader("Content-Type", "application/JSON")
WinHttpObj.Send(body_JsonCode)
GuiControl,, ResponseEdit, % WinHttpObj.ResponseText
Return
GuiClose:
ExitApp
Return