Fetching values from sql 2005 using vbscript - sql

Question

I am designing a web page that will fetch records for a specific id and print the information.I am just trying to redirect user to other page if provided id does not exists.I tried the below code but when id is null its showing blank page instead of redirecting to desired page.
code:
<%
Set conn = Server.CreateObject("ADODB.Connection")
conn.ConnectionString= "Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Initial Catalog=eseva;Data Source=BHAGWAT-PC"
conn.open
set rs=Server.CreateObject("ADODB.recordset")
rs.Open "Select * from saat_bara where id='"&request.form("t1")&"'" , conn
if IsNull(rs.Fields("id").Value) then
response.redirect("end.asp")
else
while not rs.eof
response.Write("Token no:")
response.Write(rs.fields.item(0))
response.write("<br><br>")
response.Write("Name:")
response.Write(rs.fields.item(1))
response.write("<br><br>")
response.Write("Address:")
response.Write(rs.fields.item(2))
response.write("<br><br>")
response.Write("Bdate:")
response.Write(rs.fields.item(3))
response.write("<br><br>")
rs.movenext
wend
end if
%>

Answer 1

You can't check a field that does not exist against null. So:
rs.Open "Select * from saat_bara where id='"&request.form("t1")&"'" , conn
if rs.eof
response.redirect("end.asp")
else
while not rs.eof
...
end if

Answer 2

Update:
Listed somethings you may want to consider for the future;
Look into using the ADODB.Command object to build parameterised queries.
Protects against SQL Injection
Data type negotiation is done for you (no adding apostrophes in your query when dealing with string types).
No need to manual setup ADODB.Connection and close it as .ActiveConnection can take a connection string and build your ADODB.Connection for you and when your ADODB.Command is released so is the associated connection.
Return only the field you need in your SQL query instead of using SELECT * depending on the table size this can be very costly (in your code your only returning four fields).
If you are just displaying data to screen consider using .GetRows() to return an Array rather than using ADODB.Recordset for iterating through your returned resultset. Resources that would be otherwise used by the ADODB.Recordset can be released as all your data is contained in a 2 dimensional array.
Below is an example of your code using ADODB.Command and Arrays;
<%
Dim connstr, sql, cmd, rs, data
Dim row, rows
connstr = "Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=False;Initial Catalog=eseva;Data Source=BHAGWAT-PC"
sql = ""
sql = sql & "SELECT Field0, Field1, Field2, Field3 " & vbCrLf
sql = sql & "FROM saat_bara " & vbCrLf
sql = sql & "WHERE id = ?"
Set cmd = Server.CreateObject("ADODB.Command")
With cmd
.ActiveConnection = connstr
.CommandType = adCmdText
.CommandText = sql
'As you put apostrophes around your id assumed it must be a varchar. If
'this is used as your primary key would be more efficient for it to be
'a numeric type like int, in which case you would use adInteger.
.Parameters.Append(.CreateParameter("#id", adVarChar, adParamInput, 50)
Set rs = .Execute(, Array(Request.Form("t1")))
If Not rs.EOF Then data = rs.GetRows()
'Release memory used by recordset
Call rs.Close()
Set rs = Nothing
End With
'Release memory and close connection used by command.
Set cmd = Nothing
If IsArray(data) Then
rows = UBound(data, 2)
For row = 0 To rows
'Consider not using Response.Write in your loop (taken from Bond's suggestion)
Call Response.Write("Token no:")
Call Response.Write(data(0, row))
Call Response.Write("<br><br>")
Call Response.Write("Name:")
Call Response.Write(data(1, row))
Call Response.Write("<br><br>")
Call Response.Write("Address:")
Call Response.Write(data(2, row))
Call Response.Write("<br><br>")
Call Response.Write("Bdate:")
Call Response.Write(data(3, row))
Call Response.Write("<br><br>")
Next
Else
'No data redirect
Call Response.Redirect("end.asp")
End If
%>